Excel VBA csv読込→ランキング形式で出力

Question

前提

Excel VBAにてcsvファイルを1行ずつ読み込み、
その内容をまとめたものをエクセルに出力する処理を作成しております。

実現したいこと

出力されるエクセルには売上個数が多い順にランキング形式に並べたいです。
また、csvファイルを1行ずつ読み込んだ際に、
「果物」「地域」が一致する場合は「売上個数」と「値段」に加算するようにしたいです。

読取csvファイルの例、出力したいエクセルファイルのイメージは以下の通りです。

・csvファイル
|果物|地域|売上個数|値段|
|みかん|Ａ地域|10|1000|
|みかん|Ａ地域|20|2000|
|みかん|B地域|15|1500|
|りんご|Ａ地域|8|800|
|りんご|Ａ地域|9|900|
|メロン|Ｃ地域|1|3500|

・出力したいエクセルファイル
|順位|果物|地域|売上個数|値段|
|1|みかん|Ａ地域|30|3000|
|2|りんご|Ａ地域|17|1700|
|3|みかん|B地域|15|1500|
|4|メロン|C地域|1|3500|

発生している問題・エラーメッセージ

If文の複雑化の解消方法
別の記述方法模索中

該当のソースコード

Excel VBA

Dim i As Long
Dim csvData() As Variant

'csvファイルを１行ずつ読取
For i = 2 To Ubound(csvData, 1)

'出力するエクセル側のA2(果物の最初の列)とB2(地域の最初の列)がブランクの場合
If sheet.Range("A2").Value = "" And sheet.Range("B2").Value = "" Then
    'csvファイルの１行目のカラムを取得し、それぞれのセルに値を代入 ※順位1の行に値を代入
    '果物
    sheet.Range("A2").Value = csvData(i, 1)
    '地域
    sheet.Range("B2").Value = csvData(i, 2)
    '売上個数
    sheet.Range("C2").Value = csvData(i, 3)
    uVal = sheet.Range("C2").Value
    '値段
    sheet.Range("D2").Value = csvData(i, 4)
    nVal = sheet.Range("D2").Value

'出力するエクセル側のA2(果物の最初の列)とB2(地域の最初の列)とcsvファイルのカラム1(果物),2(地域)列目が一致した場合
ElseIf　sheet.Range("A2").Value = csvData(i, 1) And sheet.Range("B2").Value =  csvData(i, 2) Then
    '売上個数(果物名と地域名が一致した場合は売上個数を加算)　※順位1の行に値を代入
    uVal = uVal + csvData(i, 3)
    sheet.Range("C2").Value = uVal
    '値段(果物名と地域名が一致した場合は値段を加算)
    nVal = nVal + csvData(i, 4)
    sheet.Range("D2").Value = nVal

'出力するエクセル側のA2(果物の最初の列)とB2(地域の最初の列)とcsvファイルのカラム1(果物),2(地域)列目がどちらかが一致しない場合
ElseIf　sheet.Range("A2").Value <> csvData(i, 1) Or sheet.Range("B2").Value <>  csvData(i, 2) Then
    'それぞれの項目を一つ下の行に代入　※順位2の行に値を代入
    '果物
    sheet.Range("A3").Value = csvData(i, 1)
    '地域
    sheet.Range("B3").Value = csvData(i, 2)
    '売上個数
    sheet.Range("C3").Value = csvData(i, 3)
    '値段
    sheet.Range("D3").Value = csvData(i, 4)

ElseIf...　(果物名または地域名が異なるたびにIf文作成が必要)

EndIf

試したこと

上記のコードのようにIf文でエクセル側の値とcsvの値を比較して一致不一致を判断しておりましたが、
果物名または、地域名どちらかが異なる場合や両方とも異なる場合に都度If文を作成し、代入するセルを指定しなければなりません。

また、エクセルファイルの２行目以降の項目で、果物名と地域名が一致した際に加算する方法も不明です。
(上記例の２位りんごのような場合)

上記以外の方法でマクロ処理内で実行する方法はございますでしょうか。

ご回答をお願いいたします。

Comments

[hatena19]

エクセルの機能を活かして、OpenBook でCSVファイルを読み込んで、あとは、関数や並べ替えの機能で簡単にできると思いますが、それではだめですか。あるいは、パワークエリでもできますね。
VBAのみでというなら、Dictionary を使うといいでしょう。

[hatena19]

あと、「csvファイルを1行ずつ読み込み」とのことですが、 csvData という二次元配列にすでに読み込み済みということでしょうか。

[sk.exe]

https://teratail.com/questions/8avgve7q3txv5f

上記のスレッドと全く同じ内容の質問をされているようですが、同じ人物が違うアカウントで投稿されているのでしょうか。

[Ymnaik]

>hatena19さん
ご回答いただきありがとうございます。
VBAのみで処理をさせたいので、Dictionaryについて調べてみます。
[あと、「csvファイルを1行ずつ読み込み」とのことですが、 csvData という二次元配列にすでに読み込み済みということでしょうか。]
はい。csvファイルは既に読み込み済です。

[Ymnaik]

＞sk.exeさん

はい。上記の通りです。
以前のアカウントにログインできなくなったため、別で質問させていただきました。

[hatena19]

エクセルのバージョンはなんでしょうか。質問に追記してください。

[Ymnaik]

バージョンは016を使用しております。

[Ymnaik]

訂正します。
バージョン2016の誤りです。

失礼いたしました。

Answer 1

下記でどうでしょう。

グループ毎の集計は、Dictionaryを使いました。
並べ替えと順位はエクセルの機能を使いました。

Sub Sample()
    Dim csvData() As Variant
    'csvファイルを１行ずつ読取
    '略
    
    Dim dic As Object
    Set dic = CreateObject("Scripting.Dictionary")
    
    Dim i As Long, sKey As String, Ary
    For i = 2 To UBound(csvData, 1)
        sKey = csvData(i, 1) & csvData(i, 2)
        If dic.exists(sKey) Then
            Ary = dic(sKey)
            Ary(2) = Ary(2) + csvData(i, 3)
            Ary(3) = Ary(3) + csvData(i, 4)
            dic(sKey) = Ary
        Else
            dic(sKey) = Array(csvData(i, 1), csvData(i, 2), csvData(i, 3), csvData(i, 4))
        End If
    Next
    Range("G1").Resize(1, 4).Value = WorksheetFunction.Index(csvData, 1)
    Range("G2").Resize(dic.Count, 4).Value = WorksheetFunction.Index(dic.Items, 0)
    Range("F1").Value = "順位"
    With Range("F1").CurrentRegion
        .CurrentRegion.Sort Key1:=Range("I1"), Order1:=xlDescending, Header:=xlYes
        Range("F2").Value = 1
        Range("F2").AutoFill Destination:=Range("F2:F" & .Rows.Count), Type:=xlFillSeries
    End With
End Sub

Comments

[Ymnaik]

ありがとうございました。

こちら解決できました。