描画した円を両方消した時の判定。

Question

procesingで円をランダムに二つ画面に置いて、その二つともクリックして消した場合、boolean型変数をfalseにする方法を教えてください。

Comments

[TN8001]

円が１個ならできますか？
であれば論理和をとるだけです。
boolean showCircles = showCircle1 || showCircle2;

[|| (logical OR) / Reference / Processing.org](https://processing.org/reference/logicalOR.html)

[tapiokazaki]

class Ball {
int size=50;
float x=int(random(size/2, width-size/2));
float y=int(random(size/2, height-size/2));
float a=int(random(size/2, width-size/2));
float b=int(random(size/2, height-size/2));

boolean isClicked;
void display() {
if (!isClicked) {
ellipse(x, y, size, size);
}
}
void move() {
x = lerp(x, width / 2, 0.01);
y = lerp(y, height / 2, 0.01);
}
void Goal() {
if (isClicked) {
fill(0);
textAlign(CENTER);
textSize(40);
text("goal", 400, 400, 200, 200);
}
}
void judgeClicked() {
if (dist(x, y, mouseX, mouseY)<=size/2&&mousePressed) {
isClicked=true;
}
}
}

Ball[] b;

void setup() {
size(800, 800);
int N=2;
b=new Ball[N];
for (int i=0; i<N; i++) {
b[i]= new Ball();
}
}
void draw() {
background(255);
int i=2;
for (i=0; i<2; i++) {
b[i].move();
b[i].display();
b[i].judgeClicked();
b[i].Goal();
}
}
この場合に二つのボールの判定がわかりません。

[TN8001]

この欄はインデントされず見にくいので、質問を編集しコードブロックを使って提示していただきますようお願いします。
[teratail【テラテイル】｜ITエンジニア特化型Q&Aサイト](https://teratail.com/help/question-tips#questionTips37)

Answer 1

思っていたのと真偽が逆だったので、&&のほうがわかりやすいですね。

こんなイメージであっていますでしょうか？

int N = 2;
Ball[] b;
int fc;

void setup() {
  size(800, 800);
  b = new Ball[N];
  for (int i = 0; i < N; i++) {
    b[i] = new Ball();
  }
}

void draw() {
  background(255);

  boolean allClicked = true;
  boolean allHits = true;
  for (int i = 0; i < b.length; i++) {
    b[i].move();
    b[i].display();
    b[i].judgeClicked();
    allClicked = allClicked && b[i].isClicked;
    allHits = allHits && b[i].isHit();
  }

  if (!allClicked) {
    fc = frameCount;
  }
  fill(0);
  textAlign(CENTER);
  textSize(40);
  text("" + fc, 40, 40, 200, 200);

  if (allHits) {
    text("goal", 400, 400, 200, 200);
  }
}

class Ball {
  int size = 50;
  float x = int(random(size / 2, width - size / 2));
  float y = int(random(size / 2, height - size / 2));
  boolean isClicked;
  color c = color(255);

  void display() {
    if (isClicked) return;

    fill(c);
    ellipse(x, y, size, size);
  }

  void move() {
    if (isClicked) return;

    x = lerp(x, width / 2, 0.01);
    y = lerp(y, height / 2, 0.01);

    if (abs(x - width / 2) < 20 && abs(y - width / 2) < 20) {
      c = color(255, 0, 0);
    }
  }

  void judgeClicked() {
    if (isClicked) return;

    if (dist(x, y, mouseX, mouseY) < size / 2 && mousePressed) {
      isClicked = true;
    }
  }

  boolean isHit() {
    return isClicked && c == color(255);
  }
}

Comments

[tapiokazaki]

インデント汚くてすいません。なるほど！本当に助かります！あと、どちらかの円がウィンドウ中央に到着してしまったら消してもゴールが表示されないようにするにはどうすればいいですか？

[TN8001]

> インデント汚くてすいません。

質問はいつでも何度でも編集できるので、この質問から実践してください。

> なるほど！

if(hoge && fuga && piyo) みたいなのと同じ仕組みですね。

> どちらかの円がウィンドウ中央に到着してしまったら消してもゴールが表示されないようにするにはどうすればいいですか？

何かフラグを作ってもいいですが、sizeを0にするのが手軽でしょうか？（セコいｗ

void move() {
x = lerp(x, width / 2, 0.01);
y = lerp(y, height / 2, 0.01);

if (abs(x - width / 2) < 10 && abs(y - width / 2) < 10) {
size = 0;
}
}

10は適当に変えてください。

[TN8001]

if (dist(x, y, mouseX, mouseY) <= size / 2 && mousePressed)

<= を < にしないとドンピシャでクリックされたら消せちゃうかな？^^;

[tapiokazaki]

ボールが消えるまでの時間も計測しなければいけないので、中心に円がきた時も消さなければいけません。この場合だとどうなりますか？

[tapiokazaki]

間違えました消せるまでの時間ですね。

[TN8001]

size = 0なら消えたように見えませんか？

[tapiokazaki]

最後にプログラミングが始まってから自分で円を消せたところまでの時間も計測して出力しなければいけないので必然的に自分で円を消さなければいけません。

[TN8001]

あぁ勝手に消えるのではなく、あくまで消えるのはクリックによると。
で、中央に来てからのクリックはゴール判定せず、ノーカンにしたいという意味ですか。

ならやっぱり別のフラグがいるでしょうねぇ。

UXとしては「この範囲に入ったら」とか「色が変わったら」とか、もう手遅れということをわかるようになっているといいですね。

例えば色を変えることにしたならば、それをフラグとして利用することもできます。

[tapiokazaki]

たびたびすいません。
その場合だとコードはどうなりますか？

[TN8001]

> その場合だとコードはどうなりますか？

乗りかかった船ですしコードを書きたいから回答しているようなものなのでコードを提示することは別に構わないのですが、tapiokazakiさんもやることをやってください。

>> インデント汚くてすいません。
> 質問はいつでも何度でも編集できるので、この質問から実践してください。

回答と同じような体裁になるはずです。
[3-7. Markdownを利用しましょう](https://teratail.com/help/question-tips#questionTips37)