文字列切り取りから取得した値を使用する方法について

Question

お世話になっております。
特定のフォルダ内を検索して、下記のような形式のファイル名の一部を切り取り、ファイル名の一部の文字列を含む名前のフォルダの存在チェックをする処理をバッチ処理で作成しようとしています。

使用するファイル名の形式
「0000_11111_22222.pdf」

具体的には以下のようなコードを作成しています。

rem 初期化
set OUTPUT_PATH=D:\TEST
set HENSU1=0
set HENSU2=0

for %%a in (*.pdf) do (

	for /f "delims=_ tokens=1-2" %%A in ("%%a") do (
		rem %%Aには「0000」、%%Bには「11111」が取得されている
		rem ここで%%Aと%%Bが変数に格納されない
		set HENSU1=%%A
		set HENSU2=%%B
		echo 1:%OUTPUT_PATH%\%%B:~0,4%
			→①　実行結果：D:\TEST\11111:~0,4　…　文字列切り取りができていない
		echo 2:%OUTPUT_PATH%\%%B:~0,4%\%%A
			→②　実行結果：D:\TEST\11111:~0,4A　…　%%Aの値が参照できていない
		if not exist %OUTPUT_PATH%\%%B:~0,4% (
			mkdir %OUTPUT_PATH%\%%B:~0,4%
		)
	)

このように、特定のフォルダ内を検索し、検索対象のファイル名の文字列を「_」で区切り、%%Aと%%B内の文字列を変数に格納して後続の処理で文字列を連結、切り取り等の操作をしたいと考えています。
なのですが、上記を実行してもHENSU1、HENSU2には「0」が格納されていて%%Aと%%Bの文字列が変数に取得されていないようです。

教えていただきたいことは以下です。
・①のように%%B内の値の文字列の切り取りなどの操作はできないのでしょうか。
・②のように%%Aの値が参照できないのはなぜなのでしょうか。
・%%A、%%Bで取得した値を使用するためにはどのようなやり方をすればよいのでしょうか。

お手数をおかけしますが、有識者の方おられましたらご教示ください。

Answer 1

まず、バッチスクリプトの文法は、一般のプログラミング言語の常識が通じない部分があるので、
・バッチスクリプトは簡単なケースだけしか使わない
・じっくりバッチスクリプトの文法を理解して熟練者になる
のどちらの方針で臨むかを最初に決めた方が良いです。

このレベルの処理をするなら、バッチスクリプトの熟練者を目指すのでなければ、他の言語をお勧めします。
・PowerShell
・VBScript （廃止予定なので、5年、10年後に使えなくなってもいい場合）
・OfficeのVBA
・WSL1またはWSL2 の bash等（デフォルトでは未インストールのはずなのでMSからインストール要）
・Windows非標準の各種プログラミング言語（インストール可能なら）
あるいは、後出の「案2」だとバッチスクリプトでもそれほど熟練者じゃなくてもいいかも。そんな気が強くしてきました。

以下、バッチスクリプトでやる場合の説明。
「環境変数」は「変数」とついてますが、一般のプログラミング言語の変数とは少し違います。

上記を実行してもHENSU1、HENSU2には「0」が格納されていて

とお書きですが、掲載のコードには%HENSU1% %HENSU2%がないので、おそらく、コピペミスで、実際にHENSU2の値を確認したのは、

rem 初期化
set OUTPUT_PATH=D:\TEST
set HENSU1=0
set HENSU2=0

for %%a in (*.pdf) do (

	for /f "delims=_ tokens=1-2" %%A in ("%%a") do (
		set HENSU1=%%A
		set HENSU2=%%B
		echo 1:%OUTPUT_PATH%\%HENSU2:~0,4%
		echo 2:%OUTPUT_PATH%\%HENSU2:~0,4%\%%A
		if not exist %OUTPUT_PATH%\%HENSU2:~0,4% (
			mkdir %OUTPUT_PATH%\%HENSU2:~0,4%
		)
	)
)

のようなコードだったのではないかと思います。
6行目のforから末尾の)までが1つの大きな文です。%HENSU2%や%HENSU2:~0,4%の値取り出しは、一般の言語のようにその文に制御か移った時ではなくて、6行目のforから末尾までの大きな1文の構文解析の直前に行われます。この時点では値は0なので、そのように変数名が値0に置き換わります。その次にfor文が実行されます。C等をご存じなら文単位ではありますが#defineで定義するマクロみたいなものと思ってください（構文解析前に置換されるという意味で）。

