VBAでセル参照とFormat関数を使用して複数階層フォルダを作成したい

Question

下記コードにてフォルダ作成をしたいと考えておりましたが、月が変わっても年月の含まれたフォルダが作成されない状況です。エラー等はは発生せず、ただ作成されずに終了します。
Aというフォルダにコードを実行するファイルと注文書2022フォルダを置いています。
例として
注文書2022→○○→○○2022.06
を作成することはできておりましたが、7月に実行しても○○2022.07フォルダが作成されません。
自分なりに調べてみると最下層しか作成されないということでしたが、最下層の作成をしているので問題ないと考えていました。
試しに○○以下を削除すると新たに○○→○○2022.07が作成されることまでは確認できました。
○○→○○2022.06が存在していると月が変わったと時に該当月のフォルダが作成されないようでした。
前月のフォルダが存在していても毎月新しいフォルダが作成されるようにするためにはどのような変更をしたらよいか教えていただけないでしょか。よろしくお願いいたします。

Sub フォルダ作成()
    
    Dim xRg As Range
    Dim xCell As Range
    Dim xRgVList As Range
    
    Set xRg = Worksheets("注文書").Range("AA11")
    Set xRgVList = Evaluate(xRg.Validation.Formula1)
    
        For Each xCell In xRgVList
            xRg = xCell.Value
    
    Dim objFso As Object
    Set objFso = CreateObject("Scripting.FileSystemObject")


    If objFso.FolderExists(ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11")) Then
   
    Else
        objFso.CreateFolder (ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11"))
        
    
        If objFso.FolderExists(ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11") & "\" & Range("AA11") & Format(Date, "yyyy.mm")) Then
       
        Else
            objFso.CreateFolder (ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11") & "\" & Range("AA11") & Format(Date, "yyyy.mm"))
      
        End If
    
    End If

    Set objFso = Nothing
    

            
        Next

End Sub

Answer 1

2回目以降はElseに入らないからでは。

    If Not objFso.FolderExists(ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11")) Then
        objFso.CreateFolder (ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11"))
    End If
   
    If Not objFso.FolderExists(ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11") & "\" & Range("AA11") & Format(Date, "yyyy.mm")) Then
        objFso.CreateFolder (ThisWorkbook.Path & "\注文書2022" & "\" & Range("AA11") & "\" & Range("AA11") & Format(Date, "yyyy.mm"))
    End If

---

＜追記＞
少し書き換えてみました。

    Dim wPath, wSubPath
    wPath = ThisWorkbook.Path & "\注文書2022" & "\" & xRg.Value
    wSubPath = wPath & "\" & xRg.Value & Format(Date, "yyyy.mm")
    
    If Not objFso.FolderExists(wPath) Then objFso.CreateFolder wPath
    If Not objFso.FolderExists(wSubPath) Then objFso.CreateFolder wSubPath

Comments

[provisional]

さっそくご回答ご教示くださりありがとうございます。
そもそもElseに入らないからエラーにもならなかったんですね。ご教示いただいたコードで希望通りの動きになりました。簡潔にもしていただきありがとうございます。
繰り返し読み解き、勉強したいと思います。次はファイル移動をしたいと考えていますが、また悪戦苦闘しそうです。
ありがとうございます。