processingで決まった時間に移動が止まるようにしたい

Question

円をクリックした際にジャンプするようにして、ある床の面で止まるようにしたいです。
自分が考えたのは、mousePressedでジャンプするようにし、変位が０になるt = 1で状態を切り替えて、とまるようにしたいのですが、t = 1になったときにF が変わらないです。if を使うことしか思いつきません。なにか間違っているところがあれば教えていただけますでしょうか。
float y;
float t;
float v;
int F;
void setup()
{
frameRate(100);
F = 0;
t = 0;
y = 200;
v = 4.9;
size(800, 800);
background(255);
}
void mousePressed()
{
F = 1;
}
void draw()
{
if ( F == 1)
{
t = t + 0.01;
y = y -( v * t - 9.8/2 * t * t);
}
if ( t == 1 )
{
F = 0;
}
background(255);
circle(200, y, 50);
println(t);
println(F);
}

Comments

[thkana]

まだ内容精査していないのですが、
> なにか間違っているところがあれば
と聞いているということは、今のプログラムで一応期待通りに動いていて、でも見つけていない間違いがあるかも知れないから探せ、というリクエストなのでしょうか?

それと、ソースコードは適切に提示してください。
```
ソースコード部分
```
という記述をすればよいです。このサイトの「ヘルプ」の項目に書いてあります。

Answer 1

t = 1になったときにF が変わらないです。

println(t);としているのですから、1になっていないことはわかってると思うのですが...

例えば0.1を10回足しても、（正確に）1にはなりません。

float a = 0.1 + 0.1 + 0.1 + 0.1 + 0.1 + 0.1 + 0.1 + 0.1 + 0.1 + 0.1;
println(a); // 1.0000001
println(a == 1); // false

何故かはｇｇってください^^;
float 誤差 - Google 検索

で、どうするかですが↓あたりがありがちな対策でしょうか。

• ==で比較しない
  if (t >= 1)に変えてもいいなら話が早いです。
• 同じと言っていいほど差が小さいかを判断する
  if (abs(t - 1) < 0.001)のようにする（もっと小さい数字でいいけど）
  abs() / Reference / Processing.org
• （その変数は）floatを使わない
  tは整数(int）にして1ずつ足していき、使うところでt / 100.0する。

---

数学苦手だけどこういうことでいいんかな？？

final float g = 9.8; // 重力
final float v0 = 4.9; // 初速
float y1 = 200; // オリジナルy座標
float y2 = 200; // 改良y座標
float t; // 時間
boolean F; // ジャンプ中フラグ

void setup() {
  size(700, 300);
  frameRate(100);
  background(255);
}

void draw() {
  //background(255); // 残像残す

  float y3 = 200; // 高さ初期位置

  if (F) {
    t += 0.01;

    // 時刻tにおける高さを減算していったらおかしなことに
    y1 -= v0 * t - g / 2 * t * t;

    // 減算していくなら速度のほう（ただしm/sなわけだから本来/100すべき？
    y2 -= v0 - g * t;

    // 公式で今の高さを計算する（が、mだと小さすぎるのと↑と合わせるために100倍
    y3 -= (v0 * t - g / 2 * t * t) * 100;
  }

  //if (t >= 1) {
  //  F = false;
  //}
  if (abs(t - 1) < 0.001) {
    F = false;
  }

  translate(t * 100, 0); // わかりやすくするため全体を右に移動
  circle(100, y1, 50); // オリジナル

  translate(200, 0); //
  circle(100, y2, 50); // 改良

  translate(200, 0);
  circle(100, y3, 50); // 高さ計算
}

void mousePressed() {
  background(255);
  F = true;
  t = 0;
  y1 = 200;
  y2 = 200;
}

Comments

[thkana]

そもそもスジとしては、時間で管理するよりも「打ち上げたモノが再び地上に落ちてきた」ことを検出すべきと私は思いますけどね。重力加速度は変わらないにしても、初速が変わることはあるでしょうし。

で、その辺をいじろうとするとモノの位置の式が間違っていることにも気付くかも...

[TN8001]

> そもそもスジとしては、

「tじゃなくてyを見ろ」ということですね。
「ある床の面で止まる」ならそうですが、「決まった時間」とも言ってるのでどっちが重要なんでしょう。

> 式が間違っていることにも気付くかも...

なるほどそれが質問へのコメントの意味ですか。
確かに放物線になっていない気はしていました^^;

Processingだとｇもテキトウで、ｖｙを加算していくような例が多いですよね。
式ありきでそれを可視化するような課題なのかな？

[thkana]

> ある床の面で止まるようにしたいです
と書いているので。

電算機らしい処理としては、微小時間毎に速度に加速度を反映させて、その分変位させて...を繰り返していくのが「王道」のような気もしますが、せっかく綺麗な等加速度運動ならそれで計算するのもいいかなぁ、とは思います。