Processingでオブジェクトを拡大させたい

Question

processing でお花をmousePressedの時に2.0に拡大させたいのですが、鳥にまでかかってしまっているせいか、マウスを押すと鳥も花も消えてしまいます。
お花だけを拡大させるにはどうしたらよいのでしょうか。ご回答よろしくお願いします。

float x;
float easing = 0.02;

void setup() {
  size(400, 400);
  noStroke();
}

void draw() {
  background(176, 204, 226);

  fill(255, 165, 0);
  circle(350, 80, 50);

  tree();

  bird(50, 0);
  bird(0, -50);
}

void tree() {
  fill(160, 82, 45);
  rect(55, 250, 50, 150);

  fill(107, 142, 35);
  for (int i = 0; i < 6; i++) {
    for (int j = 0; j <= i; j++) {
      circle(80 - 15 * i + 30 * j, 170 + i * 20, 30);
    }
  }

if (mousePressed){
  scale(2.0);
} else{
  scale(1.0);
}

 stroke(0);
 line(350,350,350,400);
 fill(255,127,80);
 noStroke();
 ellipse(345,353,10,10);
 ellipse(355,353,10,10);
 ellipse(340,345,10,10);
 ellipse(358,345,10,10);
 ellipse(345,337,10,10);
 ellipse(354,337,10,10);
 fill(255,255,0);
 ellipse(349,345,10,10);
}

void bird(int offsetX, int offsetY) {
  float targetX = mouseX;
  x += (targetX - x) * easing;
  float y = 200;
  
  pushMatrix();
  translate(offsetX, offsetY);
  fill(255, 182, 193);
  circle(x + 50, y, 20);
  triangle(x + 35, y, x + 45, y - 5, x + 45, y + 5);
  arc(x + 75, y, 50, 50, radians(0), radians(180));
  arc(x + 65, y, 35, 35, radians(300), radians(360));
  popMatrix();
}

Answer 1

お花をmousePressedの時に2.0に拡大させたいのですが、鳥にまでかかってしまっているせいか、マウスを押すと鳥も花も消えてしまいます。

scaleはそれ以降効果が残りますので、当然birdにも影響します。
pushMatrix・popMatrixで、影響範囲を制限してください。
scale() / Reference / Processing.org
pushMatrix() / Reference / Processing.org
popMatrix() / Reference / Processing.org

お花だけを拡大させるにはどうしたらよいのでしょうか。

単にscale(2);とすると、左上を起点に2倍に拡大されます。
どこを中心として拡大したいのかを、scaleする前にtranslateで指定します。
translate() / Reference / Processing.org

どうなるべきかわからないので、とりあえず花の中央を中心としました。

float x;
float easing = 0.02;

void setup() {
  size(400, 400);
  noStroke();
}

void draw() {
  background(176, 204, 226);

  fill(255, 165, 0);
  circle(350, 80, 50);

  tree();
  flower();

  bird(50, 0);
  bird(0, -50);
}

void tree() {
  fill(160, 82, 45);
  rect(55, 250, 50, 150);

  fill(107, 142, 35);
  for (int i = 0; i < 6; i++) {
    for (int j = 0; j <= i; j++) {
      circle(80 - 15 * i + 30 * j, 170 + i * 20, 30);
    }
  }
}

void flower() {
  pushMatrix();
  translate(349, 345);
  if (mousePressed) scale(2);
  
  stroke(0);
  line(1, 5, 1, 55);
  
  fill(255, 127, 80);
  noStroke();
  for (int i = 0; i < 6; i++) {
    circle(9, 0, 10);
    rotate(radians(360 / 6));
  }
  
  fill(255, 255, 0);
  circle(0, 0, 10);
  
  popMatrix();
}

void bird(int offsetX, int offsetY) {
  float targetX = mouseX;
  x += (targetX - x) * easing;
  float y = 200;

  pushMatrix();
  translate(offsetX, offsetY);
  fill(255, 182, 193);
  circle(x + 50, y, 20);
  triangle(x + 35, y, x + 45, y - 5, x + 45, y + 5);
  arc(x + 75, y, 50, 50, radians(0), radians(180));
  arc(x + 65, y, 35, 35, radians(300), radians(360));
  popMatrix();
}

Comments

[Susan.S]

大変わかりやすくありがとうございます。
思う通りに作動しました！