VBA AutoFilterで複数条件で別ブックからデータを抽出、また別の条件で抽出を繰り返し

Question

前提

VBAでオートフィルターを使い別ブックから日付と時間に合うデータをコピーしようとしているのですが繰り返しがうまくいきません。
該当データは1つのみで、複数のデータがあるわけではありません。
何卒、改善点をご教授ください。

実現したいこと

オートフィルターでセルの値を検索条件に別ブックからのデータを抜き出そうとしているのですが、変数を使って検索条件を動的にして繰り返し（コピー先の表全部を）
データを抜き出せるようにしたいです。
これを別のブックから行います。

発生している問題・エラーメッセージ

画像を添付しますが、時間の部分で
4：00：00や0：05：00がコピーされません。
20：00：00や12：15：00はされるので○○時〇〇分の時間が2桁以上は反応してくれるようです。
また、秒数は00秒固定です。時間と分のみが変動します。
また
別ブックからコピーさせるようにしてみると
「オブジェクトは、このプロパティまたはメソッドをサポートしていません。」と
エラー表示が起きます。
wb2.Range("A1").AutoFilter 1, Format(wb1.Worksheets("コピー先").Cells(i, 1), "yyyy/m/d")
この部分で止まっているようです。

コピー先とコピー元は最終的には別ブックにしたいです。
別ブックからの分を試そうとしたら動きすらしなかったので
画像の分は同じブック内の動きの分のスクショを貼り付けました。

該当のソースコード

Sub 改めて日付時間を表示形式にする繰り返し10()
    Workbooks.Open Filename:=ThisWorkbook.Path & "\実験用コピー元.xlsx"
    Dim wb1 As Workbook
    Dim wb2 As Workbook
    Set wb1 = ThisWorkbook
    Set wb2 = Workbooks("実験用コピー元.xlsx")
    
    
    With wb1.Worksheets("コピー先").UsedRange
        Dim i
        For i = 2 To .Rows.Count
            wb2.Range("A1").AutoFilter 1, Format(wb1.Worksheets("コピー先").Cells(i, 1), "yyyy/m/d")
            wb2.Range("A1").AutoFilter 2, Format(wb1.Worksheets("コピー先").Cells(i, 2), "hh:mm:ss")
            
            With wb2.Worksheets("コピー元").Range("A1").CurrentRegion
                Dim rng As Range
                Set rng = Intersect(.Cells, .Offset(1))
                If IsVisible(rng) Then rng.Copy wb1.Cells(i, 7)
            End With
            
            wb2.Worksheets("コピー元").Range("A1").AutoFilter
        Next
    End With
    wb1.AutoFilterMode = False
    wb2.Close False
End Sub

Function IsVisible(r As Range) As Boolean
    On Error Resume Next
    IsVisible = r.SpecialCells(xlCellTypeVisible).Count > 0
End Function

試したこと

時間の問題については
おそらくは下の部分のcount>0の部分の表記を変えれば10：00：00台だけでなく５：00：00台や8：00：00台にも対応できるのではとは思うのですが（0を"00:00:00"にしてみるなど）うまくいきません。
VBAはまだまだ勉強したてで考え方が間違っているのでしょうか。

Function IsVisible(r As Range) As Boolean
On Error Resume Next
IsVisible = r.SpecialCells(xlCellTypeVisible).Count > 0
End Function

補足情報（FW/ツールのバージョンなど）

追記、現状です。

Answer 1

wb2.Range("A1") の部分でシートを指定してないのでエラーになります。

wb2.Worksheets("コピー元").Range("A1")というようにシートを指定しましょう。

おまけ

Dictinary を使って検索するサンプルコード

Sub 改めて日付時間を表示形式にする繰り返し_Dictinary()
    Dim i As Long
    Dim wb1 As Workbook
    Dim wb2 As Workbook
    Set wb1 = ThisWorkbook
    Set wb2 = Workbooks.Open(FileName:=ThisWorkbook.Path & "\実験用コピー元.xlsx")
    
    Dim dic As Object
    Set dic = CreateObject("Scripting.Dictionary")
    'コピー元データをDictionaryに登録
    With wb2.Worksheets("コピー元").Cells(1).CurrentRegion
        For i = 2 To .Rows.Count
            Set dic(Format(.Cells(i, 1), "yyyy/m/d") & " " & Format(.Cells(i, 2), "hh:mm:ss")) = .Rows(i)
        Next
    End With
    'Dictionaryを検索して該当データをコピー先にコピー
    With wb1.Worksheets("コピー先").Cells(1).CurrentRegion
        For i = 2 To .Rows.Count
            Dim key As String: key = Format(.Cells(i, 1), "yyyy/m/d") & " " & Format(.Cells(i, 2), "hh:mm:ss")
            If dic.Exists(key) Then dic(key).Copy .Cells(i, 7)
        Next
    End With

End Sub

Comments

[marebito777]

前の質問の時から何度もありがとうございます。
頂いたコードで試してみたところうまくいきそうです。
今日は時間が取れずまだコードの内容を読み解けていないのですが、また内容を自分なりに理解して学習を進めて
応用できればと思います。
コードの要所要所に解説を入れていただけるのも初心者の私にとってはすごくありがたいです。
ありがとうございます。

[marebito777]

hatena19さん
たびたびすいません。現状で追記した画像のような挙動をするのですが。
日付は対応できるのですが、時間が日付の最後の時間の分が全部コピーされているような形です。
この解決方法としては連想配列に連想配列を入れ込む？方向の考え方で探していけばいいのでしょうか。

[hatena19]

あっ、済みません。コードが間違ってました。

Format(.Cells(i, 1), "yyyy/m/d") & " " & Format(.Cells(i, 1)
の部分を
Format(.Cells(i, 1), "yyyy/m/d") & " " & Format(.Cells(i, ２)
に修正してください。(2か所あります。)

回答のコードも修正しておきました。

[marebito777]

動きました！ありがとうございます。
自分でもそれは試したつもりなんですが2つ目を見落としていたみたいです汗
ありがとうございます。