VBA sheetのセレクト情報をリセットしたいです。

Question

VBAのプログラム内で、RangeやCellsを指定して.selectをしている箇所が複数あるのですが、
処理が一通り走った後、参照先のsheetを見ると、プログラム内部でSelectした選択範囲がそのまま残っていて、見た目上あまり好ましくありません。

そういった残ってしまったsheetのselect状態を一括で解放する方法はありますか。

Worksheet(1).Activate
Range("A1").Select
Worksheet(2).Activate
Range("A1").Select
を10シートくらいに対応させてやるのもなんか、ダサいです。
まぁ上記処理ならFor文で回す方法で簡潔に書けるといえば書けるのですが、
なにか良い方法はありませんか。

Answer 1

全シート一律で処理するなら、saziさんからのアドバイスにもある通り、Sheets.Selectで全シート選択するのが簡単です。
（しかし私の環境ではsaziさん提供のコードではセルのSelect時にエラーが発生したため、別途投稿させていただきました。）

ループで処理する方法は好まれていないようですが、コードとしては大差ありません。
ループ処理にはループ処理のメリットもあり、１シートずつ判断が組み込めるので一律で変更したくないシートなどは対象外にすることもできます。

あとは好みの問題でしょうか。
好みでいえば、私はアクティブシートやセルの選択状態をマクロ処理で変えてしまうこと自体があまり好みではないので、極力それを行わないようなコードを書きますが…避けられないときもありますよね(^-^;

全シート一括設定のサンプル

Sheets.Selectを使った一括変更のサンプルです。
処理前にアクティブだったシートを最後にアクティブに戻す必要がなければ、shDef関連の部分は不要です。

Sub Sample()
    Dim shDef As Worksheet
    Set shDef = ActiveSheet '処理前のアクティブシートを退避
    
    '全てのシートを選択
    Sheets.Select
    '選択中のシートでA1セルを選択
    ActiveSheet.Range("A1").Select
    
    '処理前のアクティブシートを選択
    shDef.Select
End Sub

ループ処理のサンプル

こちらはループ処理で実装する場合のサンプルです。
処理前のアクティブシートに戻す処理は組み込んでいません(^-^;

Sub Sample2()
    Dim sh As Worksheet
    '全てのシートをループ処理
    For Each sh In Worksheets
        'シートをアクティブ化しないとセルが選択できない
        sh.Activate
        'A1セルを選択
        sh.Range("A1").Select
    Next sh
End Sub

以上、参考になれば幸いです。

Comments

[sazi]

>jawaさん
>しかし私の環境ではsaziさん提供のコードではセルのSelect時にエラーが発生したため
そうでしたか。
リファレンスでは、Sheets(array("Sheet1", "Sheet2").Select のような内容ですが、
Sheets.Select　として動作したので、その内容での回答としました。
ただ、Sheets.Selectの記述については文献が無いんですよね。
回答追記しておきます。

[jawa]

Sheets.Selectでシートの全選択はできているのですが、その状態でのRange("A1").Selectがエラーとなりました。
複数シートを選択している状態から対象シートを明示しないRange指定を行うとオブジェクト定義エラーとなるようです。

ActiveSheet.Range("A1").Selectならエラーとならず全シート対象に処理してくれるようでした。
対象シートを明示しないRangeはアクティブシートを対象にするものと思っていましたが、複数シート選択状態ではそうでもないようですね。

[sazi]

うーん。
マクロの記録で行ってもセル選択部分は、シートの指定は行われていないので、Sheets(array(シート)).Selectでシートを指定すればエラーにならないような気がします。
エラーが発生しない環境なので、確認はできませんが。。。

[jawa]

ちなみに私の環境(Windows7/Excel2010)で
①複数シート(シート１～３)を選択
②A1セルをクリック
という操作をマクロ記録した結果は、
```
Sheets(Array("Sheet1", "Sheet2", "Sheet3")).Select
Sheets("Sheet3").Activate
Range("A1").Select
```
となりましたが、結論から言うとこのマクロは元の操作を再現できていません。

記録のために操作したときは全シートでA1セルが選択されましたが、記録したマクロを実行してもシート３しか反映されませんでした。
コードを見ると、シートを複数選択したときの一番表のシート（シート３）のActivateが記述されていますので、当然の結果と言えます。

これによりシート３にしか反映されませんが、単一シートのためRange("A1").Selectもエラーにならないという状態のようです。

バージョンによって、Activesheetの暗黙指定のあたりの問題が解消されている可能性はありますね。

[sazi]

>jawaさん
確認ありがとうございます。
私の環境は(Windows10,excel2007)です。
Sheets("Sheet3").Activateをコメントにするとどうなるでしょうか？

[jawa]

複数シート選択状態なので、やはりエラーになりますね(^-^;

[sazi]

確認ありがとうございました。
では、jawaさんのバージョンのほうが新しいので、厳密さが進んでいるということですね。

[jawa]

なんか個人的には2007の動きの方がしっくりくる気がしてしまいます。
わざわざActiveSheetと明示するのは、違和感がありますね(^-^;

Answer 2

これでできますね。

 Sheets.Select
 Range("A1").Select
 Sheets(1).Select

追記

上記のSheets.Selectはリファレンスには載っていない記述です。
エラーになったというコメントが有りましたので、正式な内容での追記をしておきます。

 x = Array("Sheet1","Sheet1") 'シートが可変ならこの部分をループで
 Sheets(x).Select
 Range("A1").Select
 Sheets(1).Select

※検証環境(Windows10,excel2007)
環境依存があるかもしれませんので、注意して下さい。

Answer 3

シートを処理したときに名前を保存して置いて
あとで処理したシートのみ選択位置を変えるのはどうでしょうか。

Sub tset()

    Dim ShName As String
    Dim ShArray() As String
    Dim NowSheet As Worksheet
    Dim i As Integer
    
        Set NowSheet = ActiveSheet
        
'プログラム上の処理
        For i = 1 To 5
            If i Mod 2 = 1 Then
                '処理したシートのみ名前を保存
                ShName = ShName & Chr(9) & Sheets(i).Name
            End If
        Next i
        
        '最初のいらないタブを除いて配列化
        ShArray = Split(Mid(ShName, 2), Chr(9))
        
        
        Sheets(ShArray).Select
        Range("A1").Select
        NowSheet.Select
        
End Sub

Comments

[ExcelVBAer]

余談ながら、Chr(9) を vbTab に変えた方が分かりやすいかと。

[kamikazelight]

そうですね

Answer 4

そもそも、プログラム内のSelectは必要ですか？

個人的には滅多にSelectすることがありません。
恐らく不要なSelectなので、無くす方向で考えるのが自然だと思います。

ただ、もしSelectしなければならない場合があり、
元の状態に戻したいときは、
SelectionをRange型変数に確保しておき
Select等の処理後に上記RangeでSelectし直したりします。
※選択状態のものが常にRangeとは限らないのでエラー回避してください。

シートの選択状態をわざわざA1にしたいという要求のある環境なのであれば、
For Each Sheet in ThisWorkBook.WorkSheets
等でシートを回し、各シートで選択状態にしていけばいいでしょう。
※シートが非表示だったりすると選択ができませんので、
環境に沿った形で実装するのが無難でしょう。

Answer 5

Application.ScreenUpdating = False
for i = 1 to worksheets.count
 sheets(i).activate
 range("A1").select
Next
Application.ScreenUpdating = true

これはだめですか？