括弧()を含むファイル名を括弧()内部の文字ごと削除した名前に変更したい

Question

前提

ある講習会に参加した社員のレポート（PDF）を保存しているフォルダがあり、
ファイル名は全て「連番 (部署名_氏名).pdf」とついています。

実現したいこと

タイトルの通り、ファイル名の括弧()内部を全て削除して、

「連番 (部署名_氏名).pdf」→「連番.pdf」

というファイル名に変換するバッチファイルを作成したいです。

試したこと

参考にしたURLおよび記載されたコードを作成しました。

ファイル名 一括変換 バッチファイル 作成方法

@echo off
rem ショートカットのつくファイル名を削除するバッチです。
rem 10行目のコードを変えて色んな文字の変換が出来ます。
rem ループで%%fをコールする
for %%f in ( * ) do call :sub “%%f”
exit /b
rem コール先のバッチ 「- ショートカット」と付くファイル名を””（空白）に置換
:sub
set fname=%1
set fname=%fname: – ショートカット=””%
ren %1 %fname%
pause

ここから、括弧（）の全てを削除するコードにしようと書いたものが以下の通りです。

@echo off
rem ファイル名を変更するバッチです。
rem コードを変えて色んな文字の変換が出来ます。
rem ループで%%fをコールする
for %%f in ( * ) do call :sub “%%f”
exit /b
rem コール先のバッチ （ 文字 ）と付くファイル名を”（空白なし）に置換
:sub
set fname=%1
set fname=%fname: (*=_%
set fname=%fname:(*=_%
set fname=%fname:)=%
ren %1 %fname%
pause

発生している問題・エラーメッセージ

作成したバッチファイルをフォルダに移動しクリックで実行したところ、以下のように「指定されたファイルが見つかりません」と表示されて処理が終了します。

指定されたファイルが見つかりません。
指定されたファイルが見つかりません。
指定されたファイルが見つかりません。
指定されたファイルが見つかりません。

括弧（）内の文字をワイルドカードで指定できると考えたのですが、上手くできませんでした。
ファイル名のつけ方が普通と違うというのは承知してますが、ご教示いただけますと幸いです。
よろしくお願いいたします。

補足情報（FW/ツールのバージョンなど）

PC：Windows11

Answer 1

まず、callの行の引用符が全角になっていますので、引用符の意味をなしません。
（全角と半角に無頓着だと、色々問題が起こります）

次に、文字列置換で*を使えるのは置換元の先頭だけです。set /?で表示される説明参照。
つまり、「(で終わる任意の文字列」を置換するのは可能ですが、「(で始まる任意の文字列」を置換する機能はありません。

そこで、「削除する文字列」をまず取り出して、それを空に置換するという方法を採る必要があります。
拡張子まで削除されるので、後で付けます。

変数の展開を2回する必要があるので、オーソドックスな方法として、遅延環境変数展開を使います。
（setlocal enabledelayedexpansionと書いておいて、2回目は%でなく!で変数展開）

@echo off
setlocal enabledelayedexpansion
for %%f in ( * ) do call :sub "%%f"
exit /b
:sub
set "fname=%~1"
set "fname=%fname: (=(%"
rem 括弧以前を削除した物をdelstrに入れる。つまり、括弧以降全部を delstr に入れる
set "delstr=%fname:*(=(%"
rem 括弧以降全部を削除
set "fname=!fname:%delstr%=!"
ren %1 "%fname%%~x1"
pause

Comments

[koburon]

回答ありがとうございます。
フォルダ内に重複する数字のファイルが1つ入っていたので、最初は「重複している」というようなエラーメッセージが表示されましたが、それを一旦別の場所に移動して再度実行したところ問題なく、連番のみのファイル名に変更できました。
こちらをベストアンサーとさせていただきます。

[otn]

もし一回しか実行しないのなら、別のアプローチとしては、
dir /b | clip
で、ファイル一覧をコピーして、Excelにペーストし、
列のコピーや、「データ」の「区切り位置」で空白や括弧やピリオドで分割などをして欲しいデータを作り、
"ren "と連結するなどで、目的の ren コマンドラインを作成して、
BATファイルにコピーして実行

あれこれ考えている間に出来ます。
一度きりでなく、週一や月一でこれをやるのはつらいので、その場合はこういうバッチ（や何らかのプログラム）を作りますが。

[koburon]

コメントありがとうございます。
実際、今回のような作業依頼は頻度が低く、ファイル数も50程度です。試しにExcelで
「ren　<<変更するファイル名>>　<<変更後のファイル名>>」と作成し、
でbatファイルをして実行したほうが早いと感じました。
参考にさせていただきます。

Answer 2

wshでやってみては

//rename.vbs

Set oFS = CreateObject("Scripting.FileSystemObject")
Set reg = CreateObject("VBScript.RegExp")
with reg
  .Pattern = "(.+)?\(.*?\)(\.pdf)$"
  .IgnoreCase = True
  .Global = True
end with 
Set oDir= oFS.GetFolder(".")
For Each oFile in oDir.files
  if reg.test(oFile.Name) then
    oFile.Name=reg.replace(oFile.Name,"$1$2")
  end if
Next 

パスを通すか、リネームするフォルダにvbsファイルをおき
「rename」もしくは「cscript rename.vbs」とする

Comments

[koburon]

回答ありがとうございます。
こちらも試して実行し、成功しました。