Dir関数の呼び出しでファイル名の昇順にマッチングしたい

Question

フォルダ内に__FILENAMEyyyymmddHHMMSS.txt__という名前のテキストファイルが複数あり、ファイル数が100個を超えた場合日付が古いものを消すロジックを実装したいです。

そのため以下のようなコードで実装していますが、Dir関数で返るファイル名がファイル名の昇順になりません。
これを操作することは出来ないでしょうか？

    
    'バックアップフォルダー内のファイル数をカウント
    Dim intFileCNT As Integer
    intFileCNT = 0
    Dim strBackupFileName As String
    strBackupFileName = Dir("フォルダパス")
    While strBackupFileName <> ""
        If Left(strBackupFileName, 8) = "FILENAME" Then
            intFileCNT = intFileCNT + 1
        End If
        strBackupFileName = Dir()
    Wend
    
    '古いバックアップファイルの削除
    strBackupFileName = Dir("フォルダパス")
    While intFileCNT > 100                  '最大保存ファイル数は100個
        If Left(strBackupFileName, 8) = "FILENAME" Then
            Call Kill("フォルダパス" & strBackupFileName)
            intFileCNT = intFileCNT - 1
        End If
        strBackupFileName = Dir()
    Wend

Answer 1

前に同じ内容で困った時にどなたかのHPで教えて頂いた
「StrCmpLogicalW」で、エクスプローラに近いソートができたような。

ひょっとしたら環境によって異なるのかもですが。。。

Declare Function StrCmpLogicalW Lib "SHLWAPI.DLL" (ByVal lpStr1 As String, ByVal lpStr2 As String) As Long

Public Function SortByIntuitiveFileName(ByRef PathAry As Variant)
'+ エクスプローラで表示されている順に

    Dim i           As Long
    Dim j           As Long
    Dim TempPath    As String
    Dim ConvAry()   As String
    
    If IsArray(PathAry) = False Then Exit Function
    
    ReDim ConvAry(LBound(PathAry, 1) To UBound(PathAry, 1))
    
    For i = LBound(PathAry, 1) To UBound(PathAry, 1)
        ConvAry(i) = StrConv(CStr(PathAry(i)), vbUnicode)
    Next
    
    For i = LBound(PathAry) To UBound(PathAry)
        
        For j = i To UBound(PathAry)
            
            If StrCmpLogicalW(ConvAry(i), ConvAry(j)) > 0 Then
                
                TempPath = PathAry(i)
                PathAry(i) = PathAry(j)
                PathAry(j) = TempPath
                
            End If
            
        Next
        
    Next

End Function

Comments

[Taishi2002]

ありがとうございます。
エクスプローラの特殊なソートが使える関数があるんですね。

Answer 2

ディスクのフォーマット形式によって取得順は異なるようです。
http://officetanaka.net/excel/vba/file/file07.htm

なので現状通りDir関数を使うのであれば、一旦取得結果を配列に格納してから、自力ソートするしかないと思います。

Dir関数ではなくFileSystemObjectを使うとソートは可能なようですが、コーディングにひと手間必要です。
とは言っても難しくはないと思います。
詳しくはこちらを参照。
https://kuroeveryday.blogspot.jp/2013/10/FileSystemObjectSort.html

追記
Dir関数で行うということでしたので、ソート処理について追記しておきます。
ファイル名をため込むのには、配列を使うよりもArrayListを使うと便利です。
とりあえずバックアップフォルダー内の処理だけ書き換えてみましたので参考にどうぞ。

    Dim intFileCNT As Integer
    Dim strFileName As String
    intFileCNT = 0

    'バックアップフォルダー内のファイル数をカウント
    Dim strBackupFileNames As Object
    Set strBackupFileNames = CreateObject("System.Collections.ArrayList")
    strFileName = Dir("フォルダパス")
    While strFileName <> ""
        strBackupFileNames.Add strFileName
        If Left(strFileName, 8) = "FILENAME" Then
            intFileCNT = intFileCNT + 1
        End If
        strFileName = Dir()
    Wend
    strBackupFileNames.Sort
    
    ' 確認
    For Each tmp In strBackupFileNames
        Debug.Print tmp
    Next

Comments

[Taishi2002]

ありがとうございます。
FileSystemObjectでも良さそうですが、Dir関数で一通り取得した後に自力ソートしてみます。

[Taishi2002]

重ね重ねありがとうございます。
VBAから.NET Framework クラス ライブラリの機能の一部を使用できるのですね。
勉強になりました。

Answer 3

Dirの出力順をなんとかする事は出来ない（多分物理順）ので、ソートするしかないですね。
配列のソート関数とかは無いと思うので、自分でソート処理を書く事になるかと。取得する度に、位置を決めてずらすんでしょうか。

変数宣言を省略するとこんな感じか。

n = 1
files(0) = Dir("*")
Do
    file = Dir()
    If file = "" Then Exit Do
    For i = 0 To n - 1
        If file < files(i) Then
            For j = n - 1 To i Step -1
                files(j + 1) = files(j)
            Next
            Exit For
        End If
    Next
    files(i) = file
    n = n + 1
Loop
For i = 0 To n - 1
    Debug.Print files(i)
Next

Comments

[Taishi2002]

ありがとうございます。
For j = n - 1 To i Step -1
という部分はどういう意味なのでしょうか。

[otn]

うーむ、見た通りの意味なのですが。

[Taishi2002]

Step -1がよくわかっていませんでしたが、要素数の大きいものから処理するということなんですね。