UnityのSubShader内でテクスチャの書き換えはできますか？

Question

何か解決したい問題があるわけではなくて、知識としての質問です。

例えば、以下のようなUnityのShaderファイルがあるとします。

Shader "Custom/Test"
{
	Properties
	{
		_MainTex ("Main Texture", 2D) = "white" {}
		_CopyTex ("Copy Texture", 2D) = "white" {}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float4 vertex : SV_POSITION;
				float2 uv : TEXCOORD0;
			};

			sampler2D _MainTex;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv);

				//Tex2D(_CopyTex, i.uv) = col;

				return col;
			}
			ENDCG
		}
	}
}

上記のように、フラグメントシェーダーでtex2Dを利用すれば、uv座標に対応する色情報を取得できます。

ふとした疑問なのですが、例えば、uv座標に対応する色情報を、書き換えるということはできないのでしょうか？
以下のように、値を代入するイメージです。

tex2D(_CopyTex, i.uv) = col;

ちなみに、このコードを試したところ、Unityで以下のようなエラーが表示されました。

Shader error in 'Custom/Test': undeclared identifier '_CopyTex' at line 47 (on d3d11)

Compiling Vertex program
Platform defines: UNITY_NO_DXT5nm UNITY_ENABLE_REFLECTION_BUFFERS UNITY_NO_CUBEMAP_ARRAY UNITY_USE_DITHER_MASK_FOR_ALPHABLENDED_SHADOWS UNITY_PBS_USE_BRDF1 UNITY_SPECCUBE_BOX_PROJECTION

恥ずかしながら、ShaderやGPUの仕組みがよくわかっていないので、質問いたしました。
「そんなことできないよ」ということであれば、できないとお答えいただけますと幸いです。

できるのだとすれば、フラグメントシェーダーから利用できる巨大なバッファのように扱えるかなと思いまして。

開発環境

• Unity 2017.3.0f3
• Windows 10
• DirectX 11.0

Answer 1

シェーダープログラムは多数が並列に実行されますが、通常は実行中のシェーダーコードが注目している1ピクセルにしか値を書き込まないので、不整合は起こらないでしょう。
しかし、あるテクスチャの任意の位置に値を書き込めるようにしたいとなると、複数のシェーダープログラムが同時に一つのピクセルへ値を書き込む可能性が出てきますので、調停のために処理が複雑化するはずです。

実行可能な環境の幅が狭まりますが、レンダーテクスチャのenableRandomWriteをオンにした上でSetRandomWriteTargetで書き込みターゲットに指定、シェーダー側では型名が「RWTexture...」で始まる変数で参照を受け取ることで、任意位置への書き込みも可能なようです（私はまだ使用経験がありませんが...）。

参考1: Unity の DX11 向け機能のサンプルを読んでみた - 凹みTips（「Random Write In Pixel Shader」の節）
参考2: Unity - Unity shader内でテクスチャの任意の座標に値を書き込む方法(51830)｜teratail

Comments

[segur]

ご回答ありがとうございます。ComputeShader(computeファイル)ではテクスチャの書き換えができるのですね。勉強になります。

ただ、ComputeShaderの場合、レンダリングパイプラインの外なので、UnityCG.cgincのUnityObjectToClipPos等の便利な関数が利用できない印象があります。(間違っていたらすみません。)

できれば、レンダリングパイプラインの中にあるFragmentShader(shaderファイル)でテクスチャの書き換えをしたいのですが、可能でしょうか？

[Bongo]

shaderファイルでも可能ではないでしょうか。凹みTipsさんの「Random Write In Pixel Shader」の紹介記事を挙げさせていただきましたが、これはコンピュートシェーダーではなくグラフィックス用のshaderファイルを使っているかと思います。

[segur]

迅速なご回答ありがとうございます。
紹介記事をしっかりと読み込めておりませんでした。大変申し訳ありません。
おっしゃる通り、RWTexture2Dをフラグメントシェーダで利用していますね。
動作確認してみます。

[segur]

- _MainTexから取得した色情報を_CopyTexに格納できる。
- _CopyTexから色情報を取得できる。
上記の機能の動作確認のため、Custom/Testのフラグメントシェーダーを以下のように書き換えたところ、正常に動作しました。
```
RWTexture2D<fixed4> _CopyTex;

fixed4 frag (v2f i) : SV_Target
{
fixed4 col = tex2D(_MainTex, i.uv);

int2 loc;
loc.x = int(i.uv.x * 255.0);
loc.y = int(i.uv.y * 255.0);

_CopyTex[loc] = col;

return _CopyTex[loc];
}
```
※シェーダーとして意味のあることはしていません。

ご回答ありがとうございました。

[segur]

今後、この質問を読む方がいるかもしれないので、念のため、補足します。

フラグメントシェーダーでRWTexture2Dを利用するためには、Shaderファイル内に `#pragma target 5.0` を書く必要がありました。これによって、実行環境の幅が狭まります。

DirectX 12(Windows)では動作しましたが、DirectX 11(Windows)とMetal(Mac,iOS)では動作しませんでした。

[PlayerSettings]→[Graphics APIs for Windows]で[Direct3D12]を先頭にすれば、DirectX 12が利用できます。