IFを使用した日付の比較（データ型の設定）とその処理

Question

実現したいこと

参考：https://teratail.com/questions/303318

上記を参考に
sheet1　E列の注文番号とsheet2　A列の注文番号が一致している場合
かつ
sheet1　Q列の日付とsheet2　E列の日付が一致している場合
に、sheet1　E列の注文番号の背景を赤色にしたいです。

該当のソースコード

Sub 日付が一致しているかチェック(ByVal clear_flag As Boolean)
    Dim x As Long
    Dim i As Long
    With Sheets("Sheet1")
        x = .UsedRange.Cells(.UsedRange.count).Row
        If clear_flag = True Then
            .Range("Q2:Q" & x).Interior.Pattern = xlNone
        End If
        For i = x To 2 Step -1
            If Sheets("Sheet2").Range("E:E").Find(What:=.Cells(i, 17), LookAt:=xlWhole) Then
                .Cells(i, 5).Interior.Color = RGB(255, 0, 0) 
            End If
        Next i
    End With
End Sub

困っていること

日付はAs Dataを使用するかと思いますが、修正する箇所が分からず困っておりますので、ご教授いただけますと幸いです。

Comments

[y_waiwai]

提示のコードではどういう問題があるんでしょうか。
そして、それをどうしたいということなんでしょう

[退会済みユーザー]

提示のコードではどういう問題があるんでしょうか。
→オブジェクト変数またはWithブロック変数が設定されていません。というエラーが発生してしまいます。

そして、それをどうしたいということなんでしょう
→実現したい事に記載させていただきましたが
　sheet1　Q列の日付とsheet2　E列の日付が一致している場合は、sheet1　E列の背景を赤色にしたいです。

[hatena19]

そのエラーが発生したときに、エラーダイアログのデバッグボタンを押したとき、どの行が反転表示されますか。

[退会済みユーザー]

hatena19さん

そのエラーが発生したときに、エラーダイアログのデバッグボタンを押したとき、どの行が反転表示されますか。
→下記になります。
　If Sheets("Sheet2").Range("E:E").Find(What:=.Cells(i, 17), LookAt:=xlWhole) Then

また記載が漏れていたので、実現したい事に追記させていいただきましたが
sheet1　E列の注文番号とsheet2　A列の注文番号が一致している場合
かつ
sheet1　Q列の日付とsheet2　E列の日付が一致している場合
に、sheet1　E列の注文番号の背景を赤色にしたいです。

Answer 1

Sheet1の日付のみを取得するように変えました。（時分秒は無視します）
及び下記のコーディング誤りを修正しました。
For row1 = 2 To maxrow2　-> For row1 = 2 To maxrow1

Public Sub 注文番号及び日付チェック()
    Dim dicT As Object      'キー：注文番号＋日付　値：Sheet2の行番号
    Dim maxrow1 As Long     'Sheet1     最終行
    Dim maxrow2 As Long     'Sheet2     最終行
    Dim key As String
    Dim sh1 As Worksheet    'Sheet1
    Dim sh2 As Worksheet    'Sheet2
    Dim row1 As Long
    Dim row2 As Long
    Dim wdate As Date
    Set dicT = CreateObject("Scripting.Dictionary") ' 連想配列の定義
    Set sh1 = Worksheets("sheet1")
    Set sh2 = Worksheets("sheet2")
    maxrow1 = sh1.Cells(Rows.Count, "E").End(xlUp).Row 'Sheet1 E列 最終行を求める
    maxrow2 = sh2.Cells(Rows.Count, "A").End(xlUp).Row 'Sheet2 A列 最終行を求める
    sh1.Range("E2:E" & maxrow1).Interior.Pattern = xlNone
    'Sheet2の注文番号＋日付を記憶
    For row2 = 2 To maxrow2
        key = sh2.Cells(row2, "A").Value & "|" & sh2.Cells(row2, "E").Value
        dicT(key) = row2
    Next
    'Sheet1を処理する
    For row1 = 2 To maxrow1
        wdate = Int(sh1.Cells(row1, "Q").Value)
        key = sh1.Cells(row1, "E").Value & "|" & wdate
        '注文番号＋日付がSheet2にも存在するなら赤色背景を設定
        If dicT.exists(key) = True Then
            sh1.Cells(row1, "E").Interior.Color = RGB(255, 0, 0)
        End If
    Next
    MsgBox ("完了")
End Sub

Comments

[退会済みユーザー]

tatsu99さん

ご回答ありがとうございます。
実現したい事の記載に漏れがありました。

sheet1　E列の注文番号とsheet2　A列の注文番号が一致している場合
かつ
sheet1　Q列の日付とsheet2　E列の日付が一致している場合
に、sheet1　E列の注文番号の背景を赤色にする事は可能でしょうか。

お手数をおかけし申し訳ございません。

[tatsu99]