このことは、set /?で表示される環境変数についての説明の後半に例文付きで分かり易く説明されています。

対策としては、
案1：set /?に出てくる「遅延環境変数の展開」を使う（普通の言語の「変数」と同じに使える））
案2：大きな文を作らず、小さい文を沢山並べる
の2通りあります。
案1の方針だと、

rem ↓ 案1だとこのsetlocalが重要
setlocal enabledelayedexpansion

set OUTPUT_PATH=D:\TEST
set HENSU1=0
set HENSU2=0

for %%a in (*.pdf) do (
	for /f "delims=_ tokens=1-2" %%A in ("%%a") do (
		set HENSU1=%%A
		set HENSU2=%%B
		echo 1:%OUTPUT_PATH%\!HENSU2:~0,4!
		echo 2:%OUTPUT_PATH%\!HENSU2:~0,4!\%%A
		if not exist "%OUTPUT_PATH%\!HENSU2:~0,4!" (
			mkdir %OUTPUT_PATH%\!HENSU2:~0,4!
		)
	)
)

if not existのif文の構文解析は、!HENSU2:~0,4!の変数展開の前に行われるので、ファイル名の所を二重引用符で囲む必要があります（これは構文解析時にはクォートされてないカンマなどは空白扱いされるため）。案1だと、こういう細かい配慮が必要になるケースがあります。

私自身は案2を使うことが多いのですが、案2は、「複数の文をまとめる括弧( )を使わない」、あるいは厳密には、「複数の文をまとめる括弧( )の中では括弧内で更新される環境変数の%による参照をしない」ということで、

前略
for %%a in (*.pdf) do (
	for /f "delims=_ tokens=1-2" %%A in ("%%a") do call :FOO %%a %%A %%~B
)
exit /b

:FOO
rem ↓このFILENAMEが  %%a 相当
set FILENAME=%1
set HENSU1=%2
set HENSU2=%3
以下略

のようにforの中味をサブルーチン:FOOにして、:FOOの中では文をまとめる括弧を使わずに書きます。

なお、%%B:~0,4%のような、「forの制御変数」に対しての部分文字列取り出しや文字列置換機能はありません。

Comments

[taka0920]

回答いただき、ありがとうございました。
初めはVBScriptで作成しようと考えたのですが、社内の仕組みで使用する関係上、Microsoft非推奨のものは使うことができず、PowerShellは知見がまったくないため、コマンドラインのバッチ処理で作成する方向となりました。
丁寧に教えていただきありがとうございました。
普通言語の変数のように扱える案1のほうで作成してみようと思います。

[otn]

今のコードを書き換えるなら、案1が楽なのですが、
> if not existのif文の構文解析は、!HENSU2:~0,4!の変数展開の前に行われるので、ファイル名の所を二重引用符で囲む必要があります

の部分、引用符で囲まなかった場合に出るエラーメッセージから、「これは引用符を付けなかったために出たエラーだ」と気づけるかどうかですね。まあ、試行錯誤しているうちに解決するかも知れませんが、途中で「この方向では駄目ではないか？」とか思って諦めちゃうと駄目ですね。

案2だと今のコードからの書き換えがやや面倒ですが、回答に書いたように、単純なバッチが読み書きできるスキルがあれば十分だと思います。

> 初めはVBScriptで作成しようと考えたのですが、社内の仕組みで使用する関係上、Microsoft非推奨のものは使うことができず、

環境が許せば、VBAはありかと思いますが、サーバー機だとOffice入ってないか。