Processingで四択クイズを作りたい。

Question

学校の課題で、四択クイズを作っている者です。
条件としてテキストファイルにかかれている問題と選択肢を使うことが条件だったので、とりあえず問題の表示とその問題の選択肢の表示まではできたのですが、その問題が正解か不正解を判定させるのに困っています。
mouseX,mouseYを使えば、マウスをクリックした座標の取得ができるということは調べてわかりましたが、どうしても特定の座標のテキストで条件分岐させる方法が分かりません。
最初は、if文でmouseX,mouseYをmouseClicked()内で取得して、そこで正解のテキストが書かれている座標と同じであれば、status=2の正解に移動、それ以外であれば、status=3に移動させようかと書いては見たのですが、判定されず、マウスをクリックしたら次の問題に移動してしまいました。
自分の頭ではこれが限界です。ヒントをよろしくお願いします。

processing java
コード
//以下が現状のコードです。
//課題の要件は、問題→正解か不正解か表示→次の問題(これを計3問)→合計スコアを表示で終了です。
String[]a;
String[]b;
int c = 0;
int score = 0;//スコア
int status = 0;
int count = 0;//問題をやった回数

void setup(){
size(500, 500);
PFont font = createFont("Meiryo", 50);
textFont(font);
a = loadStrings("課題.txt");
}

void draw(){// ゲームシーンの処理

if(status == 0){//問題を表示
background(255);
fill(0);
textAlign(CENTER);
textSize(80);
text("問題!",250,250);//「問題」を表示
}

if(status == 2){
background(255);
textAlign(CENTER);
textSize(80);
text("正解!",250,250);//「正解」を表示
score++;
count++;
status = 1;
}

if(status == 3){
background(255);
textAlign(CENTER);
textSize(80);
text("不正解",250,250);//「不正解」を表示
count++;
status = 1;
}

if(status == 4){// クリアシーンの処理
background(255);
textAlign(CENTER);
textSize(40);
text("正解数は",180,250);
text(score,280,250);
text("です。",360,250);
}
}

void mouseClicked(){
if(status == 1){

if(c<3){
b = split(a[c],",");
c++;
}

textSize(30);
background(255);
text(b[0],250,150);
text(b[2],140,200);
text(b[3],140,250);//1番目の問題の答え
text(b[4],140,300);//2番目の問題の答え
text(b[5],140,350);//3番目の問題の答え

}
}

void mousePressed(){
if(status == 0){
status = 1;
}
if(count == 3){
status = 4;
}
}

Comments

[meg_]

コードは「コードの挿入」で記入しましょう。

[nyhahaha]

使い方がよくわかっていないかったので、申し訳ないです。

[BeatStar]

使い方のヒント: https://qiita.com/kai0310/items/d6ad23d7e60eeb103c9d

質問は編集できるので編集してください。

Answer 1

mouseX,mouseYを使えば、マウスをクリックした座標の取得ができるということは調べてわかりましたが、どうしても特定の座標のテキストで条件分岐させる方法が分かりません。

何か枠なり四角でも選択肢の後ろに描くようにすれば、ユーザーもわかりやすいですし判定も書きやすくなると思います。

最初は、if文でmouseX,mouseYをmouseClicked()内で取得して、そこで正解のテキストが書かれている座標と同じであれば、status=2の正解に移動、それ以外であれば、status=3に移動させようかと書いては見たのですが、判定されず、マウスをクリックしたら次の問題に移動してしまいました。

遷移処理がいろいろなところに出てきて、混乱されているように見受けられます。

遷移（statusの変更）は、mouseClicked内でのみするようにします。
そして描画（text等）は、draw内でのみするようににします。
そうすれば役割が明確になり、見通しが良くなります。

---

if (status == 0) { }
if (status == 1) { }
if (status == 2) { }
if (status == 3) { }
if (status == 4) { }

と、

if (status == 0) { }
else if (status == 1) { }
else if (status == 2) { }
else if (status == 3) { }
else if (status == 4) { }

は、等価でないことに注意してください（後者はswitchに変換可能です）

statusはintだとわかりにくいので、enumをお勧めします。

---

正解の判定法が不明なので、b[1]に入っていると仮定しました^^;

String[] a;
String[] b;
int score;
int count;
Status status = Status.TITLE;

enum Status {
   TITLE, QUESTION, CORRECT, INCORRECT, RESULT,
}


