VBA DateDiff関数の使い方

Question

コンボボックスに日付を２つ入力してもらってその日付の日数差をDateDiffを使って表示するようにしたいです。
今のやり方では日数差ではなくよくわからない日付が出るのでやり方を教えてください。

Sub ボタン1_Click()
Dim n, g, p As Long
Dim h As String

n = ComboBox1.Text
g = ComboBox2.Text
p = ComboBox3.Text
h = n & "/" & g & "/" & p

Dim n2, g2, p2 As Long
Dim h2 As Date
Dim h3, dd As Date
n2 = ComboBox4.Text
g2 = ComboBox5.Text
p2 = ComboBox6.Text
h2 = n2 & "/" & g2 & "/" & p2

h3 = CDate(h)
dd = DateDiff("d", h2, h3)

MsgBox dd

End Sub

Answer 1

修正しました。以下のようにしてください。
不明点は、補足してください。

Sub ボタン1_Click()
    Dim n, g, p As Long
    Dim h As String

    n = ComboBox1.Text
    g = ComboBox2.Text
    p = ComboBox3.Text
    h = n & "/" & g & "/" & p

    Dim n2, g2, p2 As Long
    Dim hh As String
    Dim h2 As Date
    Dim h3 As Date
    Dim dd As Long
    n2 = ComboBox4.Text
    g2 = ComboBox5.Text
    p2 = ComboBox6.Text
    hh = n2 & "/" & g2 & "/" & p2
    h2 = CDate(hh)
    h3 = CDate(h)
    dd = DateDiff("d", h2, h3)

    MsgBox dd
End Sub

Answer 2

DateDiffの結果をDate型ではなくLong型で受け取れば正常に出てきます。
エクセルでも、適当な数字を入れて日付型を指定すると、それをシリアルとして変な日付が出てきますが、同じことが起きています。

Sub ボタン1_Click()
Dim n As Long, g As Long, p As Long
Dim h As String

n = ComboBox1.Text
g = ComboBox2.Text
p = ComboBox3.Text
h = n & "/" & g & "/" & p

Dim n2 As Long, g2 As Long, p2 As Long
Dim h2 As Date
Dim h3 As Date
Dim dd As Long
n2 = ComboBox4.Text
g2 = ComboBox5.Text
p2 = ComboBox6.Text
h2 = n2 & "/" & g2 & "/" & p2

h3 = CDate(h)
dd = DateDiff("d", h2, h3)

MsgBox dd

End Sub

Answer 3

Dim h3, dd As Date とddをDate型で宣言しているので日付表示になります。
日数差なので、Long型で宣言すればいいでしょう。
（ちなみに、上記のコードでは、h3 は Variant型になります。）

上記の点も含めて型宣言を正しく修正すると、下記のようなコードになります。

Sub ボタン1_Click()
    Dim n As String, g As String, p As String
    Dim h As String

    n = ComboBox1.Text
    g = ComboBox2.Text
    p = ComboBox3.Text
    h = n & "/" & g & "/" & p

    Dim n2 As String, g2 As String, p2  As String
    Dim h2 As String
    Dim dd As Long
    n2 = ComboBox4.Text
    g2 = ComboBox5.Text
    p2 = ComboBox6.Text
    h2 = n2 & "/" & g2 & "/" & p2

    dd = DateDiff("d", h2, h)

    MsgBox dd

End Sub

あと、CDate関数で、日付として成立するかどうかチェックするコードを追加した方がいいでしょう。