要件が変わるので、全面的に作り変えになります。
回答を作り変えました。

[hatena19]

要件が変わってますので、質問の方もそのように変更してください。

[退会済みユーザー]

tatsu99さん

ご回答ありがとうございます。
恐らく問題ないとは思いますが、データの性質上、下記の条件によって私は確認できない状況です。

sheet1　Q列の日付（ユーザー定義）
2022/03/15 00:00

sheet2　E列の日付（短い日付形式）
2022/3/15

こちらの表示形式の違いで一致していないと判定されてしまうでしょうか？
データの形式はダウンロードした状態から変えられないため、ご教授いただけますと幸いです。

[tatsu99]

Sheet1 Q列の書式設定はどうなってますか？
こちらで書式設定に
yyyy/mm/dd hh:mm
を設定して　2022/01/02 00:00
　のようにして確認しましたが、正常に処理されます。
（一致していると判定し、赤色背景になります）
あなたの書式設定の内容は具体的にどうなってますでしょうか。

[退会済みユーザー]

ご確認ありがとうございます。

同じくyyyy/mm/dd hh:mmになっておりますが、データ上では秒数までありました。
（表示上は00:00でしたが、0:00:00のデータとなっております。）

[hatena19]

00:00 か 0:00:00 は表示上の問題で、今回の現象の本質とは関係ないです。

書式設定を秒まで表示できるよう(ユーザー定義 yyyy/m/d h:mm:ss)にしたとき、0:00:01 のように、0:00:00 以外になっているセルはないか確認してみてください。

[tatsu99]

回答を以下のように変えました。
Sheet1の日付のみを採用するようにしました。（時分秒は無視します）

[退会済みユーザー]

ご対応ありがとうございます。
確認できました。

Answer 2

コメントにあるような複数条件の場合は、Findメソッドでは無理なので、
tatsu99さんの回答のようにDictionaryを使うか、CountIfs のような関数を使う方法になります。

CountIfsを使う場合のコード例です。

Public Sub 注文番号及び日付チェック2()
    Dim rng1 As Range, rng2 As Range '検索対象列のセル範囲
    With Worksheets("sheet2")
        Set rng1 = .Range("A2", .Cells(Rows.Count, "A").End(xlUp))
        Set rng2 = .Range("E2").Resize(rng1.Rows.Count)
    End With
    
    Dim rngE As Range '注文番号のセル範囲
    With Worksheets("sheet1")
        Set rngE = .Range("E2", .Cells(Rows.Count, "E").End(xlUp))
    End With
    rngE.Interior.Pattern = xlNone '前回の背景色変更をリセット
    
    Dim c As Range
    For Each c In rngE
        If WorksheetFunction.CountIfs(rng1, c, rng2, c.Offset(, 12)) > 0 Then
            c.Interior.Color = vbRed
        End If
    Next
    MsgBox ("完了")
End Sub

Comments

[退会済みユーザー]

hatena19さん

ご回答ありがとうございます。
tatsu99さんと同じ内容になってしまいます。
恐らく問題ないとは思いますが、データの性質上、下記の条件によって私は確認できない状況です。

sheet1　Q列の日付（ユーザー定義）
2022/03/15 00:00

sheet2　E列の日付（短い日付形式）
2022/3/15

こちらの表示形式の違いで一致していないと判定されてしまうでしょうか？
データの形式はダウンロードした状態から変えられないため、ご教授いただけますと幸いです。

[hatena19]

sheet2　E列の日付 の書式設定を yyyy/mm/dd hh:mm にしたときに、時刻が 00:00 以外になっているデータがありませんか。

[退会済みユーザー]

秒数まで入っているデータがありました。

表示上は00:00でしたが、0:00:00となっております。

Answer 3

Find関数が見つからなかった場合の戻り値はNothingです。
現在のままではSheet2のE列に対象の日付がない場合エラーになります。
Sheets("Sheet2").Range("E:E").Find(What:=.Cells(i, 17), LookAt:=xlWhole) Is Nothing
にして確認してください。
https://learn.microsoft.com/ja-jp/office/vba/api/excel.range.find

Answer 4

回答ではありません。補足要求です。
レイアウトが判りませんが、添付図のようになっていると理解して良いですか。
添付図の例では、E4、E5のセルの背景色を赤にしたいと理解しましたが、あってますが。
もし、レイアウトが異なる場合は、画像で提示してください。

Comments

[退会済みユーザー]

ありがとうございます。

レイアウトが判りませんが、添付図のようになっていると理解して良いですか。
添付図の例では、E4、E5のセルの背景色を赤にしたいと理解しましたが、あってますが。
→背景を赤くしたいsheet1　E列は注文番号になっています。
（sheet1　Q列の注文日時＝sheet2　E列の入金確定日時 が一致している事を確認したいという意図になります）
　その他レイアウトは添付の理解で問題ありません。