レコードのアルファベットだけ半角にする

Question

実現したいこと

平仮名・片仮名・漢字は全角のまま、アルファベットだけ半角にする

前提

アルファベットは全角表記だとダサい、半角にしたい
1つのセルの中にアルファベットと片仮名と漢字と平仮名が混在している

発生している問題・エラーメッセージ

StrConvだと片仮名も巻き添えで半角になる

該当のソースコード

コードとかは特にない

試したこと

StrConvで変換→先述した通り片仮名も巻き添えを食らう
『Access アルファベットだけ 半角に置換』で検索
『Access アルファベットだけ 半角変換』で検索

補足情報（FW/ツールのバージョンなど）

初心者なので優しく教えて下さい
尚、Replace関数を用いてＡ→A、ａ→ａ、、、という回答は論外とさせて頂きます

広告と受け取られるような質問

この修正依頼した奴、両目ついてる？

Answer 1

多分、正規表現を使った方が早いです。

s = "対象文字列"
Set re = CreateObject("VBScript.RegExp")
re.Pattern = "[Ａ-Ｚａ-ｚ]"
re.IgnoreCase = False
re.Global = True
For Each Match In re.Execute(s)
    Mid(s, Match.firstindex + 1, 1) = StrConv(Match.Value, vbNarrow)
Next Match

追記

グローバル変数？正規表現設定？専門用語が分からず回答がいまいちピンときません。
このコードをどこに配置したらいいんでしょうか？

とのことなので、サンプルです。ちょっと改善しておきました。
正規表現という概念を知らないということなので、コードの意味が分からないと思いますが。

Dim re 'これがグローバル変数（VBA用語ではモジュールレベル変数）。モジュール内の全Sub/Functionから使える
Sub メイン処理()
    Set re = CreateObject("VBScript.RegExp")
    re.Pattern = "[Ａ-Ｚａ-ｚ]+"
    re.IgnoreCase = False
    re.Global = True

    ～～～～～
    x = conv(x)
    ～～～～～
End Sub
Function conv(s as String) as String
    For Each Match In re.Execute(s)
        Mid(s, Match.firstindex + 1, Match.Length) = StrConv(Match.Value, vbNarrow)
    Next Match
    conv = s
End Function

追記２

初期化も関数内部で行うように変更。

Function conv(s As String) As String
    Static re As Object
    If re Is Nothing Then
        Set re = CreateObject("VBScript.RegExp")
        re.Pattern = "[Ａ-Ｚａ-ｚ]+"
        re.IgnoreCase = False
        re.Global = True
    End If
    For Each Match In re.Execute(s)
        Mid(s, Match.firstindex + 1, Match.Length) = StrConv(Match.Value, vbNarrow)
    Next Match
    conv = s
End Function

Comments

[otn]

関数にする場合は、re をグローバル変数にして、正規表現設定は関数の外で。

[退会済みユーザー]

グローバル変数？正規表現設定？専門用語が分からず回答がいまいちピンときません。
このコードをどこに配置したらいいんでしょうか？

[退会済みユーザー]

標準モジュール？というところに追記のコードをコピペしてみましたが何も変わっている感じがしません。

[退会済みユーザー]

標準モジュールに貼ってレポートを開きました

[otn]

> 標準モジュール？というところに追記のコードをコピペしてみましたが何も変わっている感じがしません。
???
元々のコードはどこに書いているのでしょうか？

[退会済みユーザー]

元々のコードとは？

質問を投稿した時点ではコードはどこにも記述しておりません。

[otn]

> 尚、Replace関数を用いてＡ→A、ａ→ａ、、、という回答は論外とさせて頂きます
もし、Replace関数でやるとしたら、そのReplace関数はどこに書くつもりだったのでしょうか？

[退会済みユーザー]

レポートのレコードソースにするクエリのフィールドを更新クエリで書く予定でした！

[otn]

そういうケースだと、モジュールレベル変数じゃなくてPublic変数ですね。
ちょっと初期化をどこでやった来意か分からないので、中に持つか。追記しておきます。

[退会済みユーザー]

度々すみませんが、初期化とはなんでしょうか？
また、その初期化を行う理由はなんでしょうか？

[otn]

単語にとらわれずにコードの意味を意味を考えましょう。
関数を何度も呼び出す訳ですが、毎回変数reの設定処理をするのは無駄なので、
関数が呼ばれた初回だけ変数reを設定して、2回目以降の呼び出しではreは設定済みなので設定をスキップします。

[otn]

今回の文脈での「初期化」とは、変数への初回の代入の事です。
もちろん一般的な日本語の単語なので文脈で意味が変わりますが。

[退会済みユーザー]

If re Is Nothing Then
ここで２回目以降reの設定を行わないようにしているということですね、理解できました。

[otn]

はい。その通りです。
static と書くことで、前回関数呼び出し時の値を保持するので。
static を書かないと毎回関数呼び出す毎に re は Nothing の値です。

CreateObject("VBScript.RegExp") の処理が重そう（CPU使用量的な意味で）なので、毎回はしたくない。

Answer 2

標準ではそのような関数や機能はないので、ユーザー定義関数を作成するか、変換テーブルを作成してそれを参照して変換するか、になりますね。

ユーザー定義関数なら例えば標準モジュールに下記のような関数を作成して、StrConvの代わりに使えばいいでしょう。

Function AlZenToHan(S As Variant) As String
    Dim i As Long
    Dim p As String
    AlZenToHan = Nz(S, "")
    For i = 1 To Len(AlZenToHan)
        p = Mid(S, i, 1)
        If p Like "[A-Za-z]" Then
           Mid(AlZenToHan, i, 1) = StrConv(p, vbNarrow)
        End If
    Next
End Function

Comments

[退会済みユーザー]

ＶＢＡあまり扱うのが得意ではないので置換用テーブルを作成してみます。

[hatena19]

VBAは使えるようになっておくと、今後、いろいろ使い出があるので、これを機会に学習されることをお勧めします。
今回に要件なら、回答のコードをコピーして、標準モジュールを新規作成して、そこに貼り付けるだけが使えるようになります。
クエリで使うなら、下記のフィールド欄に下記にように式を設定すればご希望の変換結果になります。

式1: AlZenToHan([フィールド名])

[hatena19]

フォームやレポートで使うなら、テキストボックスのコントロールソースに下記のように設定すればOKです。

=AlZenToHan([フィールド名])

[退会済みユーザー]

レポートのレコードソースに使用するクエリで使いたかったので、式の中に配置しました。
使い方も教え下さりありがとうございました。