【Excel vba】inputboxで入力されたデータにダブルコーテーションがつく。

Question

いつも色々とお世話になります。

今回はExcelのvbaで下記のマクロを組んだのですが、
Do until～　Loopの繰り返し回数を決める箇所で、
inputboxを使いデータの数を手動で入力させるようにしましたが、
変数num_allにデータを入れる部分のみダブルコーテーションがつきます。

Sub 重複確認()
Dim x, y, x1, comp_ch, num_all, num_all_ch, line_end As Long
x = 1
x1 = 1
y = 1
comp_ch = 0

line_end = Application.InputBox("データが存在する一番右端の列番号を入力して下さい。例)A2→2 ", Type:=2)
num_all = Application.InputBox("データ数を入力して下さい。", Type:=2)
'####↑inputboxで入れるとnum_allのみ数字の前後に”がついてしまう。cf)"25"####

Do Until num_all_ch > num_all
'####↑ここで繰り返し処理の回数を制限しているが、””がついている為止まらない。####

    Do Until Cells(x + x1, y) = "" Or comp_ch = 1

        If Cells(x, y) = Cells(x + x1, y) Then

            Range(Cells(x + x1, y), Cells(x + x1, line_end)).Interior.ColorIndex = 35
            
                comp_ch = 1
                
        ElseIf Cells(x, y) <> Cells(x + x1, y) Then
        
            x1 = x1 + 1 '内容が被ってないので次へ
            
        End If

    Loop
    
        comp_ch = 0
        num_all_ch = num_all_ch + 1
        x = x + 1
        x1 = 1

Loop
End Sub

Application.InputBox("〇〇〇〇〇〇〇〇〇〇", Type:=2)と同一の書き方をしており、
データを格納する変数もlongで統一しております。

試しに別PC・異なるverのExcelで実行しましたが、やはり"xx"とダブルコーテーションを含んでしまいます。

ダブルコーテーションをつけない方法はありますでしょうか？

Answer 1

戻り値のタイプを数値にすればよいでしょう。

num_all = Application.InputBox("データ数を入力して下さい。", Type:=1)

https://msdn.microsoft.com/ja-jp/vba/excel-vba/articles/application-inputbox-method-excel

但し文字列であってもVBAはうまく処理してくれるので問題はありません。
ちなみにダブルクォーテーションが付加されているのは、ステップ実行等で値を確認したときだと思いますが、これは値が数値ではなく文字列ですよ、という表示上のことだけであって、実際にダブルクォーテーションが付加されているわけではありません。

おそらく問題はループ内の処理にあるのではないかと思います。
ループ内のループは正しく処理できていますか？
試しにこのループ処理をコメントアウトして動かしてみても無限ループしますか？
num_all_chの初期化は不要ですか？

余談ですが、変数の型は明示的に宣言しましょう。

Comments

[NextSt]

お返事ありがとうございました。

参考書を読み間違えており、
Type:=2と記載している事に気づきません。

type:=1とした所、問題なく処理が完了しました。

[ttyp03]

やはり文字列で受け取っていたのが原因でしたか。
個人的には解せないのですが、まあ動いたのならよかったです。
ちなみにline_endもType:=2になっていますのでご注意を。

[ExcelVBAer]

自分も同じ勘違いをしたことあったな~
"2" って表示されるから、"が付いてる？？って思っちゃう(笑)

ちなみに、念の為に確認したいときは、
プログラム実行時にイミディエイトウィンドウで、
？[変数名] ＋ Enter ってすると、
変数に格納されている値が見れるので、参考まで~

Answer 2

Dim x, y, x1, comp_ch, num_all, num_all_ch, line_end As Long

ひょっとして、これで、この変数すべてLong型で宣言していると勘違いしているのでは。
これだと、最後のline_endのみLong、それ以外は Variantになります。
面倒でも下記のように省略せずに記述しましょう。

Dim x As Long, y As Long, x1 As Long, comp_ch As Long, num_all As Long, num_all_ch As Long, line_end As Long

そうすれば、テキストでも数値に変換してくれます。
変換できないものはエラーになるので、エラー処理で対処します。

Application.InputBox("データ数を入力して下さい。", Type:=1)

とType引数で数値を指定しておけば、数値以外を入力すれば、このメソッドが警告しますので、自前でエラー処理は不要です。

ちなみに、Type引数は、InputBoxの返すデータ型を設定するものではなく、入力可能な値のタイプを指定するものです。
InputBoxの返すデータ型は、バリアント型なので、戻り値を代入する変数の方で正しいデータ型を設定していないと、想定外の動作になる場合があります。

追記

回答を書いているうちに解決済みになってしまいました（汗）。

Type:=1 にすることで解決したということですが、
それはたまたまと考えたほうがいいでしょう。
InputBoxの返すデータ型はバリアント型なので、それをバリアント型に代入したしたら、どのようなデータ型になるかは不確実です。
受ける変数のデータ型を数値型で宣言しておくのが確実です。

Comments

[NextSt]

回答いただきありがとうございました。
Dim x, y, x1, comp_ch, num_all, num_all_ch, line_end As Longで、
全てlong型で宣言できていると勘違いしているのは、
まさにその通りでして、
long型で変数を宣言しているのに、
なんで文字列が入ってるの…？という点が、
はっきりしました。