後から挿入したコードが処理されない

Question

前提

初心者です。
コマンドボタンを押すと元データを集計してメッセージボックスに表示させるコードを書いて正しい結果が表示されています。
それに追加で、元データに空白があった時にそれを知らせるメッセージを表示させて、それ以上先の処理に進まないようにしたいです。

困っていること

下記のコードを単体で実行すると正しい結果が表示されます。
ただ、もともとある「コマンドボタンを押すと元データを集計してメッセージボックスに表示させるコード」の中に埋め込むとその処理がスルーされてしまいます。

順番としては
①変数を宣言
↓
②元データに空白があることを知らせるループ（下記コードを挿入した）
↓
③元データを集計してメッセージボックスに表示（本処理）

以上のような流れになっています。
もともと①→③で正しく機能していました。
②単体では正しい結果が返されますが、
もとのコードに挿入しても②の処理を飛ばしてしまいます。

原因がわからないのですが、教えてもらえると助かります。

該当のソースコード

 Sub CommandButton1_Click()
 
    Dim WEM As String 
    Dim Pa As String
    Dim i As Long
    Dim j As Long
    
    
    WEM = CLng(DateValue(TextBox1.Value)) & "WE" 
    Pa = CLng(DateValue(TextBox1.Value)) & "a" 
    
        For i = 2 To Cells(Rows.Count, 1).End(xlUp).Row
        For j = 5 To 10
            If Worksheets("form1").Cells(i, j).Value = "" Then
                MsgBox "form1に抜けがあります。正しく入力してください。"
            Exit Sub
            End If
        Next
    Next
    
    On Error GoTo ErrorHandler '日付が正しく入力されないとエラーになるので　ErrorHandlerに飛ぶ
    MsgBox "報告全数 : " & WorksheetFunction.SumIf(Range("b:b"), Cells(2, 11), Range("d:d")) & vbCrLf & _
            "出席者数 : " & _
            WorksheetFunction.VLookup(WEM, Worksheets("form2").Range("C:J"), 8, False) & vbCrLf & _
            "----------------------------" & vbCrLf & _
            "Paの数 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 4, False) & vbCrLf & _
            "Pa1 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 5, False) & vbCrLf & _
            "Pa2 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 6, False) & vbCrLf & _
            "Pa3 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 7, False) & vbCrLf & _
            "Pa4 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 8, False) & vbCrLf & _
            "Pa5 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 9, False), vbOKOnly, “ Pa " & Format(TextBox1.Value, "yyyy年mm月")
            Exit Sub
ErrorHandler:
        MsgBox "年月日が正しく入力されませんでした"
End Sub

Comments

[hatena19]

提示のものには「元データを集計してメッセージボックスに表示させるコード」が含まれてません。
それも含めたコードに修正してください。(Sub から End Sub まで)

あと、空白セルが見つかった時は、③ の集計処理はしないということでいいでしょうか。

[Khaan_bank]

すみません。修正しました。
＞＞空白セルが見つかった時は、③ の集計処理はしないということでいいでしょうか。
はい。そういう動きをしてもらいたいです。

Answer 1

とりあえず、書き換えてみました。

Sub CommandButton1_Click()
 
    Dim WEM As String
    Dim Pa As String
    Dim i As Long
    Dim j As Long
    
    Worksheets("form1").Select

    If WorksheetFunction.CountBlank(Range(Cells(2, 5), Cells(Cells(Rows.Count, 1).End(xlUp).Row, 10))) > 0 Then
        MsgBox "form1に抜けがあります。正しく入力してください。"
        Exit Sub
    End If
    
    If Not IsDate(TextBox1.Value) Then
        MsgBox "年月日が正しく入力されてません"
        Exit Sub
    End If
    
    WEM = CLng(DateValue(TextBox1.Value)) & "WE"
    Pa = CLng(DateValue(TextBox1.Value)) & "a"
    
    MsgBox "報告全数 : " & WorksheetFunction.SumIf(Range("b:b"), Cells(2, 11), Range("d:d")) & vbCrLf & _
            "出席者数 : " & _
            WorksheetFunction.VLookup(WEM, Worksheets("form2").Range("C:J"), 8, False) & vbCrLf & _
            "----------------------------" & vbCrLf & _
            "Paの数 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 4, False) & vbCrLf & _
            "Pa1 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 5, False) & vbCrLf & _
            "Pa2 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 6, False) & vbCrLf & _
            "Pa3 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 7, False) & vbCrLf & _
            "Pa4 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 8, False) & vbCrLf & _
            "Pa5 : " & WorksheetFunction.VLookup(Pa, Range("A:I"), 9, False), vbOKOnly, " Pa " & Format(TextBox1.Value, "yyyy年mm月")

End Sub

修正したところは、
念のためにform1を選択しておく
空白のチェックは CountBlank 関数にまかせた。
日付が正しいかどうかをIsDate関数でチェックした

Answer 2

処理を同一シートで行うようコードを書き換えてみました。

With Worksheets("form1")
    For i = 2 To .Cells(.Rows.Count, 5).End(xlUp).Row
        For j = 5 To 10
            If .Cells(i, j).Value = "" Then
                MsgBox "form1に抜けがあります。正しく入力してください。"
                Exit Sub
            End If
        Next
    Next
End With