ランダム関数の使い方

Question

float x, y, w, h;
int imgX;

PImage img[];
img[]=random(2);
void setup() {
size(800, 800);
/* パネルの大きさ*/
x = 20;
y = 300;
w = width - 40;
h = 400;

img=new PImage[10];
img[0]=loadImage("ika.png");
img[1]=loadImage("sake.png");

}

void draw() {
background(127);
showPanel(x, y, w, h); // パネルの表示
Display();
mato(imgX++);
}

画像をランダムに表示させるようにしたいのですが、いまいち使い方がよく分かりません。
教えてください。

Comments

[1T2R3M4]

https://processing.org/reference/random_.html
は既読ですか。
調べたこと、試したことを質問に追記していただけませんか。

[sho888]

お手数をおかけしてすいません。調べてはいるのですが、配列とランダム関数の組み合わせ方が分かりません。

[thkana]

では、ランダムではなく、例えば'0'キーと'1'キーで画像を切り替える、というお題だったらできるのですか?
(わかっていないのは「配列とランダム関数の組み合わせ方」ではないような気がするのです)

それはそれとして、「ランダムに表示される」というプログラムの動作はどういうものでしょう? 起動してからの動作を説明してみてください。(ランダムの話以外にも、「そうなの?」と思う点があって...)

Answer 1

配列とランダム関数の組み合わせ方が分かりません。

randomはfloat（小数）を返すので、配列のインデックスに使うにはint（整数）に直す必要があります。
random() / Reference / Processing.org
int() / Reference / Processing.org

PImage[] imgs;
PImage img;
float imgX;
float imgVX;

void setup() {
  size(800, 800);

  imgs = new PImage[] {
    loadImage("https://www.gravatar.com/avatar/1f4f0a2782fdb4f59c0acc14a7455416?d=identicon", "png"),
    loadImage("https://teratail-v2.storage.googleapis.com/uploads/avatars/u13/132786/KnkDDC5A_thumbnail.jpg"),
  };
  
  imgVX = random(1, 5); // 1以上5未満のfloat値
  
  float f = random(imgs.length); // 0以上2未満のfloat値（1.234のような）
  int i = int(f); // 0か1（小数点以下を切り捨てる）
  img = imgs[i];
  
  //img = imgs[int(random(imgs.length))]; // まとめて書くと
}

void draw() {
  background(127);

  mato();
}

void mato() {
  if (width < imgX) {
    imgX = 0;
    imgVX = random(1, 5);
    img = imgs[int(random(imgs.length))];
  }

  image(img, imgX, 150, 50, 50);
  imgX += imgVX;
}

Character[] charas;
Character chara;

void setup() {
  size(800, 800);

  PImage img1 = loadImage("https://www.gravatar.com/avatar/1f4f0a2782fdb4f59c0acc14a7455416?d=identicon", "png");
  PImage img2 = loadImage("https://teratail-v2.storage.googleapis.com/uploads/avatars/u13/132786/KnkDDC5A_thumbnail.jpg");
  charas =  new Character[] { new Character(img1, 0, 150, 2), new Character(img2, 0, 150, 3), };
  chara = charas[int(random(charas.length))];
}

void draw() {
  background(127);

  chara.move();
  chara.display();
}


class Character {
  PImage img;
  float xpos;
  float ypos;
  float xspeed;

  Character(PImage tempImg, float tempXpos, float tempYpos, float tempXspeed) {
    img = tempImg;
    xpos = tempXpos;
    ypos = tempYpos;
    xspeed = tempXspeed;
  }

  void display() {
    image(img, xpos, ypos, 50, 50);
  }

  void move() {
    xpos += xspeed;
    if (width < xpos) {
      xpos = 0;
      xspeed = random(1, 5);
      // ここでグローバル変数をいじるのはどうかとは思うが、まあいいでしょうｗ
      chara = charas[int(random(charas.length))];
    }
  }
}