processingでオブジェクトの配列を交換したい

Question

実現したいこと

オブジェクトの入ってる配列をループで動かしていきたいです。

発生している問題・分からないこと

staff.xには情報とx座標がはいっています。staff.positionはwindowをmember2でわったx座標が、格納されています。
staff.xは移動する情報でstaff.positionはその情報をしまう箱のような役割をしています。この情報を箱にしまうループがうまくいきません。
forループでは、配列であらわすと、例えばint data【5】＝｛1，2，3，4，5｝があったとして、キーボードで要素数の1を入力したら1，3，4，5，2，というようにループでずれ、次にキーボードで0を入力したら、3，4，5，2，1となります。
つまり、入力された数字が配列の末尾にいき、入力された数字より後ろが前倒しになるということです。
このとき入力される数字はclickedIndexになります、この動きがうまくいきません。
また、
int []data=new int[member2-clickedIndex+1];のmember2-clickedIndex+1というのは先程例に上げた配列の要素数がmember2にあたり、キーボードで入力したものがclickedIndexにあたるので、clickedIndex以降の数字をループで動かすために
int []data=new int[member2-clickedIndex+1];となっております。
プログラムではstaff.position［j］に入ってるstaff.xを見つけ出して、別の箱に移動させらるように準備をしています。

この箱の移し替えの作業が例に上げた配列のループのように動かすにはどうしたらいいでしょうか？

プログラム初心者で言葉足らずなとこもありますがよろしくお願いいたします。

該当のソースコード

