DataGridViewのカスタムコントロールのビルドエラーについて

Question

実現したいこと

https://teratail.com/questions/iz38sxqefzlx0z
↑の質問にて、C#でDataGridViewの編集中セルのEnterでのセル移動を制御するために
カスタムコントロールを作りました。

VB.NETでも同様のことをしたいのですが、エラー一覧にエラーは表示されませんが、
デバッグを実行すると「ビルドエラーが発生しました。続行して、最後に成功したビルドを実行しますか？」
のメッセージが表示されます。

正しいコードがわかりましたら教えて頂きたいです。

出力　を見ると、デバッグ実行時に以下の表示が出ています。

発生している問題・エラーメッセージ

１．
error BC30928: クラス 'DataGridViewEX' に指定された基本クラス 'DataGridView' は、その他の Partial 型の 1 つである基本クラス 'Control' と異なることはできません。

２．
error BC30284: 基底クラスで function をオーバーライドしないため、function 'ProcessDataGridViewKey' を 'Overrides' として宣言することはできません。

該当のソースコード

Imports System.ComponentModel

Public Class DataGridViewEX
    Inherits DataGridView

    Public Sub New()
        InitializeComponent()
    End Sub

    Public Event PressEnter As EventHandler(Of CancelEventArgs)

    <System.Security.Permissions.UIPermission(System.Security.Permissions.SecurityAction.Demand, Window:=System.Security.Permissions.UIPermissionWindow.AllWindows)>
    Protected Overrides Function ProcessDialogKey(ByVal keyData As Keys) As Boolean
        If (keyData And Keys.KeyCode) = Keys.Enter Then

            If Not OnPressEnter() Then
                Return MyBase.ProcessDialogKey(keyData)
            Else
                Return True
            End If
        End If

        Return MyBase.ProcessDialogKey(keyData)
    End Function

    <System.Security.Permissions.SecurityPermission(System.Security.Permissions.SecurityAction.Demand, Flags:=System.Security.Permissions.SecurityPermissionFlag.UnmanagedCode)>
    Protected Overrides Function ProcessDataGridViewKey(ByVal e As KeyEventArgs) As Boolean
        If e.KeyCode = Keys.Enter Then

            If Not OnPressEnter() Then
                Return MyBase.ProcessDataGridViewKey(e)
            Else
                Return True
            End If
        End If

        Return MyBase.ProcessDataGridViewKey(e)
    End Function

    Private Function OnPressEnter() As Boolean
        If PressEnterEvent IsNot Nothing Then
            Dim e As CancelEventArgs = New CancelEventArgs()
            RaiseEvent PressEnter(Me, e)
            Return e.Cancel
        End If

        Return False
    End Function

    Protected Overrides Sub OnPaint(ByVal pe As PaintEventArgs)
        MyBase.OnPaint(pe)
    End Sub
End Class

試したこと

・4行目のInherits DataGridViewを Inherits Controlに変更
↓
ビルド時の出力に表示される１．のエラーは表示されなくなりますが、
17行目と23行目のProcessDataGridViewKeyに対して
エラー BC30456 'ProcessDataGridViewKey' は 'Control' のメンバーではありません。
というエラーがエラー一覧に表示されます。

・13行目と27行目のProtected Overrides　のOverridesを削除
↓
ビルド時の出力に表示される２．のエラーは表示されなくなりますが、

警告 BC40005 function 'ProcessDialogKey' は、ベース class 'DataGridView' のオーバーライド可能なメソッドをシャドウします。ベース メソッドをオーバーライドするには、このメソッドは 'Overrides' に宣言されていなければなりません。
という警告がエラー一覧に表示されます。

Answer 1

これを作成する際にどのように作成されたのでしょうか？
既存のコントロールを継承したコントロールを作成されるのであればプロジェクトにユーザーコントロールを追加するのではなく
通常のクラスを追加して作成しましょう。

その時は

    Public Sub New()
        InitializeComponent()
    End Sub

このようなコンストラクタは必要ありません。

---

追記

何故このようなことになったかというと、カスタムコントロールを追加すると
CustomControl1.Designer.vbといった感じの隠しファイルが自動生成されて、

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
Partial Class CustomControl1
    Inherits System.Windows.Forms.Control

    'Control は、コンポーネント一覧に後処理を実行するために、dispose をオーバーライドします。
    <System.Diagnostics.DebuggerNonUserCode()> _
    Protected Overrides Sub Dispose(ByVal disposing As Boolean)
        Try
            If disposing AndAlso components IsNot Nothing Then
                components.Dispose()
            End If
        Finally
            MyBase.Dispose(disposing)
        End Try
    End Sub

    'コントロール デザイナーで必要です。
    Private components As System.ComponentModel.IContainer

    ' メモ: 以下のプロシージャはコンポーネント デザイナーで必要です。
    ' コンポーネント デザイナーを使って変更できます。
    ' コード エディターを使って変更しないでください。
    <System.Diagnostics.DebuggerStepThrough()> _
    Private Sub InitializeComponent()
        components = New System.ComponentModel.Container()
    End Sub

End Class

という感じでコードが自動生成されます。
そこにInherits System.Windows.Forms.ControlとControlを継承するように記載されているので、自分で書いたInherits DataGridViewと型が異なるというエラーが発生することになります。

Comments

[ohno1011]

YAmaGNZさん、昨日に引き続きありがとうございます。

おっしゃる通りプロジェクトの新規項目の追加でカスタムコントロールを作っていました。
通常のクラスを作りそちらにコードを書くことでエラーが無くなりました。

今回の現象についてまだ理解できていないのでまた調べてみます。

ありがとうございました。

[ohno1011]

YAmaGNZさん、わざわざ解説までありがとうございます。
納得がいきました。