VBAでオブジェクト指向 クラスの中にクラス Rangeっぽいオブジェクト等を作りたい

Question

前提・実現したいこと

Rnageっぽいクラスを作り書式や値のコピーに
対応させたい
--以降「っぽい」は省略--

理由(蛇足)

Excel VBA で帳票のシステムを作成していて
大体出来上がったところで
上司「クリップボード(Excelの機能で履歴として見れる)に変なもの(システムで行のコピーなどをした履歴)が出ていて邪魔だから出ないようにして」っと言われてしまい
Copyコマンドが使えなくなってしまいました。

今後もCopyコマンドが使えなさそうなので
疑似的なRangeっぽいクラス等を作りたいです

発生している問題

とりあえずRangeはCellの塊として考えて
作ろうとしたのですが
「Range(1,4)」の様に使えるように
単純にRangeはCellの配列を返すようにしようとしたところで
Range.count等のRangeのプロパティーが
使えないことに気づきました
Itemプロパティーを作り
「Range.Item(1,4)」の様にしようかと思ったのですが
Rangeの下層にあるクラスも全く同じ様になってしまい
Itemまみれになってしまうので
出来ることなら避けたいです。

何か手段はないでしょうか?

あがいたけどダメだった策

「Range」は上位階層を作る予定がないので出来ないがそれ以下であれば
上位のオブジェクトのプロパティを使って

'使う時
~~~~略~~~~
set MR as MyRng

print MR.Item(1,4).Borders(xlEdgeLeft).Weight

'MyRangeクラスの中
private Cell__ as MyCell
~~~~略~~~~
property Get Item(Byval RowIndex,byval ColumnIndex)as MyCell
    
    Item=Cell__(RowIndex,ColumnIndex)
End Property

'MyCellクラスの中
~~~~略~~~~
Property Get Borders_() As MyBorders
    Borders_ = Borders__
End Property

Property Get Borders_(byval Index as XlBordersIndex) As MyBorder
    BorderS_ = Borders__.Item(Index)
End Property

みたいな感じで引数(インデクス)の有り無しで返すオブジェクトが
変更出来たらなぁ...
っと思ったのですがうまく行きませんでした.....。

補足情報（FW/ツールのバージョンなど）

Excel 2013以降
Win10 64bit Home と Pro

Answer 1

書かれているコードから、オーバーロードのようなことをしたいのだと思われます。
VBAではオーバーロードはできないですが、無理矢理やるとしたら以下のような感じでしょうか。

• 引数を省略可能・返り値の型をObject型にして、引数の有無で返すオブジェクトを変更する（例：Worksheet.OLEObjectsメソッド）
• 複数としても単数としても使えるクラスを作成する（例：Rangeオブジェクト）

---

Copyをどのように使っているかわかりませんが、Range.Value(xlRangeValueXMLSpreadsheet)で代用できないでしょうか？

RangeのValueプロパティは引数を指定できるプロパティで、xlRangeValueXMLSpreadsheetを指定すると、セルの値、罫線、色などの基本的な情報を取得、設定することができます。
（条件付き書式などExcelに依存した機能はダメですが、単純な書式なら取得、設定できます）

Sub Sample()
    
    'コピー元のセル
    Dim srcRng As Excel.Range
    Set srcRng = Range("A1")
    
    '適当に書式設定
    With srcRng
        .Interior.Color = vbYellow
        .Font.Color = vbRed
        .BorderAround XlLineStyle.xlContinuous, xlThin
        .Value() = "ABC"
    End With
    
    '貼り付け先のセル
    Dim destRng As Excel.Range
    Set destRng = srcRng.Offset(2)
    
    '書式などコピー（要サイズ合わせ）
    destRng.Value(xlRangeValueXMLSpreadsheet) = _
        srcRng.Value(xlRangeValueXMLSpreadsheet)
    
    'xlRangeValueXMLSpreadsheet
    ' = Excel.XlRangeValueDataType.xlRangeValueXMLSpreadsheet
    ' = 11
    
End Sub

Comments

[kamikazelight]

朝一番で試させてもらいました。
すばらしいです。
ありがとうございました。