VBA 配列の値を別の配列に代入するときの型エラー

Question

前提・実現したいこと

VBAで、CSVファイルを読み込み、そのファイルの中身を加工して、
CSVファイルとして書き出す、ということをやろうとしています。
・ボタンを設置して、起動する
・起動すると、ファイルダイアログが開き、CSVファイルを選択する
・選択したCSVファイルの最終行と列を確認し、二次元配列を宣言
・CSVファイルの内容を二次元配列へ格納
ここまで出来ました。
この後、標準モジュールに書いた構造体（Type)で作った二次元配列に読み込んだデータを入れたいです。

発生している問題・エラーメッセージ

実行時エラー13
型が一致しません。

該当のソースコード

Public Type hanyou
    order_zip_code()    As Variant
    order_address1()    As Variant
    order_name()        As Variant
    order_kana()        As Variant
    order_tel()         As Variant
    order_mail()        As Variant
End Type

Function test(ary)

 　Dim i As Long
    Dim hanyou() As hanyou
    ReDim Preserve hanyou(UBound(ary))
       
    For i = 1 To UBound(ary)       
        
        hanyou(i).order_zip_code = ary(i, 21)
        hanyou(i).order_address1 = ary(i, 22)
        hanyou(i).order_address2 = ary(i, 23)
        hanyou(i).order_name = ary(i, 24)
        hanyou(i).order_kana = ary(i, 25)
       
    Next

End Function




Sub Btn_Click()

    Dim ar()
    Dim arCSVdata() As Variant
    Dim arHanyou() As Variant
       
    FileType = "CSV ﾌｧｲﾙ (*.csv),*.csv"
    prompt = "CSV File を選択してください"
    
    '操作したいファイルのパスを取得
    FilePath = SelectFile(FileType, prompt)
    If FilePath = False Then    
        End
    End If
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    With FSO.OpenTextFile(FilePath, 8)
        ReDim ary(.Line - 1)
        .Close
    End With
    Set FSO = Nothing
  
    
    arCSVdata() = CsvToArray(FilePath, ar())
    
    arHanyou() = test(arCSVdata())
End

Function SelectFile(FileType, prompt) As Variant
    SelectFile = Application.GetOpenFilename(FileType, , prompt)
End Function

Function CsvToArray(a_sFilePath, a_sArLine())
    Dim oFS As New FileSystemObject '// FileSystemObjectインスタンス
    Dim oTS As TextStream           '// TextStream変数
    Dim sLine                       '// CSVファイルの行文字列
    Dim iLineCount                  '// CSVファイル行数
    Dim iCommaCount                 '// カンマ数
    Dim v                           '// カンマ分割後の配列
    Dim i                           '// ループカウンタ
    Dim iColumn
    
    '// 引数のファイルが存在しない場合は処理を終了する
    If (oFS.FileExists(a_sFilePath) = False) Then
        Exit Function
    End If
    
    '// 最終行を取得するために追加モードで開く
    Set oTS = oFS.OpenTextFile(a_sFilePath, ForAppending)
    '// CSVファイルの行数を取得
    iLineCount = oTS.Line - 1
    Call oTS.Close
    
    '// TextStreamオブジェクト作成
    Set oTS = oFS.OpenTextFile(a_sFilePath)
        
    i = 0
    iCommaCount = 0
    
    '// ファイルループ
    Do While oTS.AtEndOfStream <> True
        '// 1行読み込み
        sLine = oTS.ReadLine
        
        '// カンマで文字列を分割し配列化
        v = Split(sLine, ",")
        
        '// 現在行をカンマで分割した数が今までより多い場合
        If (iCommaCount < UBound(v)) Then
            '// 最大カンマ数を更新
            iCommaCount = UBound(v)
        End If
        
        i = i + 1
    Loop
    Call oTS.Close
    
    Erase a_sArLine
    ReDim a_sArLine(iLineCount - 1, iCommaCount)
    
    '// TextStreamオブジェクト作成
    Set oTS = oFS.OpenTextFile(a_sFilePath)
    
    i = 0
    
    '// ファイルループ
    Do While oTS.AtEndOfStream <> True
        '// 1行読み込み
        sLine = oTS.ReadLine
        
        '// カンマで文字列を分割し配列化
        v = Split(sLine, ",")
        
        '// カンマ区切り配列をループ
        For iColumn = 0 To UBound(v)
            '// カンマ区切りの内容を二次元配列に格納
            a_sArLine(i, iColumn) = v(iColumn)
        Next
        
        i = i + 1
    Loop
    Call oTS.Close
    CsvToArray = a_sArLine
End Function

試したこと

iが1から始まってるのは、読み込んだCSVの先頭行がカラム名になっているためです。
型をVariantで揃えてみましたが解消せず、でした。

Comments

[hatena19]

実際に動くコードを提示してください。
提示のコードではコンパイルすらできません。
nameという変数名は予約語なので使えない、 構造体XXXは使われていない、hanyouが宣言されていないなど。

また、「構造体（Type)で作った二次元配列」というのも何なのか不明瞭。

Answer 1

この後、標準モジュールに書いた構造体（Type)で作った二次元配列に読み込んだデータを入れたいです。

構造体は２次元配列とは異なります。
構造体のメンバーを配列するのではなく、構造体は1行分のデータを格納して、構造体を配列にします。

---

ユーザー定義型はVariant変数に入れることはできません。（下記参照）
ユーザー定義型・構造体（Type）｜VBA入門

当然、Variant型の配列に入れることもできません。
Dim arHanyou() As Variant → Dim arHanyou() As hanyou

---

配列を関数の戻り値にする方法は下記を参照。

VBAで配列を引数・戻り値にする方法 - Qiita

---

上記の点を考慮してコーディングしてください。

参考コード

Public Type hanyou
    order_zip_code    As Variant
    order_address1    As Variant
    order_address2    As Variant
    order_name        As Variant
    order_kana        As Variant
End Type

Function test(ary) As hanyou()
    Dim arHanyou() As hanyou
    ReDim Preserve arHanyou(UBound(ary))
    
    Dim i As Long
    For i = 1 To UBound(ary)

        arHanyou(i).order_zip_code = ary(i, 21)
        arHanyou(i).order_address1 = ary(i, 22)
        arHanyou(i).order_address2 = ary(i, 23)
        arHanyou(i).order_name = ary(i, 24)
        arHanyou(i).order_kana = ary(i, 25)
    Next

    test = arHanyou()
End Function

Sub Btn_Click()
    Dim arCSVdata() As String
    Dim arHanyou() As hanyou

    '二次元配列のサンプルデータ生成 
    ReDim arCSVdata(1 To 2, 21 To 25)
    arCSVdata(1, 21) = "123-4567"
    arCSVdata(1, 22) = "東京都"
    arCSVdata(1, 23) = "新宿区"
    arCSVdata(1, 24) = "山田"
    arCSVdata(1, 25) = "ヤマダ"
    arCSVdata(2, 21) = "234-5678"
    arCSVdata(2, 22) = "大阪府"
    arCSVdata(2, 23) = "大阪市"
    arCSVdata(2, 24) = "鈴木"
    arCSVdata(2, 25) = "スズキ"
    
    '二次元配列を構造体配列に変換
    arHanyou() = test(arCSVdata)
    
    'arHanyou() の内容の確認
    Dim i As Long    
    For i = 1 To UBound(arHanyou)
        Debug.Print arHanyou(i).order_zip_code
        Debug.Print arHanyou(i).order_address1
        Debug.Print arHanyou(i).order_address2
        Debug.Print arHanyou(i).order_name
        Debug.Print arHanyou(i).order_kana
    Next
    
End Sub