バッチにより特定のVBSのPIDを取得したい

Question

前提・実現したいこと

バッチを使用して、実行中のVBSのPIDを取得したい。Windows10使用。

例えば、A.vbsとB.vbsが実行中の時にバッチを実行して、B.vbsのPIDを取得したい。
最終的にそのPIDを使用してそのプロセスをkillする事が目的です。

発生している問題・エラーメッセージ

tasklist /FI "IMAGENAME eq wscript.exe"を使用しましたが、

イメージ名                     PID セッション名     セッション# メモリ使用量
========================= ======== ================ =========== ============
wscript.exe                  16080 Console                    1     14,332 K
wscript.exe                  16016 Console                    1     14,328 K

得られる情報は以上のみで、どちらのwscript.exeがB.vbsを実行しているか判断できません。

バッチを使用してB.vbsを実行するwscript.exeのPIDを調べる方法は無いでしょうか。
バッチが無理な場合、VBScriptでは可能でしょうか。

Answer 1

KILLすることまで考えると、VBScriptを使うのが簡単です。

for each p in GetObject("winmgmts:{impersonationLevel=impersonate}"). _
    ExecQuery("select * from Win32_Process where CommandLine Like '%wscript.exe%foo.vbs%'")
    WScript.Echo p.CommandLine, p.ProcessId
    p.Terminate
next

バッチでやるのだと、WMIC process where (commandline like "%WScript.exe%foo.vbs%") get processidでいいかと思ったのですが、WMIC自体も引っかかってしまいますので面倒。

@echo off
WMIC process where (commandline like "%%WScript.exe%%foo.vbs%%") get commandline,processid | findstr /v WMIC | findstr vbs > work.txt
for /f "tokens=3" %%A in (work.txt) do (
  echo %%A
  taskkill /pid %%A
)

foo.vbsのパス名に空白がある場合は、tokes=3を調整要。

ちょっと乱暴ですが、KILLするのが目的なら、これもあり。taskkillでエラーが出るけど無視。

for /f %%A in ('wmic process where ^(commandline like "%%wscript.exe%%foo.vbs%%"^) get processid') do taskkill /pid %%A 2>NUL

Comments

[himrock]

回答ありがとうございます。
確かにVBScriptの方が楽そうですが、バッチを使用した方法も用意して頂き助かりました。
WMICを使った事が無かったのですが、これを覚えればバッチでできる事の幅が広がりそうです。
勉強になりました。

Answer 2

「Windows Management Instrumentation（WMI）」を使用すると、プロセスのコマンドラインを取得できるため、
「コマンドラインの中にB.vbsが含まれているかどうか」程度の判定であれば可能です。

WMIの操作はバッチからも、VBScript(COM)からも、どちらからでも行えます。

バッチから操作する場合はWMIC.exeを使用します。
私はちゃんと使ったことが無いので割愛しますが、以下の記事が参考になると思います。

Windows がなんか重いときにコマンドで調べる（WMIC PROCESS） - Qiita

---

COMから操作する場合はMicrosoft WMI Scripting V1.2 Libraryを使用します。
以下はVBScriptの場合のサンプルです。

Option Explicit

'https://teratail.com/questions/145888
Call Sample_KillProcess_teratail_Q145888

Sub Sample_KillProcess_teratail_Q145888()
    
    'Win32_Process から
    'Nameが'wscript.exe'かつCommandLineに'b.vbs'が含まれるものを探し
    'ProcessId と CommandLine を取得する
    '[WQLクエリステートメントの紹介 - WMI Reference](http://www.wmifun.net/reference/wql_query_statement.html)
    Dim wql 
    wql = "SELECT ProcessId, CommandLine "
    wql = wql & "FROM Win32_Process "
    wql = wql & "WHERE Name = 'wscript.exe' AND CommandLine LIKE '%b.vbs%'"
    
    
    'WbemScripting = Microsoft WMI Scripting V1.2 Library
    Dim locator 'As WbemScripting.SWbemLocator
    Set locator = CreateObject("WbemScripting.SWbemLocator")
    
    'ローカル端末に接続し検索
    Dim proc 'As WbemScripting.SWbemObject
    For Each proc In locator.ConnectServer().ExecQuery(WQL)
        '[[WMI Class] Win32_Process クラス - WMI Library](http://www.wmifun.net/library/win32_process.html)
        Dim cmdLnTxt
        cmdLnTxt = proc.Properties_.Item("CommandLine").Value
        Dim pId
        pId = proc.Properties_.Item("ProcessId").Value
        
        Dim msg
        msg = "ProcessId = " & pId & vbLf & _
              "CommandLine = " & cmdLnTxt & vbLf & _
              "kill ok ?"
              
        If MsgBox(msg, vbQuestion Or vbOKCancel) = vbOK Then
            '[[WMI for VB6] WMI のメソッドを使ってみよう - WMI Step](http://www.wmifun.net/step/vb6_04.html)
            Call proc.Terminate
        End If
        
    Next 'proc
    
End Sub