VBAで順に選択した図形に書かれた文字列をひとつに結合したい

Question

[やりたいこと]
エクセルの複数の図形に書かれた文字列をクリックする度にA1セルに次々にクリックした順に文字列結合されるようなVBAを書きたいです。

[具体的に]
図形1に"AAA"
図形2に"BBB"
図形3に"CCC"
図形4に"DDD"
図形5に"EEE"
とあると仮定し、

図形1 > 図形3 > 図形5 > 図形2 > 図形4の順に押下すると
A1セルに"AAACCCEEEBBBDDD"と表示される

以上のようなことを実行できるマクロが組みたいです。
VBAは初心者ですが、エクセルの関数くらいは普通に使えるのでVBAの記述だけで結構です。
ご教示お願いいたします。

Comments

[ttyp03]

PHPとJavaはこの質問にどのような関係が？不要ならタグから削除してください。

Answer 1

Excelの仕様的に地味に面倒な処理ですね

最低限の記述だけするとこんな感じでしょうか

Private targetWs As Excel.Worksheet

'開始時に実行
Sub Start()
    Set targetWs = Excel.ActiveSheet
    targetWs.Range("A1").Value() = Empty
    setOnAction targetWs, "'" & ThisWorkbook.Name & "'!OnClick"
End Sub

'止めたいとき実行
Sub Finish()
    setOnAction targetWs, VBA.vbNullString
    Set targetWs = Nothing
End Sub

Private Sub setOnAction(ws As Excel.Worksheet, procName As String)
    Dim shp As Excel.Shape
    For Each shp In ws.Shapes
        shp.OnAction = procName
    Next shp
End Sub

Private Sub OnClick()
    Dim clickedShp As Excel.Shape
    Set clickedShp = targetWs.Shapes.Item(Excel.Application.Caller)
    With targetWs.Range("A1")
        .Value() = .Value() & clickedShp.TextFrame2.TextRange.Text
    End With
End Sub

Comments

[yosaku]

ありがとうございました！
思い描いていた通りの動作になりました。

[yosaku]

すみませんが、このファイルでうまく動作していたのですが次の日に立ち上げたらエラーが出ました。
「実行時エラー ’91’: オブジェクト変数または With ブロック変数が設定されていません。」というダイアログが出ているのですが、下から５行目あたりで「clickedShp = Nothing」となっています。
なにか追記しなくてはいけないのでしょうか？

[imihito]

詳細な条件が一切示されなかったため、`Start`を実行した瞬間のシートを内部的に保持する仕様にしています。
ブックを閉じれば内部的に取得していたものが無くなるため、エラーになります。

理想とする動作がこちらにはわからないので、ご自身で直してみてください。
自身ではどうしても難しいようであれば、仕様を明確にした上で、別途質問をしてください。