VBA Dictionary 取り出し方にて質問

Question

VBAにて下記実装を行いました。

Dim dictionary As Variant
Set dictionary = CreateObject("Scripting.Dictionary")

Dim hogeIndex As Integer
Dim hogeString As String

For hogeIndex = 1 To 10
    hogeString = sheet1.cells(hogeIndex,1)
    If Not dictionary.Exists(hogeString ) Then
        dictionary.Add hogeString , hogeString 
    End If    
Next

上記コンパイルは通っている状態です。

ここでdictionaryにAddしたitemをループで取得したいのですが、
下記サイトの情報通りの実装を行っても値取得ができません。

http://www.excel-wing.com/study/jitumu/970

Dim hugeIndex As Integer
For hugeIndex = 0 To 10 
    Debug.Print(dictionary.Items(hugeIndex))
Next

dictionary.Itemsだとコンパイルエラー、dictionary.Itemだとコンパイルエラーは出ませんが、値取得は出来ない。

また、dictionaryにAddしてからDebug.Pintでdictionaryを出力しようてしている処理までの流れでdictionaryのオブジェクト破棄は行っていません。

dictionaryに追加したItemをkeyなど関係なく、Addした順番で出力したいのですが、
どのように実装すればよろしいでしょうか。

よろしくお願いいたします。

追記。
dictionary.Items(0)で出力しようとした際のエラーメッセージは下記になります。
【Proparty Let　プロシージャが定義されておらず、Property Getプロシージャからオブジェクトが返却されませんでした。】

Answer 1

こちらのページにあるように、itemsを一旦別の変数に代入すれば(n)で参照できるようですね。

Dim hugeIndex As Integer
Dim items
items = dictionary.Items
For hugeIndex = 0 To 9
    Debug.Print items(hugeIndex)
Next

Itemsは引数を伴わないメソッドなので、一旦通常の配列に移し変えて使えるようにしているイメージでしょうか。

もしくはFor Eachを使うと楽かもしれません。

For Each Item In dictionary.Items
    Debug.Print Item
Next

Itemで値が取得できないのは、当然です。
Addの第一引数はキー名です。
提示コードでは、キー名に値を用いているので、1とか2では登録されていません。
キーをhogeIndexにすることでItem(n)で参照できるようになります。

For hogeIndex = 1 To 10
    hogeString = Sheet1.Cells(hogeIndex, 1)
    If Not dictionary.Exists(hogeString) Then
        dictionary.Add hogeIndex, hogeString  ' hogeIndexをキー名にする
    End If
Next

Dim hugeIndex As Integer
For hugeIndex = 1 To 10
    Debug.Print dictionary.Item(hugeIndex)
Next

Comments

[King_of_Flies]

配列にDictionaryを格納するのが楽だったので、ttypさんの案を採用しました。
ありがとうございました。

Answer 2

Dictionary はキーと値を一組にして保持するオブジェクトです。
例えば dictionary.Add "foo", "bar" とした場合は dictionary.Item("foo") で bar が取り出せます。
次の通りアレンジを加えず入力して実行してみてください。

Sub Macro1()
    Dim dictionary As Variant
    Set dictionary = CreateObject("Scripting.Dictionary")

    Dim hogeIndex As Integer
    Dim hogeString As String

    For hogeIndex = 1 To 10
        hogeString = Sheet1.Cells(hogeIndex, 1)
        If Not dictionary.Exists(hogeString) Then
            dictionary.Add "cell" & hogeIndex, hogeString
        End If
    Next
    
    For hogeIndex = 1 To 10
        Debug.Print dictionary.Item("cell" & hogeIndex)
    Next
End Sub

Answer 3

一度Itemsの結果を取得してから参照することとなるかと思います。
Items メソッド

Dim items As Variant
items = dictionary.items

Dim hugeIndex As Integer
For hugeIndex = 0 To dictionary.Count - 1
   Debug.Print items(hugeIndex)
Next

参照されたサイトでも(追加)すみません、こちら参照設定のみできます。と追記されており、変数をAs Dictionaryで定義した場合のみ、Items(0)等の直接参照が可能となります。

Answer 4

蛇足ですが、Itemの列挙の方法についていくつか
参照設定なしでも、dictionary.Itemsから直接取れなくは無いですよということで。

'dictionary だと型名と被って大文字小文字が崩れるので避けた方が無難
Dim dic As Object
Set dic = CreateObject("Scripting.Dictionary")

Dim hogeIndex As Long
Dim hogeString As String

With Sheet1.Cells
    For hogeIndex = 1 To 10
        hogeString = .Item(hogeIndex, 1).Text
        If Not dic.Exists(hogeString) Then
            dic.Add hogeString, hogeString
        End If
    Next hogeIndex
End With 'Sheet1.Cells


Debug.Print "方法1：添え字で直接取得"
    '毎回配列全体を取得→添え字アクセスなので遅そう
Dim hugeIndex As Long
For hugeIndex = 0 To dic.Count - 1
    Debug.Print dic.items()(hugeIndex)
Next hugeIndex


Debug.Print "方法2：値を配列化して添え字で取得"
    '今回の用途なら一番無難そう
Dim itemBuf() As Variant
itemBuf = dic.items()
For hugeIndex = LBound(itemBuf) To UBound(itemBuf)
    Debug.Print itemBuf(hugeIndex)
Next hugeIndex


Debug.Print "方法3：値を配列化してForEach"
    'VBAでは配列のForEachはForより遅いので微妙
Dim itm As Variant
For Each itm In dic.items()
    Debug.Print itm
Next itm