VBAにおける#VALUE!の判定

Question

WEBAPIをエクセル上で取り扱う場合、標準関数としてWebService(URL)を利用できることを知りました。
標準関数として利用する場合に、対象となるものがなくエラーとなる場合に、セルに#VALUE!を返してくれるのですが、これをvba上で取り扱う場合、hereのようにIsErrorを利用しても特に識別することができません。
また、それが原因なのか、その後の条件分岐の最後で処理を終了するためにEndを付けると、全ての選択肢でセルは戻り値として#VALUE!を返してしまいます。

1. VBAでこのエラーを判定する方法はあるのでしょうか？
2. また、それぞれの分岐の選択でEndで処理を終了させる術はあるのでしょうか？

宜しくお願い申し上げます。

Function getId(reg As String, dat As String)
Dim userid
Dim Parse As Object
Dim Band_Member As Variant
Dim URL As String
Dim parsedUrl As String


userid = "XXXXX"
URL = "https://web-api.invoice-kohyo.nta.go.jp/1/valid?id=" & userid & "&number=" & reg & "&day=" & dat & "&type=21"
parsedUrl = WorksheetFunction.WebService(URL) '標準関数で対象のURLがない場合、#VALUE!を返す

If IsError(parsedUrl) Then 'here 
 getId = "ERROR:01"
Else
    Set Parse = JsonConverter.ParseJson(parsedUrl)
    If Parse("count") = 0 Then
     Debug.Print (1)
      getId = "ERROR:02"
      'End

     ElseIf Parse("count") = 1 Then
      Debug.Print (2)
      getId = "HIT!"
      'End
      
     Else
      Debug.Print (3)
      getId = "ERROR:03"
      'End
      
     End If   
  End If

End Function

Answer 1

Dim parsedUrl As String
を
Dim parsedUrl As Variant
にして
WorksheetFunction.WebService
を
Application.WebService
に変更すれば、iserrorで検出出来るかと思います。

endの件は何をしたいのかがよく分からないので分かりません。
Y.H.さんの言うように、exit functionの方が良いとは思いますが。

Comments

[Y.H.]

> endの件は何をしたいのかがよく分からないので分かりません。
endを使うとその時点でマクロが終了してしまい、戻り値が呼び出し元へ戻らないので
ワークシート関数として呼び出した際に、「#VALUE!」がセルに表示されてしまいますね。

[xail2222]

そうですね。
処理を抜けたいだけなら、exit functionですね。
ただそれだけなのかどうかを疑問に思ってしまって良くわからない。
と記載しました。

質問文のコードだけならexit function も無くても変わらなさそうだったので。

[SugiuraY]

コメント遅くなり申し訳ございません。
まずEndですが、単純に不要でした。ただ、処理を抜けるときにexit functionであることは存じ上げなかったため、ご教示を頂きありがとうございます。

[SugiuraY]

加えて、仰って頂いた通り、Application.を以下の通り利用したのですが、以下の通り、特にErrorを拾ってはくれません。発想に誤りがあればご指摘願えますでしょうか？

parsedUrl = Application.WebService(URL)
Debug.Print (parsedUrl)　'何も出力されない
If IsError(parsedUrl) Then 'falseを返してくれない
getId = "ERROR:01"　'
Else
'後略

[SugiuraY]

申し訳ございません、Variant型への変更の箇所を見落としました、実装できました！

Answer 2

VBAでこのエラーを判定する方法はあるのでしょうか？

エラー判定はこんな感じでやるしか無さそうですね

    Dim ret As String
    Dim isErr As Boolean
    
    On Error Resume Next
    ret = WorksheetFunction.WebService("http://foo.example.com/")
    isErr = Err.Number <> 0
    Err.Clear
    On Error GoTo 0
    
    If isErr Then
        Debug.Print "エラー"
    Else
        Debug.Print ret
        getId = ret
    End If

また、それぞれの分岐の選択でEndで処理を終了させる術はあるのでしょうか？

ENDではなく Exit Functionを使用しましょう。

Comments

[SugiuraY]

コメントありがとうございます。返信遅くなり誠に申し訳ございません。
拾うことはできたのですが、初心者故に以下の動作がErrオブジェクトにピンときません・・
On Error Resume Next
On Error GoTo 0
try-catchの中で例外をthrowしているようなものなのか、調べてみます。
また、Exit Functionについて理解できました、ありがとうございます！