VBA match関数を使用したエラーに関して（実行時エラー'1004':アプリケーション定義またはオブジェクト定義のエラーです）

Question

前提

複数のエクセルブック（※１）の一つのデータを
１つのブックに転記したい

※１：複数のエクセルブックは約200個

実現したいこと

複数のエクセルブックにある、ワークシート名「7月」に入力している、一つのデータを抽出する為に、
キーワード（特定の文字列）から行列を特定し、行を一つずらし、転記したいデータを
１つのブックに転記する

発生している問題・エラーメッセージ

実行時エラー '1004':
アプリケーション定義またはオブジェクト定義のエラーです

該当のソースコード

Option Explicit

Sub test_ver00()

Dim cnt
Dim cnt_2
Dim i
Dim file
Dim filebook
Dim test_1 As Workbook

cnt = Workbooks("Book1.xlsm").Sheets("sheet1").Range("a100000").End(xlUp).Row + 1
file = Application.GetOpenFilename(MultiSelect:=True)

If IsArray(file) Then

For Each filebook In file

Workbooks.Open (filebook)

Set getsuji_gb = ActiveWorkbook

cnt_2 = 0

On Error Resume Next

cnt_2 = WorksheetFunction.Match("今日の活動状況詳細*", Range("h1:h100"), 0) + 1

On Error GoTo 0

If cnt_2 <> 0 Then

    MsgBox "該当なし"

Else

With Workbooks("Book1.xlsm").Sheets("Sheet1")

.Cells(cnt, 1).Value _
= test_1.Name

.Cells(cnt, 2).Value _
= test_1.Sheets("7月").Cells(cnt_2, 3).Value

cnt = cnt + 1

End With

End If

test_1.Close

Next

End If

試したこと

型をvariantにしたり、
イミディエイトではcnt_2の実行結果は出力されていることを確認しました

補足情報（FW/ツールのバージョンなど）

office365

Answer 1

とりあえず明らかな間違いと思われるところと、変数宣言はちゃんと型指定するように修正してみた。

Sub test_ver00()
    Dim cnt As Long
    Dim cnt_2 As Long
    Dim file As Variant
    Dim filebook As Variant
    Dim test_1 As Workbook

    cnt = Workbooks("Book1.xlsm").Sheets("sheet1").Range("a100000").End(xlUp).Row + 1
    file = Application.GetOpenFilename(MultiSelect:=True)

    If IsArray(file) Then
        For Each filebook In file
            Workbooks.Open filebook
            Set test_1 = ActiveWorkbook
            cnt_2 = 0
            On Error Resume Next
            cnt_2 = WorksheetFunction.Match("今日の活動状況詳細*", test_1.Sheets("7月").Range("h1:h100"), 0) + 1
            On Error GoTo 0

            If cnt_2 = 0 Then
                MsgBox "該当なし"
            Else
                With Workbooks("Book1.xlsm").Sheets("Sheet1")
                    .Cells(cnt, 1).Value = test_1.Name
                    .Cells(cnt, 2).Value = test_1.Sheets("7月").Cells(cnt_2, 3).Value
                    cnt = cnt + 1
                End With
            End If
            test_1.Close
        Next
    End If

End Sub

Comments

[mdspecial_2010]

hatena19様

すぐにお返事下さりありがとうございました。

お教え頂いた通りにしましたら問題なく実行できました。本当にありがとうございました。

確認型の定義とmatch関数をどこから読み込んでいるのかをしっかり記述しないとダメと言うことがよく分かりました！

一日中悩んでおりましたので本当に助かりました。
ありがとうございました！