Access VBA テキストボックスの値(yyyymmdd, yy/m/dなど)を日付型(yyyy/mm/dd)にする

Question

ACCESSのフォーム上に日付を入力するテキストボックスdodate(IMEは使用不可)があります。このテキストボックスに入力された文字列のうち、日付形式のものを日付型にします。年２桁or４桁、月日は各一桁の場合に0埋めするorしない、年月日の間にスラッシュありorなしの違いがあり、以下のような処理を考えました。「00/0/0」や「00000000」をはじくためにIsDate(dodate)を加えています。日付形式でないと判断したものは、再入力します。長くなったのですが、より簡素にする方法はないでしょうか。よろしくお願いします。

Private Sub dodate_Exit(Cancel As Integer)

    Dim datetest As Boolean
    If dodate Like "##/#/#" Or dodate Like "##/##/#" Or dodate Like "##/#/##" Or _
    dodate Like "##/##/##" Or dodate Like "####/#/#" Or dodate Like "####/##/#" Or _
    dodate Like "####/#/##" Or dodate Like "####/##/##" Then datetest = True
    If dodate Like "######" Then dodate = Format(dodate, "@@/@@/@@"): datetest = True
    If dodate Like "########" Then dodate = Format(dodate, "@@@@/@@/@@"): datetest = True
    If datetest And IsDate(dodate) Then
        dodate = CDate(dodate)
    Else
        MsgBox "日付を入力してください。"
        Cancel = True
    End If

end sub

Answer 1

とりあえず下記でどうでしょう。

Private Sub dodate_Exit(Cancel As Integer)
    Dim s As String
    s = Me.dodate.Text
    
    If s Like "######" Then s = Format(s, "@@/@@/@@")
    If s Like "########" Then s = Format(s, "@@@@/@@/@@")
    If s Like "*#/*#/#*" And IsDate(s) Then
        Me.dodate.Value = CDate(s)
    Else
        MsgBox "日付を入力してください。"
        Cancel = True
    End If
End Sub

ただし、IsDateやCDateは可能な限り日付に変換しようとしますので、「012345」と入力してもエラーにはならず「2045/01/23」と日付に変換します。それらもエラーにしたいならもう少し複雑になります。

Comments

[mnbwqz]

ありがとうございます。判定はこの量で大丈夫だと思います。
大変短くなりました。感謝。