【test – sheet】のハイフンをVBA上で？に文字化けすることなく記述する方法を探しています。

Question

実現したいこと

【test – sheet】 という文字列をVBAエディタに文字化けなしで表示させたい。

前提とエラー状況

エクセル2013で、xlsmファイルにてVBAマクロを記述しているのですが、VBAエディタ上で、【test – sheet】という定数をかきたいのです（【】除く）

【マクロによる業務効率を上げたい】
1．インポートするデータ一覧をシートに作成する。
2．シート名をダブルクリックして【test – sheet】に変更する。
3．xlsxファイルとして保存しなおし、業務システムに【test – sheet】シートの内容を読み込ませています。
ただ、毎日発生する作業のため、手動で毎回シート名をコピペするというのは時間の無駄になっています。

ALT+F11でVBAエディタを開き
インポート対象のデータをあらかじめ作成し、マクロで読み込み、シート名を【test – sheet】に変更する。というマクロを組みたいのです。むしろ完成しています。

ただ、コードは問題なくかけたのですが、【test – sheet】という名前をシート名につけて、処理しようとしたところ、「ハイフン」が文字化けするのです。

–　←文字化けするハイフン。今回使いたいハイフン。
-　←半角のハイフン
ー ←全角のハイフン。
※半角や全角ではなく、中間ぐらいのハイフンみたいなのです。

ALT+F11でVBAエディタを起動し、
ほかのsubプロシージャとかで使いまわせるように定数として下記のように一番上に記述しました。

【Public Const SheetName As String = "Create workflow ? template"】

すると、ハイフンが？に文字化けするのです。
普通の【-】ハイフンを使えばいいじゃないか？と思われるかもしれませんが、
システムにシートをインポートするのですが、インポート時にシート名としてこの文字化けするハイフンを使わないと駄目なようになっているのです。なので、現状文字化けしている【ハイフン】を使うしかありません。

【-】のハイフン等で置換すると、シート名が違うということで弾いてきます。

試したこと

ネットで調べて、VBAエディタの【ツール】→【オプション】→【エディタの設定】→フォントを明朝やメイリオといったいろいろなフォントに変えてみたりしましたが、ダメでした。

このハイフンを【？】にすることなく、【–】としてVBAエディタに記述する方法をご存じの方がおられませんでしょうか？

Comments

[xebme]

enダッシュ「–」(Unicode U+2013、JIS X 0213 1-1-30)
https://ja.wikipedia.org/wiki/%E3%83%80%E3%83%83%E3%82%B7%E3%83%A5_(%E8%A8%98%E5%8F%B7)
ASCIIに存在しないコードなのでエディタにコピペすると?に置き換わるようです。
ascW/chrW関数を調べてください。<- ?

[astaeta]

この文字enダッシュっていうのですね。
この文字が一体何なのかも調べる方法がわからず困っておりました。
情報ありがとうございました。

Answer 1

【test – sheet】という名前をシート名につけて、処理しようとしたところ、「ハイフン」が文字化けするのです。

–　←文字化けするハイフン。今回使いたいハイフン。

• VBAのモジュールにおいて、Unicode機種依存文字を文字列リテラルとして直接記述することは出来ない（インターフェースがUnicode機種依存文字の表示をサポートしていないため）。

• 代替手段としては、ChrW 関数を使用してその文字を取得し、他の文字列リテラルと文字列連結させるのが一般的である。

Cells(1, 1).Value = "Create workflow " & ChrW(8211) & " template"

ほかのsubプロシージャとかで使いまわせるように定数として下記のように一番上に記述しました。
【Public Const SheetName As String = "Create workflow ? template"】
すると、ハイフンが？に文字化けするのです。

• しかし、Const ステートメントによって定数を宣言する際、値を代入する式に変数や関数を使用することはできない。

結論: VBAにおいて、Unicode機種依存文字を含む文字列を定数として宣言することは不可能である。

別解: 定数ではなくユーザー定義関数として定義する。

Private Sub Test()
    
    '新規ブックを作成し、1つめのワークシートの名前を設定する
    Workbooks.Add.Worksheets(1).Name = TemplateSheetName

End Sub

Function TemplateSheetName() As String

    TemplateSheetName = "Create workflow " & ChrW(8211) & " template"

End Function

Comments

[astaeta]

ありがとうございます。

非常にわかりやすかったです。
なぜ定数として使えないのかも書いていただき納得できました。

