VBA リストから中央値を取得したい

Question

前提・実現したいこと

VBAで写真のような果物と価格の表（A、B列）があったとき、D、E列に被っている果物の中央値を出力したいです（被っていない果物はそのまま出力）。この表は11行ですが、実際には何千行もあります。

該当のソースコード

作成したソースコードは以下の通りです。
6行目のThenとElseの間に中央値のコードを書きたいのですが、書き方がわからないです。
またコードを書くのが初めてなので、もし他にもおかしいところなどございましたら、お手数をおかけしますが、ご指摘いただけますと幸いです。

Sub 重複データから中央値を取り出す()

    Dim dData As New Dictionary
    Dim data As Variant
    
    data = Range("A1").CurrentRegion
    
    For i = 1 To UBound(data)
     If dData.Exists(data(i, 1)) Then
       
    Else
     dData.Add data(i, 1), data(i, 2)
    End If
    
Next i

Dim key As Variant
Keys = dData.Keys

For i = 1 To UBound(Keys)
    Cells(1 + i, "D").Value = Keys(i)
    Cells(1 + i, "E").Value = dData(Keys(i))
Next i

End Sub

試したこと

最大値の取得などと近いのかなと思い、調べたら出てきたのですがなかなかヒントが得られず、結局中央値の取得はできませんでした。

Comments

[mdj]

果物・値段でソートして、「りんご」の総数を取得して、総数の半分の値になったところを値段を取得したらよいです。総数が偶数なら中央の2件の平均値を取得したらよいです。

Answer 1

中央値は、データをソートして、その中央の値(偶数個なら中央2個の平均)を取得する必要がありますので、VBAだけでやろうとすると面倒ですし、重くなります。
MEDIANというワークシート関数がありますので、その式を埋め込むのが簡単でしょう。

Sub 重複データから中央値を取り出す()

    Dim dData As New Dictionary
    Dim data As Variant
    data = Range("A1").CurrentRegion.Value
    
    Dim i As Long
    For i = 2 To UBound(data)
        If dData.Exists(data(i, 1)) Then
            dData(data(i, 1)) = dData(data(i, 1)) & "," & data(i, 2)
        Else
            dData.Add data(i, 1), data(i, 2)
        End If
    Next i

    Dim keys As Variant
    keys = dData.keys
    
    For i = 0 To UBound(keys)
        Cells(2 + i, "D").Value = keys(i)
        Cells(2 + i, "E").Value = "=MEDIAN(" & dData(keys(i)) & ")"
    Next i

   '式を値に変換
    With Range("D2").CurrentRegion
        .Value = .Value
    End With
 
End Sub

Comments

[ritsu0308]

MEDIANの埋め込みをご教授いただきありがとうございます。
大変勉強になりました。
中央値を取得する方法がわからず、作成が止まってしまっていたため、本当に助かりました。
ご回答いただき、誠にありがとうございました。