void setup() {
  size(500, 500);
  textFont(createFont("Meiryo", 50));
  textAlign(CENTER, CENTER);
  rectMode(CENTER);

  //a = loadStrings("課題.txt");
  a = new String[] {
    "史上初の家庭用ゲーム機とされるものは？,オデッセイ（マグナボックス）,カラーテレビゲーム15（任天堂）,テレビブロック（エポック社）,オデッセイ（マグナボックス）,ホーム・ポン（アタリ）", 
    "「ドラゴンクエスト6 幻の大地」の定価(税抜）は？,１１，４００円,１４，８００円,１１，４００円,９，７００円,５，９００円", 
    "PlayStationの同時発売ソフトは？,リッジレーサー（ナムコ）,グランツーリスモ（SCE）,モータートゥーン・グランプリ（SCE）,チョロQ（タカラ）,リッジレーサー（ナムコ）", 
  };
}

void draw() {
  background(255);
  fill(0);

  switch(status) {
  case TITLE:
    textSize(80);
    text("問題!", 250, 250);
    break;

  case QUESTION:
    noFill(); // これなんでtext出るんだろう？？
    textSize(20);
    text(b[0], 250, 150);

    rect(250, 200, width*0.8, 40);
    text(b[2], 250, 200);

    rect(250, 250, width*0.8, 40);
    text(b[3], 250, 250);

    rect(250, 300, width*0.8, 40);
    text(b[4], 250, 300);

    rect(250, 350, width*0.8, 40);
    text(b[5], 250, 350);
    break;

  case CORRECT:
    textSize(80);
    text("正解!", 250, 250);
    break;

  case INCORRECT:
    textSize(80);
    text("不正解", 250, 250);
    break;

  case RESULT:
    textSize(40);
    text("正解数は" + score + "です。", 250, 250);
    break;
  }
}

void mouseClicked() {
  switch(status) {
  case TITLE:
  case CORRECT:
  case INCORRECT:
    if (count < a.length) {
      b = split(a[count], ",");
      count++;
      status = Status.QUESTION;
    } else {
      status = Status.RESULT;
    }
    break;

  case QUESTION:
    String ans = getAnswer();
    if (ans == null) break; // 選択肢範囲外

    if (ans.equals(b[1])) {
      score++;
      status = Status.CORRECT;
    } else {
      status = Status.INCORRECT;
    }
    break;

  case RESULT:
    count = 0;
    score = 0;
    status = Status.TITLE;
    break;
  }
}

String getAnswer() {
  if (isInside(250, 200, width*0.8, 40)) return b[2];
  if (isInside(250, 250, width*0.8, 40)) return b[3];
  if (isInside(250, 300, width*0.8, 40)) return b[4];
  if (isInside(250, 350, width*0.8, 40)) return b[5];
  return null;
}

// rectMode(CENTER)の場合での判定
boolean isInside(float cx, float cy, float w, float h) {
  return cx - w/2 < mouseX && mouseX < cx + w/2 && cy - h/2 < mouseY && mouseY < cy + h/2;
}

Comments

[jimbe]

>enumをお勧め
ついでに draw や mouseClicked での処理をそれぞれに含ませれば、 status の大きな switch が無くなりますね。

[TN8001]

> ついでに draw や mouseClicked での処理をそれぞれに含ませれば、 status の大きな switch が無くなりますね。

↓みたいな話ですよね？
enum Status {
TITLE {
@Override void draw() {
text("問題!", 250, 250);
}
};
abstract void draw();
}

「そういえばJavaはenumにメソッド書けるんだっけ」と思ってやってみたのですが、ネストしたenumはstaticになってしまいtext()が呼べなくなってしまいましたorz

※Processingの仕様上、コードはクラスの中に書いていることになります。
class App extends PApplet {
// ここの中に書いていることになる
}

わたしはいまだにJavaのネストしたクラスがよくわかってませんｗ

[nyhahaha]

TN8001さん、質問への詳しい解説ありがとうございます。
enumについては学校の授業内で出てこなかったと思うので、その考えは思いつきませんでした。
まだまだ知識不足であることを痛感し、この課題に再度、取り掛かる前にenumについて勉強しようと思います。
また、疑問が生まれたら、なるべく早くコメントしようと思います。
今回はありがとうございました。

[TN8001]

習ってなくて使いづらければ↓のようなのでも構いません。
int status = TITLE;
final int TITLE = 0, QUESTION = 1;

要は直接「if(status == 0)」・「status = 0」のように、数字が出てきてもわかんないよねって話です^^