プロセッシングでエラーが出ておりどのように解決したらいいかわからない

Question

processing

The method join(String[], String) in the type PApplet is not applicable for the arguments (int[], String)とエラーが出てきました。どこがエラーの原因かわかりませんので教えてください。

ソースコード

void setup()
{
  int d[]={71, 84, 48, 92, 68, 24};
  size(500, 300);
  fill(#000000);
  textFont(createFont("meiryo", 20));
  text(join(d, " "), 50, 30);
  int o=getSummation(d);
  int p=getAverage(d);
  int u=getMax(d);
  int y=getMin(d);
  text("合計点 : "+str(o)+ "平均点"+str(p), 250, 150);
  text("最大点:"+str(u)+"最小点"+str(y), 270, 150);
}
int getSummation(int a[])
{
  int sum= 0 ;
  for (int i = 0; i < a.length; i++)
  {
    sum=sum+a[i];
  }
  return(sum);
}
int getAverage(int a[])
{
    int ave =0;
  for (int i = 0; i < a.length; i++)
{
  ave=ave+a[i]/ a.length;
}
return(ave);
}
{
  String s= str(data[0]);
  for (int i=1; i<data.length; i++)
  {
    s+=sep+str(data[i]);
  }
  return(s);
}
int getMax(int a[])
{
  int max=a[0];
  for (int i=1; a.length>i; i++)
  {
    if (a[i]>max)
    {
      max=a[i];
    }
  }
  return max;
}
int getMin(int a[])
{
  int min=a[0];
  for (int i=1; a.length>i; i++)
  {
    if (a[i]<min)
    {
      min=a[i];
    }
  }
  return min;
}

Comments

[TN8001]

質問はいつでも何度でも【編集】できるので、同じ内容の質問を複数立てないでください。

コードブロックの言語が「proxessing」と、ミスっているので色がついていません。
できれば【編集】して直してください。

【編集】の仕方がわからなければそのままでいいです^^;（新たに質問しなおしたりはしないでください）

[hoshi-takanori]

int[] を join するには nf を使うと良いらしい。
https://nobita-rx7.hatenablog.com/entry/28728224

[TN8001]

> int[] を join するには nf を使うと良いらしい。

ほう。それいただきます^^

リファレンスを見ると nf(int[] nums) がありそうに見えて、
nf(int[] nums, int digits) しかないのが地味にワナっぽいｗ

[nf() / Reference / Processing.org](https://processing.org/reference/nf_.html)

Answer 1

エラー文が分かりにくいですが↓がおかしいです。

// ココ
{
  String s= str(data[0]);
  for (int i=1; i<data.length; i++)
  {
    s+=sep+str(data[i]);
  }
  return(s);
}

前回の質問にあったjoin関数があるはずではありませんか？
processingコードのエラー

実は組み込みのjoin関数があるため、よくわからないエラー文になってしまいました。
join() / Reference / Processing.org

---

間違いではないけど気になった点

• 開き波かっこの改行
  void setup() {のように、改行を入れないほうが一般的です。
• C形式の配列宣言
  int[] dのように、角かっこを型のほうにつけるのが一般的です。
• return(sum);
  丸かっこは不要です（return sum;）
• 命名
  同じint配列なのに、dだったりaだったりdataだったり一貫性がないです。

最大値と最小値は、組み込み関数があります。
max() / Reference / Processing.org
min() / Reference / Processing.org

---

void setup() {
  size(500, 300);
  textFont(createFont("meiryo", 20));

  int[] array = { 71, 84, 48, 92, 68, 24, };
  int sum = getSummation(array);
  int ave = getAverage(array);

  fill(0);
  text(join(nf(array, 0), " "), 50, 30);
  text("合計点:" + sum + " 平均点:" + ave, 50, 150);
  text("最大点:" + max(array) + " 最小点:" + min(array), 50, 180);
}

int getSummation(int[] array) {
  int sum = 0;
  for (int i = 0; i < array.length; i++) {
    sum += array[i];
  }
  return sum;
}

int getAverage(int[] array) {
  int sum = getSummation(array);
  int ave = sum / array.length;
  return ave;
}

Comments

[ions]

プログラムのことだけでなく追加でのアドバイスまで教えていただきありがとうございます。