ACCESSでExcelファイルを新規作成した後にクエリ内容をエクスポートするには

Question

実現したいこと

ACCESSVBAで、EXCELファイルを新規作成した後にその新規作成したEXCELファイルのワークシートにクエリの内容をエクスポートできるようにしたい。

前提

今現在、ACCESSVBAでExcelファイルを新規作成した後に、クロス集計クエリの内容をExcelにエクスポートするプログラムをコーディングしています。
しかし、Excelファイルを新規作成した後に名前を付けて保存したファイルを指定しようとすると、オブジェクトが見つかりません。というエラーが出ました。原因を調べたところ、ファイル名を付ける変数FILEPATHが文字列型だったことが原因であることが分かりました。
そこで新たにオブジェクト変数VPATHを定義して、ファイル名をそれに代入してオブジェクト変換できるか試してみたのですが、今度は「オブジェクト変数またはwithブロック変数が設定されていません。」というエラーが出ます。
ファイル名を付けた変数の値でオブジェクトとして呼び出すにはどういったコードにすればいいのでしょうか。
分かりづらい質問ですがよろしくお願いします。

エラーメッセージ

実行時エラー'91'
オブジェクト変数またはWith ブロック変数が設定されていません。

該当のソースコード

Dim XLAPP As Object                'Excelオブジェクト向け変数
Dim WB As Object                   'Excelワークブック向け変数
Dim WS As Object                   'Excelワークシート向け変数
Dim FILEPATH As String             'Excel保存先パス向け変数
Dim VPATH As Object                'クエリのExcelへのエクスポート先向け変数


'Excelを起動する
Set XLAPP = CreateObject("Excel.Application")

'開いたExcelでワークブックを追加する。
Set WB = XLAPP.Workbooks.Add

'一つ目のワークシートを参照する。
Set WS = WB.WORKSHEETS(1)

'ワークシートの名前を変更する。
WS.Name = "商品名と明細金額"

'Excelファイルの保存先を決める。
'ファイルを今日の日付の「YYMMDD」形式とする。
FILEPATH = CurrentProject.Path & "\" & Format(Date, "YYMMDD") & ".xlsx"

'ワークブックを保存する。
WB.SAVEAS FILEPATH

'オブジェクトVPATHにワークブック名FILEPATHを代入する。
VPATH = FILEPATH

'ワークブックにクエリ「商品名と明細金額」
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel12Xml, "商品名と明細金額", FILEPATH, True

'ワークブックを閉じる。
WB.Close

'変数を解放する。
Set XLAPP = Nothing
Set WB = Nothing
Set WS = Nothing

'作成したExcelファイルを開くか確認する。

If MsgBox("作成したExcelファイルを開きますか？", vbYesNo) = vbYes Then

    Shell "Excel.exe " & FILEPATH, vbNormalFocus
    
End If

End Sub

試したこと

ここに問題に対して試したことを記載してください。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Comments

[hatena19]

「ファイル名を付ける変数FILEPATHが文字列型」というのは問題ないです。原因は別です。
ファイル名は文字列でオブジェクトでないので、
「そこで新たにオブジェクト変数VPATHを定義して、ファイル名をそれに代入してオブジェクト変換できるか試してみた」
ということはできませんし、無意味です。
この追加したコードは削除してください。
そのうえでそのコードを実行して「オブジェクトが見つかりません。」というエラーがどの行ででるか質問に追記してください。

[AKI_TADA]

コメントありがとうございます。
追加したコードを削除してもう一度実行してみたところ、「ワークブックにクエリ『商品名と明細金額』をエクスポートする。」の行で「オブジェクトが見つかりません。」というエラーが出ました。

[AKI_TADA]

その行のコードも貼っておきます。

DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel12Xml, "商品名と明細金額", FILEPATH, True

Answer 1

ワークブックを開いたまま、そこにエクスポートしようとしているのが原因のようです。
閉じてからエクスポートすればエラーはでないでしょう。

'ワークブックを保存する。
WB.SAVEAS FILEPATH

'オブジェクトVPATHにワークブック名FILEPATHを代入する。
VPATH = FILEPATH

'ワークブックを閉じる。
WB.Close

'ワークブックにクエリ「商品名と明細金額」
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel12Xml, "商品名と明細金額", FILEPATH, True

ただし、空の「商品名と明細金額」シートの後に「商品名と明細金額1」というシートに出力されます。

新規のワークブックにエクスポートするなら、わざわざワークブックを作成しなくても、エクスポート(TransferSpreadsheet)だけで新規のワークブックにエクスポートできます。

   Dim FILEPATH As String                       'Excel保存先パス向け変数
    'Excelファイルの保存先を決める。
    'ファイルを今日の日付の「YYMMDD」形式とする。
    FILEPATH = "C:\TEST\" & Format(Date, "YYMMDD") & ".xlsx"
    
    '新規ワークブックにクエリ「商品名と明細金額」をエクスポート
    DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel12Xml, "テーブル1", FILEPATH, True

    '作成したExcelファイルを開くか確認する。
    If MsgBox("作成したExcelファイルを開きますか？", vbYesNo) = vbYes Then
        Shell "Excel.exe " & FILEPATH, vbNormalFocus   
    End If