迷路ゲームの当たり判定について

Question

現在processingで迷路ゲームを作成しているのですが、
迷路を表示、キャラの操作まではできたのですが、
壁をすり抜けない機能とゴール機能が分かりません。
教えてもらえますと幸いです

 int map[][] = {{1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1},
 {1,0,1,0,0,0,0,0,1,0,0,0,0,1,0,0,0,1,0,1},
 {1,0,1,0,0,1,1,0,1,0,1,0,0,1,1,1,0,1,0,1},
 {1,0,1,0,0,0,1,0,1,0,1,1,0,1,0,0,0,0,0,1},
 {1,0,0,0,1,0,1,0,1,0,0,1,0,1,0,1,0,1,0,1},
 {1,0,1,0,1,0,1,0,0,0,1,1,1,1,0,1,1,1,0,1},
 {1,0,1,0,1,0,0,0,1,0,0,1,0,0,0,1,0,1,0,1},
 {1,1,1,0,1,1,0,1,0,0,0,1,0,1,0,1,0,0,0,1},
 {1,0,1,1,1,1,0,1,0,1,0,1,0,1,0,1,1,1,0,1},
 {1,0,1,0,1,0,0,1,0,1,0,0,0,1,0,0,0,0,0,1},
 {1,0,1,0,1,0,0,0,1,0,0,0,0,1,0,0,0,1,0,1},
 {1,0,1,0,1,1,1,0,1,0,1,1,0,1,1,1,0,1,0,1},
 {1,0,1,0,0,0,1,0,1,0,0,1,0,1,0,0,0,0,0,1},
 {1,0,0,0,1,0,1,0,1,0,0,1,0,1,0,1,0,1,0,1},
 {1,0,1,0,1,0,1,0,0,0,1,1,1,1,0,1,1,1,0,1},
 {1,0,1,0,1,0,0,0,1,0,0,1,0,0,0,0,0,1,0,1},
 {1,1,1,0,1,1,0,1,0,0,0,1,0,1,0,0,0,1,0,1},
 {1,0,0,0,0,1,0,1,0,1,0,1,0,1,0,1,1,1,0,1},
 {1,0,0,1,0,0,0,1,0,1,0,0,0,1,0,0,0,0,2,1},
 {1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1}};
 
 float speed = 30.0;
 float x = 30.0;
 float y = 30.0;
 
 
 void setup(){
 size(600,600);
 
 
 
 }
 
 void keyPressed() {
 if (key == CODED) { // コード化されているキーが押された
 if (keyCode == RIGHT) { 
 x += speed;
 }
 
 else if (keyCode == LEFT) {
 x -= speed;
 }
 else if (keyCode == UP) {
 y -= speed;
 } else if (keyCode == DOWN) {
 y += speed;
 }
 }
 }
 void draw(){
 background(255);
 fill(0,0,255);
 rect(x, y, 30, 30);
 for(int i = 0; i < 20; i ++){
 for(int j = 0; j < 20; j ++){
 if (map[j][i] == 1){
 fill(0);
 rect(i*30, j*30, 30, 30);
 
 
 }
 }
 }
 }

Comments

[thkana]

https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q12264446022
https://teratail.com/help#posted-otherservice
「やむを得ず複数のサイトに質問を投稿された場合は、質問内容にマルチポストをする理由を書き、他のサイトの投稿へのリンクを貼ってください。 また、解決した際には必ずteratail及びすべての投稿に解決した旨と、どのように解決したかを記載してください。」
対応して下さい。

Answer 1

迷路ゲームの当たり判定について

• x・yの変数はマップデータに合わせて、０～１９のintで保持するように変更する
  そうすれば自分の足元を、map[y][x]と簡単に取得できます。

• speedも１マスのサイズを表す変数（size）に変更する
  x・yがmapのインデックスになったので、x++等とすることで進むことになります。
  square(x * size, y * size, size)と、描画のほうで位置・サイスを調整します。

壁をすり抜けない機能

keyPressed()で実際にx・yを変更した後、map[y][x]が1だった場合は変更前の値に戻すようにします。

ゴール機能が分かりません。

2がゴールということでいいんでしょうか。
x・yをmapのインデックスと対応するように変更したので、if (map[y][x] == 2)とするだけでゴール判定となります。

とりあえず文字を表示しましたが、お好みに変更してください。

int[][] map = {
  {1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1},
  {1, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 1, 0, 1},
  {1, 0, 1, 0, 0, 1, 1, 0, 1, 0, 1, 0, 0, 1, 1, 1, 0, 1, 0, 1},
  {1, 0, 1, 0, 0, 0, 1, 0, 1, 0, 1, 1, 0, 1, 0, 0, 0, 0, 0, 1},
  {1, 0, 0, 0, 1, 0, 1, 0, 1, 0, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1},
  {1, 0, 1, 0, 1, 0, 1, 0, 0, 0, 1, 1, 1, 1, 0, 1, 1, 1, 0, 1},
  {1, 0, 1, 0, 1, 0, 0, 0, 1, 0, 0, 1, 0, 0, 0, 1, 0, 1, 0, 1},
  {1, 1, 1, 0, 1, 1, 0, 1, 0, 0, 0, 1, 0, 1, 0, 1, 0, 0, 0, 1},
  {1, 0, 1, 1, 1, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 1, 1, 0, 1},
  {1, 0, 1, 0, 1, 0, 0, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1},
  {1, 0, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 0, 0, 1, 0, 1},
  {1, 0, 1, 0, 1, 1, 1, 0, 1, 0, 1, 1, 0, 1, 1, 1, 0, 1, 0, 1},
  {1, 0, 1, 0, 0, 0, 1, 0, 1, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 1},
  {1, 0, 0, 0, 1, 0, 1, 0, 1, 0, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1},
  {1, 0, 1, 0, 1, 0, 1, 0, 0, 0, 1, 1, 1, 1, 0, 1, 1, 1, 0, 1},
  {1, 0, 1, 0, 1, 0, 0, 0, 1, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 1},
  {1, 1, 1, 0, 1, 1, 0, 1, 0, 0, 0, 1, 0, 1, 0, 0, 0, 1, 0, 1},
  {1, 0, 0, 0, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 1, 1, 0, 1},
  {1, 0, 0, 1, 0, 0, 0, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 2, 1},
  {1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1}};

int x = 1;
int y = 1;
int size = 30;


void setup() {
  size(600, 600);
  textSize(72);
  textAlign(CENTER, CENTER);
}

void keyPressed() {
  if (key == CODED) {
    int oldX = x;
    int oldY = y;

    if (keyCode == RIGHT) x++;
    else if (keyCode == LEFT) x--;
    else if (keyCode == UP) y--;
    else if (keyCode == DOWN) y++;

    if (map[y][x] == 1) {
      x = oldX;
      y = oldY;
    }
  }
}

void draw() {
  background(255);

  fill(0);
  for (int j = 0; j < 20; j ++) {
    for (int i = 0; i < 20; i ++) {
      if (map[j][i] == 1) {
        square(i * size, j * size, size);
      }
    }
  }

  fill(0, 0, 255);
  square(x * size, y * size, size);

  if (map[y][x] == 2) {
    fill(255, 0, 0);
    text("Congratulations", 0, 0, width, height);
  }
}