ご提示いただいたユーザー定義関数を参考にさせていただいた結果、下記コードでデータの読み込みに成功しました。

大変助かりました。本当にご丁寧に解説していただきありがとうございました。

Sub CSV取り込みSHIFTJIS()
Dim SettingFileName, targetShitJIS_sheet As Variant

targetShitJIS_sheet = TemplateSheetName
MsgBox targetShitJIS_sheet

Sheets(targetShitJIS_sheet).Cells.Clear

SettingFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
Title:="CSVファイルの選択")
If SettingFileName = False Then
Exit Sub
End If

With Sheets(targetShitJIS_sheet).QueryTables.Add(Connection:="text;" & SettingFileName, Destination:=Sheets(targetShitJIS_sheet).Range("A1"))

.TextFilePlatform = 932 'SHIFTJIS
.AdjustColumnWidth = False '列の幅を自動計算しない
.TextFileCommaDelimiter = True 'コンマ区切り
.Refresh BackgroundQuery:=False 'シートに出力

.Delete
End With

Sheets(targetShitJIS_sheet).Activate

End Sub

'Create workflow ? template シート名を記入。
'
Function TemplateSheetName() As String
TemplateSheetName = "Create workflow " & ChrW(8211) & " template"
End Function

Answer 2

予め、テキストファイルに変更するシートの名前をUTF-8の文字コードで記述しておき、そのファイルを読み込んで、
その内容をシート名に設定する方法です。
マクロのあるブックと同じホルダに
sheet_name.txt という名称のファイルを作成します。
sheet_name.txtの1行目は
Create workflow – template
となっています。文字コードはUTF-8でBOM付きで保存します。
以下のマクロは上記のテキストファイルを読み込み、その内容で、Sheet1のシート名を
新しいシート名に変えます。シート名は、Create workflow – templateになります。

Public Sub シート名変更()
    Dim buf As String, Target As String
    Target = ThisWorkbook.Path & "\" & "sheet_name.txt"
    With CreateObject("ADODB.Stream")
        .Charset = "UTF-8"
        .Open
        .LoadFromFile Target
        buf = .ReadText(-2)
        .Close
    End With
    Worksheets("Sheet1").name = buf
End Sub

Comments

[astaeta]

ファイル名にシート名の名前を書いておく方法のご提示ありがとうございます。
ただ、シートを作成することが目的ではなく、【Create workflow – template】シート名にデータを読み込むという作業が最終目標なのです。提示いただいたコードで読み込みプログラムを考えてみたのですが、自分で作成することができませんでした。
ご提示いただいたのにすみません。

Answer 3

直接的な回答にはなりませんが、解決法の一案です。
1．インポートするデータ一覧をシートに作成する。
2．シート名をダブルクリックして【test – sheet】に変更する。
3．xlsxファイルとして保存しなおし、業務システムに【test – sheet】シートの内容を読み込ませています。
ということですが、
シート名をSheet1などにしておいて、xlsxファイルとして保存しなおし、
その後、pythonを使って、シート名を【test – sheet】に変更する。
ということでは、いかがでしょうか。pyhtonならutf-8でスクリプト記述できますので、【test – sheet】は
文字化けしません。
「シート名をダブルクリックして【test – sheet】に変更する。」手間と、pythonのスクリプトを実行する手間とで
たいした違いはないといえば、それまでになりますが・・・・。
python で「インポートするデータ一覧をシートに作成する。」ことも含めて、行うようにすれば、
pythonの実行だけですみますので、手間は減ります。

とりあえず、以下は、シート名をSheet1からCreate workflow – templateに変えるスクリプトです。
python3で作成しています。（文字コードはutf-8で作成すること）
ブック名はあなたの環境に合わせて適切に設定してください。

import openpyxl as px
# Sheet1をCreate workflow – template に変更する
pathname = "D:/goo/data9/0001支店.xlsx"
oldname = "Sheet1"
newname = "Create workflow – template"
wb = px.load_workbook(pathname)
ws = wb[oldname]
ws.title = newname
wb.save(pathname)

Comments

[astaeta]

解決方法の一案ご提示ありがとうございます。
パイソンを使うとそういう方法になるのですね。
ただ、今回VBAで動かしているので、途中で違う言語を挟んでしまうと、どこまでを「パイソン」「どこからをVBA」と考えることにもなり、障害時、私本人しかメンテナンスができなくなってしまう可能性がでてしまうためできればVBAで済ませたかったのです。

pythonコードのご提示ありがとうございます。
大変参考になりました。