VBA CSVデータ(UTF-8(BOM)付き)の読込

前提

Excel VBA で　CSVデータを読み込みExcelシートに出力する

CSVデータがSJISの場合、下記のソースで文字化けせずに読込ができますが
UTF-8(BOM有)の場合、文字化けします。

実現したいこと

ソースコードを大きく変更することなく、文字化けさせないようにするには
どのようにすればよいのでしょうか。

また、CSVデータ件数が多く、１件づつ読み込む方法では時間がかかるため、
以下の読込方法をできれば使いたい。

VBA
1    Open "C:\temp\data2.csv" For Binary As #1
2        ReDim buf(1 To LOF(1))
3        Get #1, , buf
4    Close #1

CSVデータ
・ヘッダーはダブルコーテーションなし
・データはダブルコーテーションあり、カラム内に改行コードあり
・行末はカンマで終わっている

(例)data2.csv

列1,列2,列3,
"0001","漢字１－１　漢字１－２","AAAAA",
"0002","漢字２ー１　
漢字２ー２","BBBBBBBBB",
"0003","漢字３ー１　漢字３ー２","漢字漢字",

該当のソースコード

VBA
1'CSVデータがSJisではOKのコード
2Public Sub test()
3    Dim buf() As Byte
4    Dim tmp As Variant, tmp2 As Variant
5    Dim i As Long
6    Dim t1 As String
7    Dim t2 As String
8    
9    Open "C:\temp\data2.csv" For Binary As #1
10        ReDim buf(1 To LOF(1))
11        Get #1, , buf
12    Close #1
13    
14    t1 = "," & vbCrLf
15    t2 = """," & vbCrLf
16    
17    buf2 = StrConv(buf, vbUnicode)
18    buf3 = Replace(buf2, t1, t2)
19    
20    tmp = Split(buf3 & "," & vbCrLf, """," & vbCrLf)
21    
22    For i = 0 To UBound(tmp) - 1
23        If i > 0 Then
24            tmp2 = Split(tmp(i), """,""")
25        Else
26            tmp2 = Split(tmp(i), ",")
27        End If
28        
29        tmp2(0) = Replace(tmp2(0), """", "")
30        tmp2(UBound(tmp2)) = Replace(tmp2(UBound(tmp2)), """", "")
31        Cells(i + 1, 1).Resize(1, UBound(tmp2) + 1).Value = tmp2
32    Next i
33End Sub

試したこと

補足情報（FW/ツールのバージョンなど）

Excle2016

行動規範の内容に同意します

回答2件

ベストアンサー

ADODB.Streamを使う方法
【VBA】BOM付きUTF-8形式でテキストファイルを読み込み・出力する方法

vba
1    With CreateObject("ADODB.Stream")
2        .Charset = "UTF-8"
3        .Open
4        .LoadFromFile  "C:\temp\data2.csv"
5        buf = .ReadText
6        .Close
7    End With

QueryTableを使う方法
【EXCEL VBA】UTF-8のCSVファイルを高速に読み込みたい | EXCEL VBA 研究所（入門）

BOMの有無に対応しているかは試したことないので不明
シートに出力するならこちらの方が高速らしい。

投稿2022/10/06 05:48

hatena19

総合スコア33699

km0815.lj

2022/10/06 08:24

ご回答ありがとうございます。 45000件程度、100桁程度のCSVデータで、 SJISを読み込む元のソースでは一瞬で読み取りが終わりますが、時間が少しかかりました(5分程度)。ただ、BOM有もBOM無も問題なく読込できましたので、こちらで対応させて頂きます。ありがとうございました。 ※この部分は buf2 = StrConv(buf, vbUnicode) buf3 = Replace(buf2, t1, t2) 以下に修正 'buf2 = StrConv(buf, vbUnicode)　コメントアウト buf3 = Replace(buf, t1, t2)　　　　'buf2をbufに変更

行動規範の内容に同意します