【GAS】doPost 日本語が取得できない【Excel VBA】

Question

当方、VBAとGASを勉強中の身のものです。
つたない説明でわかりづらい部分もあると思いますがご教示願います。

業務でIEでないと動作しないWEBシステムを使用しており
システムからデータをコピペすることが多々発生していたので
下記等を参考にしながらExcelVBAでスクレイピングができるようにしました。
https://tonari-it.com/ie-setting-navigate/

すると一部の部署から
スクレイピングしたデータをGoogleスプレッドシートへ自動で入力できないかと言われ
下記の過去記事を参考にしスプレッドシートへ転記する流れはでき、
半角英数字に関しては問題なく転記することもできました。

しかし下記コードで param2 に格納している日本語だけ空値になってしまいました。
日本語と半角英数字を混在させると日本語のみ認識されず
「1あ2」と入れると「12」とスプレッドシート上では値が貼り付けられてしまいました。

GAS側で e のcontentLength では日本語の分もカウントしているようではあるのですが
parameterを見るとやはり日本語だけ認識されていない状態になっていました。

日本語の処理に関して記述している記事などが見つからずご質問をさせていただいています。
そもそも日本語は処理できないものなのでしょうか？それすらもわからないので
諦めようにも諦められない状況です。
それか他に何か良い方法があればご教示いただきたいのでよろしくお願いいたします。

【VBA】【GAS】VBAで送信し、webアプリケーションで処理させたい。

作成したサンプルコードは下記になります。

Public Sub html_post()

'   参照設定
'   Microsoft XML, v6.0

    Dim httpReq As XMLHTTP60
    Set httpReq = New XMLHTTP60
    Dim param As Variant
    Dim url As String
    url = "ウェブ アプリケーションの URL"
        
    With httpReq
        .Open "POST", url, False
        Call .setRequestHeader("Content-Type", "application/x-www-form-urlencoded")
        param = _
            "param1=" & "TEST&" & _
            "param2=" & "テスト&" & _
            "param3=" & "123&" 
        .send (param)
    End With
    Set httpReq = Nothing
End Sub

function doPost(e) {
  var Id = 'スプレッドシートID';
  var ss = SpreadsheetApp.openById(Id);
  var sh = ss.getSheetByName('log');
  var maxRow = sh.getRange('A:A').getValues().filter(String).length + 1;
  try {
    var params = e.parameter
    var ADD_LIST = [[
      params.param1,
      params.param2,
      params.param3
    ]];
    
    sh.getRange(maxRow,1,ADD_LIST.length,ADD_LIST[0].length).setValues(ADD_LIST);
  } catch(ex) {
    sh.getRange(maxRow, 1).setValue('error');
  }
}

Answer 1

仕様を見た訳ではないですが、encodeだろうなーと思ってやってみました。

同じ問題を再現したうえで、下記のような手当をしたところ、「テスト」が書かれるようになりました。

Public Sub html_post()

'   参照設定
'   Microsoft XML, v6.0

    Dim httpReq As XMLHTTP60
    Set httpReq = New XMLHTTP60
    Dim param As Variant
    Dim url As String
    url = "ウェブ アプリケーションの URL"

    ' encodeUrl
    Dim objSC As Object
    Dim encodeUrlUtf8 As String
    Set objSC = CreateObject("ScriptControl")
    objSC.Language = "Jscript"
    encodeUrlUtf8 = objSC.CodeObject.encodeURIComponent("テスト")
    Set objSC = Nothing


    With httpReq
        .Open "POST", url, False
        Call .setRequestHeader("Content-Type", "application/x-www-form-urlencoded")
        param = _
            "param1=" & "TEST&" & _
            "param2=" & encodeUrlUtf8 & "&" & _
            "param3=" & "123&"
        .send (param)
    End With
    Set httpReq = Nothing
End Sub

Comments

[lazyAnt]

おっしゃる通りにやってみたところ無事転記ができました！！
こんなに早くご返信していただきありがとうございます！

Excel側でencodeをこのように変換する方法初めて知りました
GAS側の部分ばかり調べていましたのでわからなかったはずです。

関数化して私用させていただきたいと思います。
ありがとうございました！

[papinianus]

> GAS側の部分ばかり調べていましたのでわからなかったはずです。
chromeのアプリ(拡張機能)で、postを手動作成できるツールがあって(例えばPOSTMAN)、そういうのでチェックすると、GAS(受け手)なのか、VBA(送り手)なのか、問題の切り分けができます。私自身、postmanでいけたので、VBAでencodeURIをやってみるかなーと思いました。

[lazyAnt]

ご返信遅くなってしまいすみません！
postman ですが、こちらも知りませんでした。。。
デベロッパーツールも使ったことがないのでこれを機に使用し始めてみます^^
とりあえずpostmanの使い方を調べつつインストールしてみます！
回答だけでなくアドバイスもいただき本当にありがとうございます！