processingで記録を保存したい。

Question

実現したいこと

• 記録を保存したい

前提

processingでタイマーアプリを作っているのですが、タイマーの記録が保存されません。一度停止したのちに起動するとタイマーの記録が０になってしまいます。エラーは出ていません。

該当のソースコード

ソースコード
```PFont font;
int currentScreen = 0; // 0:メニュー, 1:目標設定, 2:記録, 3:タイマー, 4:時間設定パネル
boolean timerRunning = false;
boolean timerStopped = false;
int startTime, currentTime, totalTime;
ArrayList<Integer> records = new ArrayList<Integer>();

int[] weeklyGoals = new int[7];
int[] dailyRecords = new int[7];
int currentDay = 0; // 仮の現在の曜日
int selectedDay = -1; // 時間設定中の曜日
String []days = {"月","火","水","木","金","土","日"};

void setup() {
  size(480, 640);
  font = createFont("Meiryo", 20); // メイリオフォントを使用
  textFont(font);

  loadRecords();
  loadGoals();
  updateCurrentDay(); // setup時に一度現在の曜日を取得

}

void draw() {
  updateCurrentDay(); // 毎フレーム現在の曜日をチェックして更新
  switch (currentScreen) {
  case 0:
    drawMenuScreen();
    break;
  case 1:
    drawGoalSettingScreen();
    break;
  case 2:
    drawRecordScreen();
    break;
  case 3:
    drawTimerScreen();
    break;
  case 4:
    drawTimeInputPanel();
    break;
  }
}

void drawMenuScreen() {
  background(220, 240, 255);

  fill(0);
  textAlign(CENTER);
  textSize(24);
  text("自習アプリ", width / 2, 50);

  textSize(16);
  fill(100, 150, 255);
  rect(width / 2 - 100, 120, 200, 50, 10);
  fill(0);
  text("目標設定", width / 2, 150);

  fill(100, 150, 255);
  rect(width / 2 - 100, 220, 200, 50, 10);
  fill(0);
  text("記録", width / 2, 250);

  fill(100, 150, 255);
  rect(width / 2 - 100, 320, 200, 50, 10);
  fill(0);
  text("タイマー", width / 2, 350);
}

void drawGoalSettingScreen() {
  background(255, 230, 230);

  fill(0);
  textAlign(LEFT);
  textSize(24);
  text("目標設定", 20, 50);

  textSize(16);
  for (int i = 0; i < 7; i++) {
    fill(100, 150, 255);
    rect(20, 100 + i * 70, 340, 50, 10);
    fill(0);
    textAlign(CENTER, CENTER-5);
    text(days[i]+"曜日 " + ": " + convertToTime(weeklyGoals[i]), 90, 130 + i * 70);

    // 時間設定ボタン
    fill(150, 255, 150);
    rect(370, 105 + i * 70, 90, 40, 10);
    fill(0);
    textAlign(CENTER, CENTER);
    text("時間設定", 415, 125 + i * 70);
  }

  // メニューに戻るボタン
  fill(100, 150, 255);
  rect(width - 120, height - 50, 100, 30, 10);
  fill(0);
  textAlign(CENTER, CENTER);
  text("メニュー", width - 70, height - 35);
}

void drawRecordScreen() {
  background(230, 255, 230); // 淡い緑色の背景

  fill(0);
  textAlign(LEFT);
  textSize(24);
  text("記録", 20, 50);

  textSize(16);
  for (int i = 0; i < 7; i++) {
    text(days[i] +"曜日 "  + ": " + dailyRecords[i] + " 秒", 20, 100 + i * 50);
  }

  int totalRecordedTime = 0;
  for (int i = 0; i < 7; i++) {
    totalRecordedTime += dailyRecords[i];
  }

  if (totalRecordedTime >= weeklyGoals[currentDay]) {
    text("目標達成！", 20, 550);
  }

  // メニューに戻るボタン
  fill(100, 150, 255);
  rect(width - 120, height - 50, 100, 30, 10);
  fill(0);
  textAlign(CENTER, CENTER);
  text("メニュー", width - 70, height - 35);
}

void drawTimerScreen() {
  background(240, 240, 255);

  fill(0);
  textAlign(CENTER);
  textSize(24);
  text("タイマー", width / 2, 50);

  if (timerRunning) {
    currentTime = millis();
  }

  textSize(48);
  text((currentTime - startTime) / 1000 + " 秒", width / 2, height / 2);

  textSize(16);
  text("合計時間: " + totalTime / 1000 + " 秒", width / 2, height - 50);

  // メニューに戻るボタン
  fill(100, 150, 255);
  rect(width - 120, height - 50, 100, 30, 10);
  fill(0);
  textAlign(CENTER, CENTER);
  text("メニュー", width - 70, height - 35);
}

void drawTimeInputPanel() {
  background(255);

  fill(0);
  textAlign(LEFT);
  textSize(24);
  text("時間設定", 20, 50);

  textSize(16);
  textAlign(CENTER, CENTER);
  String[] buttons = {
    "1", "2", "3", "4", "5", "6", "7", "8", "9", "0", "クリア", "設定"
  };

  for (int i = 0; i < buttons.length; i++) {
    int x = 20 + (i % 3) * 140;
    int y = 100 + (i / 3) * 80;
    fill(200, 200, 255);
    rect(x, y, 120, 60, 10);
    fill(0);
    text(buttons[i], x + 60, y + 30);
  }

  // 現在の入力を表示
  fill(0);
  textAlign(LEFT);
  textSize(20);
  text("現在の入力: " + convertToTime(weeklyGoals[selectedDay]), 20, height - 100);

  // メニューに戻るボタン
  fill(100, 150, 255);
  rect(width - 120, height - 50, 100, 30, 10);
  fill(0);
  textAlign(CENTER, CENTER);
  text("戻る", width - 70, height - 35);
}

void mousePressed() {
  switch (currentScreen) {
  case 0:
    if (mouseY > 120 && mouseY < 170) currentScreen = 1;
    if (mouseY > 220 && mouseY < 270) currentScreen = 2;
    if (mouseY > 320 && mouseY < 370) currentScreen = 3;
    break;
  case 1:
    // 目標設定画面の操作
    for (int i = 0; i < 7; i++) {
      if (mouseY > 100 + i * 70 && mouseY < 150 + i * 70) {
        if (mouseX > 370 && mouseX < 460) {
          selectedDay = i;
          currentScreen = 4;
        }
      }
    }
    // メニューに戻る
    if (mouseX > width - 120 && mouseX < width - 20 && mouseY > height - 50 && mouseY < height - 20) {
      saveGoals();
      currentScreen = 0;
    }
    break;
  case 2:
    // メニューに戻る
    if (mouseX > width - 120 && mouseX < width - 20 && mouseY > height - 50 && mouseY < height - 20) {
      saveRecords();
      currentScreen = 0;
    }
    break;
  case 3:
    // タイマー画面の操作
    if (timerRunning) {
      timerRunning = false;
      timerStopped = true;
      totalTime += currentTime - startTime;
      records.add(currentTime - startTime);
      dailyRecords[currentDay] += (currentTime - startTime) / 1000;
    } else {
      timerRunning = true;
      timerStopped = false;
      startTime = millis();
    }
    // メニューに戻る
    if (mouseX > width - 120 && mouseX < width - 20 && mouseY > height - 50 && mouseY < height - 20) {
      saveRecords();
      currentScreen = 0;
      timerRunning = false;
      timerStopped = false;
      startTime = 0;
      currentTime = 0;
    }
    break;
  case 4:
    // 時間入力パネルの操作
    String[] buttons = {
      "1", "2", "3", "4", "5", "6", "7", "8", "9", "0", "クリア", "設定"
    };
    for (int i = 0; i < buttons.length; i++) {
      int x = 20 + (i % 3) * 140;
      int y = 100 + (i / 3) * 80;
      if (mouseX > x && mouseX < x + 120 && mouseY > y && mouseY < y + 60) {
        if (buttons[i].equals("クリア")) {
          weeklyGoals[selectedDay] = 0;
        } else if (buttons[i].equals("設定")) {
          currentScreen = 1;
        } else {
          int num = int(buttons[i]);
          weeklyGoals[selectedDay] = weeklyGoals[selectedDay] * 10 + num * 3600; // 時間単位で加算
        }
      }
    }
    // メニューに戻る
    if (mouseX > width - 120 && mouseX < width - 20 && mouseY > height - 50 && mouseY < height - 20) {
      saveGoals();
      currentScreen = 1;
    }
    break;
  }
}

// 秒を時間:分:秒の形式に変換する関数
String convertToTime(int seconds) {
  int hours = seconds / 3600;
  int minutes = (seconds % 3600) / 60;
  int secs = seconds % 60;
  return nf(hours, 2) + ":" + nf(minutes, 2) + ":" + nf(secs, 2);
}

// 記録を保存する関数
void saveRecords() {
  Table table = new Table();
  table.addColumn("Day");
  table.addColumn("Seconds");

  for (int i = 0; i < 7; i++) {
    TableRow row = table.addRow();
    row.setInt("Day", i);
    row.setInt("Seconds", dailyRecords[i]);
  }

  saveTable(table, "records.csv");
}

// 記録をロードする関数
void loadRecords() {
  Table table = loadTable("records.csv", "header");
  if (table == null) return;

  for (TableRow row : table.rows()) {
    int day = row.getInt("Day");
    int seconds = row.getInt("Seconds");
    dailyRecords[day] = seconds;
  }
}

// 目標時間を保存する関数
void saveGoals() {
  Table table = new Table();
  table.addColumn("Day");
  table.addColumn("Seconds");

  for (int i = 0; i < 7; i++) {
    TableRow row = table.addRow();
    row.setInt("Day", i);
    row.setInt("Seconds", weeklyGoals[i]);
  }

  saveTable(table, "goals.csv");
}

// 目標時間をロードする関数
void loadGoals() {
  Table table = loadTable("goals.csv", "header");
  if (table == null) return;

  for (TableRow row : table.rows()) {
    int day = row.getInt("Day");
    int seconds = row.getInt("Seconds");
    weeklyGoals[day] = seconds;
  }
}

void updateCurrentDay() {
  int newDay = (day() - 1) % 7; // 曜日は 0 (月曜日) から 6 (日曜日)
  if (newDay != currentDay) {
    currentDay = newDay;
    saveRecords(); // 曜日が変わるときに記録を保存
    dailyRecords[currentDay] = 0; // 新しい曜日の記録をリセット
  }
}

Answer 1

processingでタイマーアプリを作っているのですが、タイマーの記録が保存されません。

「タイマーの記録」とは、records.csvのことでしょうか。
保存されているかどうかはファイルを見れば一目瞭然ですよね（保存はされています）

一度停止したのちに起動するとタイマーの記録が０になってしまいます。

アプリを再起動すると「淡い緑色の背景画面」で、今日の曜日の記録がリセットされるということですね。

「記録をリセット」していそうなところは、updateCurrentDay()だけです。
currentDayを適切に初期化しておけばいいんじゃないですかね？（updateCurrentDay()内のnewDayも同様）

//int currentDay = 0; // 仮の現在の曜日
int currentDay = (java.util.Calendar.getInstance().get(java.util.Calendar.DAY_OF_WEEK) + 5) % 7;

Processingで曜日のデータを取得する | Free Style

---

Processingは毎フレームdrawが走るので、こういうデバッグに（表示が出すぎて）printlnは向かないです。

デバッガ（右上の虫みたいなボタン）の使い方を覚えましょう^^
processing pde デバッガ - Google 検索

Comments

[TN8001]

仕様を完全には理解できていないので、それだけでいいのかは自信なし^^;

[kain1270]

ちゃんと記録できました。
ありがとうございます。