void setX() {
  int j=0;
  int []data=new int[member2-clickedIndex+1];
  if (clickedIndex!=-1) {
    
if (clickedIndex < member2 && clickedIndex >= 0) {
if (staff[clickedIndex].isTimerOn && clickingTimer) {
　while (j<member2) {
if (staff[j].position==member2) {
 int tmp=staff[j].x;
  for (int k=clickedIndex;
  k<=member2-1; k++) {
 for (int i =clickedIndex+1; i <=member2; i++) {
 if (staff[i].position==k) {
    data[k]=staff[i].x;
 }
 }
 for (int i=0; i<=member2; i++) {
 if (staff[i].position==k+1) {
            data[k]=staff[i].x;
  }
   }
  print(data[k]);
  }
    staff[clickedIndex].x=tmp;
          ｝
          j++;
        }
        clickingTimer=false;
      }
    }
  }
}

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

GPTや調べてコードを変えてみましたが、交換したいところが初期値から動かなかったり、交換してほしいところに表示されません。

補足

説明が難しく伝わっわてない部分もあるかもしれませんがどうかお願いいたします。

Comments

[TN8001]

[[Q&A] オブジェクトの座標交換をループでしたい。 - Qiita](https://qiita.com/hsjyr1112/questions/09f7e5cffa177f112e74)

[ヘルプ｜他のサービスにも質問投稿をしたい（してしまった）](https://teratail.com/help#posted-otherservice)

[thkana]

これも。
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q10292424965

[TN8001]

解決したあるいは解決の目途がついたならば、質問を「解決済」にしてください。

参考になった回答をベストアンサーするか、
[ヘルプ｜質問を解決済みにしたい](https://teratail.com/help#resolve-question)

回答をヒントにコードを改善した等の場合は自己回答でも結構です。
[ヘルプ｜質問をした後に自己解決してしまった](https://teratail.com/help#resolve-myself)

その際は他サイトにも同様の回答をするか、このページのリンクを貼ってください（未解決の質問は誰か考えているかもしれず、回答したら「実は別のサイトで解決していました」ではガッカリしますので）

もちろん目途がついていないなら安易に「解決済」にせず、回答への疑問点や不明点をお気軽にコメントください^^
（「未解決」のまま放置されるのは困りますが）「解決済」を急かすつもりはありません。

あるいはもっと良い回答が付くかもしれませんｗ

[nanako_o]

色々教えてくださり、ありがとうございます。
知恵袋は解決済みにしました。

話はプログラミングの方にもどしますが、教えてくださったコードを参考にして書き換えてみました。
いままでオブジェクトが思い道理に全く動きませんでしたが、はじめてクリックした箇所が後ろに回るループがうまく行きました！
本当にありがとうございます。
ただ、clickedIndex＋1からmember2までを前倒しにしたいのですが、どうしてもmember2より前からしかループにはいってくれません。
ループの動きは完璧なのですが、、
以下にコードをはります。
void setX() {

if (clickedIndex!=-1) {
// ボディ側だったら
if (clickedIndex <= member2 && clickedIndex >= 0) {
if (staff[clickedIndex].isTimerOn && clickingTimer) {
Staff tmp = staff[clickedIndex];
for (int i = clickedIndex+1; i <member2; i++) {
staff[i - 1] = staff[i];
}
staff[member2-1] = tmp;
print(1);
int[] xx = new int[member2]; // x用の配列を用意
for (int i = 0; i < xx.length; i++) {
xx[i] = staff[i].x; // 詰める
}
//printstaff(xx);
xx = sort(xx); // ソート
//printstaff(xx);
for (int i = 0; i < xx.length; i++) {
staff[i].x = xx[i]; // 詰め直し
}
}
}
}
}

staff[member2-1] = tmp;この部分をmember2に変えてみたのですが、それだとループが一切動かなくなってしまいます。

どうしたらいいでしょうか？

Answer 1

例えばint data【5】＝｛1，2，3，4，5｝があったとして、キーボードで要素数の1を入力したら1，3，4，5，2，というようにループでずれ、次にキーボードで0を入力したら、3，4，5，2，1となります。

字面通り素直に書くならこうでしょうか。

int[] array = { 1, 2, 3, 4, 5 };

int index = 1;
int tmp = array[index];
for(int i = index + 1; i < array.length; i++){
  array[i - 1] = array[i];
}
array[array.length - 1] = tmp;
println(array);
println();

index = 0;
tmp = array[index];
for(int i = index + 1; i < array.length; i++){
  array[i - 1] = array[i];
}
array[array.length - 1] = tmp;
println(array);

[0] 1
[1] 3
[2] 4
[3] 5
[4] 2

[0] 3
[1] 4
[2] 5
[3] 2
[4] 1

ループの代わりにarrayCopyを使うこともできます。

//for(int i = index + 1; i < array.length; i++){
//  array[i - 1] = array[i];
//}
arrayCopy(array, index + 1, array, index, array.length - index - 1);

arrayCopy() / Reference / Processing.org

---

ただこの要件ならリスト（IntList等）のほうがはるかに簡単です（まあいろいろ罠もありますが^^;

IntList list = new IntList(1, 2, 3, 4, 5);

int index = 1;
int tmp = list.remove(index); // index番目を削除しその値を返す
list.append(tmp); // 末尾に追加
println(list);
println();

index = 0;
list.append(list.remove(index)); // １行でもok
println(list);


// intじゃなくて何かのクラスだった場合
//import java.util.List;

//ArrayList<Integer> list = new ArrayList<>(List.of(1, 2, 3, 4, 5));

//int index = 1;
//int tmp = list.remove(index); // index番目を削除しその値を返す
//list.add(tmp); // 末尾に追加
//println(list);
//println();

//index = 0;
//list.add(list.remove(index)); // １行でもok
//println(list);

IntList / Reference / Processing.org
ArrayList / Reference / Processing.org

---

この箱の移し替えの作業が例に上げた配列のループのように動かすにはどうしたらいいでしょうか？

実際はintの配列ではなくStaffクラスの配列ということはわかりますが、xとpositionの関係が全く分かりません。

• 動く図形の上下関係（Z-order）のようなもの？？
• 選んだトランプを右端に回すような処理？？

交換したいところが初期値から動かなかったり、交換してほしいところに表示されません。
説明が難しく伝わっわてない部分もあるかもしれませんがどうかお願いいたします。

言葉で説明が難しければintの例と同じように、初期値と期待値を例示するとか（↓のような）

staff	[0]	[1]	[2]	[3]	[4]
x	1	2	3	4	5
position

clickedIndex = 1
↓

staff	[0]	[1]	[2]	[3]	[4]
x	1	3	4	5	2
position

clickedIndex = 0
↓

staff	[0]	[1]	[2]	[3]	[4]
x	3	4	5	2	1
position

あるいは今問題になっている部分を極々単純化した、実行できるプログラムを提示いただけると話が通じやすいです。

---

追記 配列がそのまま並び順になるように変更できないでしょうか？（例えばこんな）

Card[] cards = {
  new Card(5, #ff0000),
  new Card(65, #00ff00),
  new Card(125, #0000ff),
  new Card(185, #ffff00),
  new Card(245, #00ffff)
};

void setup() {
  size(300, 200);
}

void draw() {
  background(255);

  for (int i = 0; i < cards.length; i++) {
    fill(cards[i].c);
    rect(cards[i].x, 75, 50, 50);
  }
}

void mouseClicked() {
  // mouseXを雑にcardsインデックス（0～4）に変換
  int index = int(map(mouseX, 0, width, 0, 5));
  println(index);

  // 選択カードを配列の末尾に移動
  Card tmp = cards[index];
  for (int i = index + 1; i < cards.length; i++) {
    cards[i - 1] = cards[i];
  }
  cards[cards.length - 1] = tmp;

  int[] xx = new int[cards.length]; // x用の配列を用意
  for (int i = 0; i < cards.length; i++) {
    xx[i] = cards[i].x; // 詰める
  }
  xx = sort(xx); // ソート
  for (int i = 0; i < cards.length; i++) {
    cards[i].x = xx[i]; // 詰め直し
  }
}

class Card {
  int x;
  color c;
  Card(int x, color c) {
    this.x = x;
    this.c = c;
  }
}

---

さらに追記

int member2 = 5;
Staff[] staff = {
  new Staff(0, "A"),
  new Staff(50, "B"),
  new Staff(100, "C"),
  new Staff(150, "D"),
  new Staff(200, "E"),
  new Staff(250, "F"),
  new Staff(300, "G"),
  new Staff(350, "H"),
  new Staff(400, "I"),
  new Staff(450, "J")
};


void setup() {
  size(500, 200);
  textAlign(CENTER, CENTER);
  textSize(24);
}

void draw() {
  background(255);

  for (int i = 0; i < staff.length; i++) {
    fill(0);
    text(staff[i].c, staff[i].x, 75, 50, 50);
    noFill();
    rect(staff[i].x, 75, 50, 50);
  }
}

void mouseClicked() {
  int clickedIndex = int(map(mouseX, 0, width, 0, 10));
  println("clickedIndex:" + clickedIndex);

  if (clickedIndex <= member2 && clickedIndex >= 0) {
    Staff tmp = staff[clickedIndex]; // clickedIndex番目をとっておく
    for (int i = clickedIndex + 1; i <= member2; i++) { // clickedIndexの次からmember2番目も含め回す
      staff[i - 1] = staff[i]; // １個前へ
    }
    staff[member2] = tmp; // 抜けたmember2番目にはめる

    int[] xx = new int[member2 + 1]; // member2がインデックス（5）なら要素数は+1です（6）
    //int[] xx = new int[staff.length]; // ややこしくなるぐらいなら全件見てもいいのではないか？
    for (int i = 0; i < xx.length; i++) {
      xx[i] = staff[i].x;
    }

    xx = sort(xx);

    for (int i = 0; i < xx.length; i++) {
      staff[i].x = xx[i];
    }

    printArray(staff); // 配列表示
  }
}


class Staff {
  int x;
  String c;
  Staff(int x, String c) {
    this.x = x;
    this.c = c;
  }
  @Override String toString() { // toStringとprintArrayでデバッグしやすくなる
    return c + " x:" + x;
  }
}

Comments

[nanako_o]

回答ありがとうございます。
表に書くと以下のようになります。
staff　 [0] [1] [2] [3] [4]
x 　　　1　 2 3 4 5
position 1 2 3 4 5
clickedIndex = 1
↓

staff [0] [2] [3] [4] [1]
x 1 3 4 5 2
position1 2 3 4 5
clickedIndex = 0
↓

staff [2] [3] [4] [1] [0]
x 3 4 5 2 1
position 1 2 3 4 5

となります。
staff.xの要素数がループで移動するたびに要素吸うごと交換されてるため、staff.positionというオブジェクトをつくりました。
staff.positionは格納するための箱になります。
そのため、staff.positionでj番目にあたるstaff.xを探し出して交換させる必要があります。

説明が下手で本当にすみません。
よろしくお願いいたします。

[TN8001]

例えばint[] data ＝｛1，2，3，4，5｝を clickedIndex = 1 したら 1，3，4，5，2 なんですよね？
[0] [1] [2] [3] [4] ←dataのインデックス
1 2 3 4 5 ←インデックス番目の値
clickedIndex = 1
↓
[0] [1] [2] [3] [4] ←data[1]の値2が、配列の最後になり抜けた分は詰める
1 3 4 5 2

> staff [0] [2] [3] [4] [1]
> x 1 3 4 5 2
> position1 2 3 4 5

インデックスのほうが動いてしまうと意図が分からないです。。。
インデックス順に並び変えるとこうですが、

staff [0] [1] [2] [3] [4]
x 1 2 3 4 5
position 1 5 2 3 4

xは常にインデックス+1なので必要ないような？
positionは逆にdata[1]に配列の最後の値（5）を入れ、右にずらすような動作ってことでしょうか？？

そもそも図の理解の前提が違いますか？

> staff.xの要素数がループで移動するたびに要素吸うごと交換されてるため、staff.positionというオブジェクトをつくりました。
> staff.positionは格納するための箱になります。

元の順番を保持するような変数なのかなって気はしますが、すいませんがまだ意味が分かりません。

今何を作っていてこの処理がどう使われるのかを説明できませんか？

[nanako_o]

説明が下手ですみません。
staff.xをループにいれたときにstaff.xの中身を交換したいのですが、どうも要素数ごと動いてしまいます。
それがどうしてかは私にもわかりませんでした、、
そのためstaff.positionをつくりました。

positionは一切動かないようにプログラムしております。
固定された箱と認識して頂きたいです。
staff.xの入力された値の要素数番目を配列の末尾に持っていきたいため、入力された要素数番目のstaff.xをpositionで前から何番目にいるのか探しています。

このときのstaff.x要素数で呼び出してしまうと最初のループはうまく行きますが、それ以降が要素数が動いてしまうのでstaff.xの要素数0が先頭にいるとは限らないということです。
そのためpositionで探します。

今作っているのはアルバイト先のエステティシャンをローテーションで管理するツールです。
担当のエステティシャンが仕事に入ったら列の一番うしろにそのエステティシャンは入るというようにプログラムしたいです。

また説明で理解できないところがあったら行ってください。

よろしくお願いいたします。

[TN8001]

あぁ、わかったかもしれません。
配列の要素を入れ替えるのではなく、要素はそのまま`x`だけが変わるようなイメージですかね？
並び順がxを見ないとわからないとなると、単純な入れ替え処理では並び替えられないような気がします（だから詰まっているんでしょうけど^^;

配列がそのまま並び順になるように変更できないでしょうか？（回答に追記）
クラスにxが必要だとしても配列を入れ替えたうえで、別途取得したxをソートし入れなおすようなアプローチのほうが分かりやすい気がします。

[nanako_o]

そうです！！！！はじめて理解してくれる人に出会いました！！
おお、、その手がありましたか、、
かなり長い間この問題でつまずいていたので、新たなアプローチ方を知れて嬉しいです。
試してみます。
ありがとうございます！！！

また何かあったらコメントさせてください、、

[TN8001]

> かなり長い間この問題でつまずいていたので、新たなアプローチ方を知れて嬉しいです。

そうですかよかったです^^
「xをソートし入れなおすようなアプローチ」に回答コードを変更しました。

> また何かあったらコメントさせてください、、

もちろんお気軽にどうぞ^^

[TN8001]

回答への質問は回答のコメント欄にお願いします。

> ただ、clickedIndex＋1からmember2までを前倒しにしたいのですが、どうしてもmember2より前からしかループにはいってくれません。

このループのことですか？
for (int i = clickedIndex + 1; i < member2; i++) {
staff[i - 1] = staff[i];
}

i < member2 としてるので、当然member2より前ということになります。
member2はstaff.lengthと違うんですかね？

こういうことでしょうか？（<じゃなくて<=）
for (int i = clickedIndex + 1; i <= member2; i++) {

あるいはmember2を全部staff.lengthに置き換えるかでしょうか？

[nanako_o]

コメントが遅くなってしまい、申し訳ありません。
上にあるもう一つのコメントを見ていたため気づくのに時間がかかってしまいました。
member2を＝つけて試しても見ましたが、member2より前からしか動きませんでした。
staff.lengthはmember2と別物になります。

[TN8001]

> staff.lengthはmember2と別物になります。

member2の役割がよくわかりません。
staff.lengthはもっと多くて、member2はそれより小さいのでしょうか？

0 1 2 3 4 5 6 7 8 9 ←インデックス
A B C D E F G H I J ←入ってるオブジェクト

lengthは10
clickedIndexは2
member2は5

だとすると
clickedIndex 2のCを引っこ抜いてDEFが前倒しになり、あいたところにCが入る
A B D E F C G H I J こうなるってことでしょうか？

さらに追記しました。
そうではない場合どういう結果を期待しているかを書いてください。

[nanako_o]

＞0 1 2 3 4 5 6 7 8 9 ←インデックス A B C D E F G H I J ←入ってるオブジェクト lengthは10 clickedIndexは2 member2は5 だとすると clickedIndex 2のCを引っこ抜いてDEFが前倒しになり、あいたところにCが入る A B D E F C G H I J こうなるってことでしょうか？

そのとおりです。
しかしmember2より前からしか動かないという状況になります。
期待している結果は回答者様が出してくださって例がまんま期待している結果です。
よろしくお願いいたします。

[TN8001]

> そのとおりです。
> しかしmember2より前からしか動かないという状況になります。

詳しくは追記コードを動かして確認していただきたいのですが

member2番目が入れ替わらないことは↓の問題（< と <=）で、
> // clickedIndexの次からmember2番目も含め回す
> for (int i = clickedIndex + 1; i <= member2; i++) {

ここも-1だとおかしくなります。
> staff[member2] = tmp; // 抜けたmember2番目にはめる

さらにここの+1がないとxのソートが届かない（member2番目になったCのxが変わらない）ので（順番は入れ替わっているが）見た目の位置は動かないことになります。
> // member2がインデックス（5）なら要素数は+1です（6）
> int[] xx = new int[member2 + 1];

文字で書くとなんのこっちゃという感じですが^^;

追記コードそのままと < と <=の場合・+-1の有り無し等のコードを2窓で同時に実行し、コンソールをよくよく見比べれば「あぁ、なるほどね」ってなると思います^^

[nanako_o]

詳しく教えていただきありがとうございます。
回答者様が教えてくださった部分を修正したら無事に動かすことができました。

何度質問しても丁寧に答えてくださって本当にありがとうございます！
なんとか正常に動かせるようになってよかったです！