accessのVBAで条件付き書式を設定したい。

Question

締め切り一覧をaccessの表形式のフォームで管理しています。
締め日のレコードは赤文字で表示し、締め日を意識付けたいのですが
うまくvbaを組むことができません。

例えば、締め日が本日のものだけを赤くしたいときは以下のコードを記載していますが
一番上のレコードの日付が条件に合致していると、すべてのレコードが赤文字になり
一番上のレコードの日付が条件に合致していないと、すべてのレコードの色が変わりません。

Private Sub Form_Open(Cancel As Integer)

If [入力日時] = #1/15/2022# Then
[入力日時].ForeColor = &HFF
End If

End Sub

どのようにしたらレコードごとに条件判定をさせることができるでしょうか。

※条件式書式を使っていないのは、締め日の条件を
1億円以上は土日水除く5営業日前、1億円未満は土日水を除く2営業日前としており
その判別式の組み方がvbaでしか分からなかったためです。

Answer 1

Accessは、コントロールのプロパティを各レコード毎に保持しいるわけではないので、すべてのレコードで同じ設定になります。
レコード毎に書式を変えたい場合は、条件付き書式しかありません。

※条件式書式を使っていないのは、締め日の条件を

1億円以上は土日水除く5営業日前、1億円未満は土日水を除く2営業日前としており
その判別式の組み方がvbaでしか分からなかったためです。

フォームのレコードソースのクエリにその条件をもとに締め日を計算する演算フィールドを追加して、それをもとに条件付き書式を設定してください。

「1億円以上は土日水除く5営業日前、1億円未満は土日水を除く2営業日前」という条件は式だけだと複雑になりすぎるので、ユーザー定義関数をVBAで作成するといいでしょう。

テーブルのフィールド構成などの情報が不足しているので、一般的な場合のサンプルコードを提示しておきますので、必要に応じて修正して使用してください。

標準モジュールに下記の関数を作成します。

Public Function 締日(金額, 日付)
    If IsNull(金額) Then Exit Function
    If IsNull(日付) Then Exit Function
    
    Dim cnt As Long, days As Long
    cnt = 0
    If 金額 >= 100000000 Then days = 5 Else days = 2
    締日 = 日付
    Do
        締日 = 締日 - 1
        Select Case Format(締日, "aaa")
        Case "土", "日", "水"
        Case Else
            cnt = cnt + 1
        End Select
    Loop Until cnt = days
End Function

クエリのフィールド欄に下記の式を設定します。

締日: 締日([金額],[日付])

これで締日が表示されますので、これを元に条件付き書式を設定すればいいでしょう。

Comments

[t_msd]

ご丁寧にありがとうございます。
レコードごとに計算をさせることは出来たので条件付き書式も出来ると思っていましたが、そういうものなのですね。

明日、上記を元に組んでみたいと思います。