２次元配列を１次元配列に変換したい。

Question

前提・実現したいこと

２次元配列を１次元配列に変換したい。

VBAで配列にある要素が含まれているかを確認したいです。

まず検索元となる配列としてA1:E1の値を格納します。
このとき配列は2次元配列(１行５列)…検索元配列になると思います。

このあと
'Filter()関数により要素を検索
varResult = Filter(検索元配列, 検索キー)

'戻り値配列のサイズで要素の有無を判定
If UBound(varResult) <> -1 Then
としたいのですが、２次元配列なのでうまくいきません。

該当のソースコード

Dim varArray() As Variant
Dim varResult As Variant
Dim strTarget As String

'検索元の配列を作成
varArray = Worksheets("Sheet1").Range("A1:D1").Value

'検索要素を指定
strTarget = Worksheets("Sheet1").Range("A2").Value

'Filter()関数により要素を検索
varResult = Filter(varArray, strTarget)

'戻り値配列のサイズで要素の有無を判定
If UBound(varResult) <> -1 Then
    Debug.Print strTarget & "は配列内に存在する"
Else
    Debug.Print strTarget & "は配列内に存在しない"
End If

試したこと

2次元配列を１次元配列に変換する方法として
varArray_1 = WorksheetFunction.Index(varArray,1)
varResult = Filter(varArray_1, strTarget)
としてみたところ
varArray(1,1)の値がvarArray_1に格納されていました。

Answer 1

一例として。
結果がご希望通りなら良いのですが。

Sub try()
    Dim varArray As Variant '★
    Dim varResult As Variant
    Dim strTarget As String

    '検索元の配列を作成 ★
    varArray = WorksheetFunction.Index(Worksheets("Sheet1").Range("A1:D1").Value, 1, 0)

    '検索要素を指定
    strTarget = Worksheets("Sheet1").Range("A2").Value

    'Filter()関数により要素を検索
    varResult = Filter(varArray, strTarget)

    '戻り値配列のサイズで要素の有無を判定
    If UBound(varResult) <> -1 Then
        Debug.Print strTarget & "は配列内に存在する"
    Else
        Debug.Print strTarget & "は配列内に存在しない"
    End If
End Sub

でも有無であればセル範囲をワークシート関数のCountIfで調べてもと考えてしまいます。

Comments

[persimmon0330]

ありがとうございます。うまくいきました。
WorksheetFunction.Index(Worksheets("Sheet1").Range("A1:D1").Value, 1, 0)
だと配列の1行目0列目=A1が取得されると思うのですが、なぜうまくいったのかわかりません。

またWorksheetFunction.CountIfs(varArray, strTarget)
としたら、オブジェクトが必要というエラーが出てしまいました。。