【Terraform】Terraform apply時にstatus code: 400が表示され、applyが通りません

Question

実現したいこと

Terraform applyを通したい

前提

フォルダ構成は下記の通りです。
(stg,prodはdevと同じ構成)

git管理フォルダ
└env
 |  └dev
 |    └main.tf
 |    └variables.tf
 |    └terraform.tfvars
 |  └stg
 |  └prod
 |
 └modules
 　└vpc
       └main.tf
       └variables.tf
       └output.tf
   └ec2
       └main.tf
       └variables.tf
       └output.tf
   └aurora
       └main.tf
       └variables.tf

発生している問題・エラーメッセージ

Error: error creating Security Group (sg_aurora): InvalidVpcID.NotFound: The vpc ID 'aws_vpc.vpc.id' does not exist
│	status code: 400, request id: 00d45532-5ed5-4163-a3df-9f395fe60fb0

│  with module.aurora.aws_security_group.sg_aurora,
│  on ../../module/aurora/main.tf line 2, in resource "aws_security_group" "sg_aurora":
│   2: resource "aws_security_group" "sg_aurora" {


Error: Error creating DB Subnet Group: InvalidParameterValue: Some input subnets in :[var.private_sub1, var.private_sub2] are invalid.
│	status code: 400, request id: 4494b123-a94f-4d6f-ba1d-330602baad17

│  with module.aurora.aws_db_subnet_group.db_group,
│  on ../../module/aurora/main.tf line 32, in resource "aws_db_subnet_group" "db_group":
│  32: resource "aws_db_subnet_group" "db_group" {


│Error: error creating Security Group (sg-ec2): InvalidParameterValue: Value (sg-ec2) for parameter GroupName is invalid. Group names may not be in the format sg-*.
│	status code: 400, request id: dd706655-1387-4caf-a674-246383e4eef9

│  with module.ec2.aws_security_group.sg_ec2,
│  on ../../module/ec2/main.tf line 2, in resource "aws_security_group" "sg_ec2":
│   2: resource "aws_security_group" "sg_ec2" {

エラー対象のコード

ec2/main.tf

#　セキュリティグループ作成
resource "aws_security_group" "sg_ec2" {
  name        = "sg-ec2"
  description = "Allow ssh inbound traffic"
  vpc_id      = var.vpc_id
  tags = {
    Name = "${var.env}-sg"
  }

  ingress {
    description = "SSH from VPC"
    from_port   = 22
    to_port     = 22
    protocol    = "tcp"
    cidr_blocks = ["118.241.238.210/32"]
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
}

#　インスタンス作成
resource "aws_instance" "ec2" {
  ami                    = "ami-02c3627b04781eada"
  instance_type          = "t2.micro"
  key_name               = "samurai"
  vpc_security_group_ids = [aws_security_group.sg_ec2.id]

  root_block_device {
    volume_size = 8
    volume_type = "gp2"
  }

  subnet_id = var.public
  tags = {
    Name = "${var.env}-ec2"
  }
}

ec2/outputs.tf

output "env" {
  value = var.env
}

output "vpc_id" {
  value = "aws_vpc.vpc.id"
}

output "private_sub1" {
  value = "aws_subnet.private1.id"
}

output "private_sub2" {
  value = "aws_subnet.private2.id"
}

dev/main.tf

terraform {
  required_version = ">= 0.12"
  backend "s3" {
    bucket = "dev-terraform-module"
    key    = "terraform.tfstate"
    region = "ap-northeast-1"
  }
}

provider "aws" {
  region = "ap-northeast-1"
}

# variables.tfの値を参照する
# vpcモジュールを呼び出す
module "vpc" {
  source = "../../module/vpc"
  env    = var.env
  cidr   = var.cidr
}

# ec2モジュールを呼び出す
module "ec2" {
  source = "../../module/ec2"
  env    = var.env
  vpc_id = module.vpc.vpc_id
  public = module.vpc.public
}

#auroraモジュールを呼び出す
module "aurora" {
  source       = "../../module/aurora"
  env          = var.env
  vpc_id       = module.vpc.vpc_id
  private_sub1 = module.vpc.private_sub1
  private_sub2 = module.vpc.private_sub2
  sg_ec2       = module.ec2.sg_ec2
}

aurora/variables.tf

riable "env" {
 type = string
}

variable "vpc_id" {
 type = string
}

variable "private_sub1" {
 type = string
}

variable "private_sub2" {
 type = string
}

variable "sg_ec2" {
 type = string
}

aurora/main.tf

# セキュリティグループ作成
resource "aws_security_group" "sg_aurora" {
  name   = "sg_aurora"
  vpc_id = var.vpc_id
  tags = {
    Name = "${var.env}-sg_aurora"
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
}

#許可するセキュリティルール
resource "aws_security_group_rule" "sb_rule_aurora" {
  type      = "ingress"
  from_port = 3306
  to_port   = 3306
  protocol  = "tcp"

  #inしていいセキュリティグループID
  source_security_group_id = aws_security_group.sg_ec2.id

  #このセキュリティルールの関連付け対象であるセキュリティグループ
  security_group_id = aws_security_group.sg_aurora.id
}

# dbサブネットグループ作成
resource "aws_db_subnet_group" "db_group" {
  name       = "tf_db_group"
  subnet_ids = [var.private_sub1, var.private_sub2]

  tags = {
    Name = "terraform module subnet group"
  }

}

# auroraリソース作成
resource "aws_rds_cluster" "aurora_terraform_module" {
  cluster_identifier     = "aurora-cluster"
  engine                 = "aurora-mysql"
  engine_version         = "5.7.mysql_aurora.2.10.2"
  database_name          = "mydb"
 #username,passwordは変えています
  master_username        = "・・・・" 
  master_password        = "・・・・"
  db_subnet_group_name   = aws_db_subnet_group.db_group.name
  vpc_security_group_ids = aws_security_group.sg_aurora.id
}

調べた、実践したこと

ec2/main.tfはsg-*という記載がダメだということで、 sg_ec2に書き換えました。

他の2種類のエラーについてはdev/main.tfに、”各moduleを参照する"という意味合いで書いたコードの書き方が間違っていると思い、terraform registryのData Source: aws_vpcを参考に書き換えましたが、そうするとplanが通りませんでした。

書き換えた内容（Data Source: aws_vpcを参考に）

aurora/variables.tfの

variable "vpc_id" {
  type = string
}

を

variable "vpc_id" {}

data "aws_vpc" "vpc" {
  id = var.vpc_id
}

に書き換え、

dev/main.tfの

module "aurora" {
  source       = "../../module/aurora"
  env          = var.env
  vpc_id       = module.vpc.vpc_id
  private_sub1 = module.vpc.private_sub1
  private_sub2 = module.vpc.private_sub2
  sg_ec2       = module.ec2.sg_ec2
}

を

module "aurora" {
  source       = "../../module/aurora"
  env          = var.env
  vpc_id       = data.aws_vpc.vpc.id
  private_sub1 = module.vpc.private_sub1
  private_sub2 = module.vpc.private_sub2
  sg_ec2       = module.ec2.sg_ec2
}

に書き換えました。

お願いしたいこと

400エラーがクライアント側に問題があるという意味で、variablesやoutputの書き方が間違っていると思いました。
着目点の間違いや解決方法を教えてください。

Answer 1

自分もTerraform勉強中なので見当違いだったらすいませんが、気になったところを書いておきますmm

• aurora/variables.tf で data を書いていますが、dataはすでにあるリソースを参照するために使うものなので、今回は module.vpc.vpc_id をそのまま渡す元の形で良いと思いました。dataでもできると思いますが、その場合は、 dev/main.tf の方に書いたほうが良いと思います。

• ec2/output.tf（これはvpc/outputs.tfのことかなと思って見てました）で、valueをダブルクォートで囲っているのが気になりました。これだと"aws_vpc.vpc.id"という文字列になっちゃいそうです。

---

各variables.tfの中身がわからないですが、基本的には、下記の流れで値を渡せば良いかなと思います。

• ec2 / auroraのvariables.tfで、値を受け取れるようにする

variable "vpc_id" {
  type = string
}

• dev/main.tfで値を渡す

module "aurora" {
  ...
  vpc_id = module.vpc.vpc_id
  ...
}

• 各moduleのmain.tf内で値を利用

resource "aws_security_group" "sg_aurora" {
  ...
  vpc_id = var.vpc.id
  ...
}

Comments

[sakura]

回答ありがとうございます！
仰っていた通り、valueを"　"で囲っていたことが問題でした。
訂正したところ問題なくapplyできました！
ありがとうございました！