VBAでエラーが出る。。。

Question

以前質問した内容を自分で組んでみたのですが、エラーやらで上手くいきません。。。
自分の技量と、やらなければいけない事の差がありすぎて困っています。
アドバイスをお願い致します。

【やりたいこと】

1. 範囲はI8:T17
2. 上記の範囲の中で、セルに色がついている場合は無視
3. セルに色がついておらず、尚且つ文字(データ)が入っているセルを赤くする
4. ただし、3)の条件でもセル[00][56]と並んでいるデータに関してはセルを赤くしない

テーブル内には色のついていないセルで[00]単体のものもあるが、単体の場合はセルを赤くする
5) 1)の範囲に1つでも赤いセルがあればU5に×、赤いセルがない場合は〇と記載する

問題のコードです↓
※5）にはまだ至っていません。

Dim i As Integer, j As Integer
Dim C_row As Integer, C_Clm As Integer
Dim Star As Range
Dim Luz As Range
Cielo As Range
Dim Flag As Boolean

Sub AAA()

'[go 05]をチェックする
i = 8
j = 9

For C_Row = 7 To 28 Step 1
     For C_Clm = 13 To 22 Step 1

          Set Star = Sells(C_Row, C_Clm)
       
          For Each Star In Luz
               Flg = False
               Select Case True
                    Case Not Star.Interior.Color = xlNone
                    Case Star.Value = "FF"
                    Case Star.Value = "00" and Star.Offset',1).Value = "56"
                    Case Len(Star.Value) = 0
                    Case Else: Flg = True
               End Select

               If Flag Then
                    If Cielo = Star
               Else
                    Set Star = Union(Cielo, Star)
               End If

　　　　　　　　 If Star.Interior.ColorIndex = xlNone Then
                     Tange(Cielo).Interior.Color = 22
               End If
          Next
     Next
Next

Comments

[imihito]

色々問題があるのでまずは最低限ののことについて ①モジュールの先頭に「Option Explicit」を追加する ②「デバッグ」内の「○○のコンパイル」を実行する ③コンパイルを行うと「コンパイルエラー～」と表示される。「○○が定義されていません」はスペルミスなので修正、それ以外はメッセージに応じて修正。「Ctrl + Space」で使えるものの一覧が出てくるので「○○が定義～」系はそちらも参考に。

[sysjojo]

とりあえず先頭に「Option Explicit」を書きましょうか。Sellsとか書いてるうちはまともにデバッグなんてできないでしょうから、まずは文法的におかしなところを潰して、潰したいエラー内容を付け加えて質問内容を更新されるとよいかと。

[zuzu1984]

訳あって、実際のコードをコピペできないので、スペルミスしてしまいました。実際はCellsと書いています。

Answer 1

前回の質問の、mattuwanさんの回答で概ね問題無さそうだと思いましたが、あちらのコードは試されたのでしょうか？

やっている内容について自分なりの解釈でコメント入れてみたので、良ければこちらも参考にしてください
（若干好みで変えてますが、流れ・内容はほぼ同じです）。

Sub test()

    '検索範囲の取得
    Dim rngFind As Range
    With Range("B7").CurrentRegion
        'Range("B7").CurrentRegion・.Cells
        'B7を選択してCtrl+Aを押したときに選択される範囲
        '→B7:T17の範囲（下にもデータがあるならそこまで範囲）
        
        '.Offset(1)
        '上記の範囲を下に1行ずらした範囲
        
        '.Offset(, 7)
        '上記の範囲を右に7列ずらした範囲
        
        'Excel.Intersect
        '上記範囲の重なったところ、つまり8行目以下、I列含めてそこから右の範囲
        '→I8:T17の範囲（下にもデータがあるならそこまで範囲）
        Set rngFind = Excel.Intersect(.Cells, .Offset(1), .Offset(, 7))
    End With
    
    '赤くするセル
    Dim rngTarget As Range
    
    '取得した検索範囲全体に対してループ（Zの字を描く順番、1行目を右に行って、終わったら2行目…）
    Dim r As Range
    For Each r In rngFind
        'セルに色を付けるかどうかのフラグ
        Dim flg As Boolean
        flg = False
        
        Select Case True
            Case r.Interior.Pattern <> xlNone
                'セルに色がついている場合は無視
                'セルの、背景の、塗りつぶし方法が、無し ではない
                '→ 何かしら塗りつぶしが設定されていれば
                '何もしない
                
            Case r.Text = "00" And r.Offset(, 1).Text = "56"
                '[00][56]の判定
                '今のセルが[00]で、1列右のセルが[56] なら
                '何もしない
                
            Case r.Text = "56" And r.Text(, -1).Value = "00"
                '[00][56]の判定
                '今のセルが[56]で、1列左のセルが[00] なら
                '何もしない
                
            Case r.Text = ""
                'セルの、文字が、空 なら
                '何もしない
                
            Case Else
                'それ以外なら、赤色（のフラグ）にする
                flg = True
        End Select
        
        If flg Then
            
            'rngTargetに赤色にするセル範囲をくっつける
            If rngTarget Is Nothing Then
                '1個目の場合
                Set rngTarget = r
            Else
                '2個目以降の場合
                Set rngTarget = Excel.Union(rngTarget, r)
            End If
            
        End If
    Next
    
    If Not rngTarget Is Nothing Then
        rngTarget.Interior.Color = vbRed
    End If
End Sub