ERRORLEVELが想定と異なる

Question

実現したいこと

ERRORLEVELにPowershellの戻り値を反映させたいです。

前提

シェル側でIP疎通確認を行い、その結果を0,1で戻り値としてバッチファイルに返却する処理を行っています。

発生している問題・エラーメッセージ

エラーは特にありませんが、シェル側の戻り値がERRORLEVELに反映されず、全て1で返ってきてしまいます。

該当のソースコード

ip.confにはipアドレスを任意数分、縦に並べているイメージです。
バッチファイルよりシェルを呼び出しています。

@echo off
for /f %%i in (.ip.conf) do (
	powershell ".netCheck.ps1 %%i;exit $LASTEXITCODE"	
	echo %%i : %ERRORLEVEL%
)

Param(
	[String]$ip
)

if( (Test-NetConnection $ip -WarningAction SilentlyContinue ).PingSucceeded ){
	exit 0
}else{
	exit 1
}

試したこと

シェルのexitは問題ないことを確認しました。
バッチファイルに戻ってきてから想定と異なる動きとなっているようです。

補足情報（FW/ツールのバージョンなど）

Powershell：5.1.22621.963

Answer 1

Windowsの%に依る環境変数展開は、一般のプログラミング言語の変数値参照とは異なります
展開は文の実行に先立って行単位で行われます。コマンドプロンプトでのset /?の説明から引用すると、

 set VAR=before
 if "%VAR%" == "before" (
 set VAR=after;
 if "%VAR%" == "after" @echo If you see this, it worked
 )

この例は、論理的には IF 文が別の IF 文の本体に含まれる複合文なので、
両方の IF 文の %VAR% が、最初の IF 文を読み取ったときに展開されます。
このため、メッセージは決して表示されません。
複合文の中の IF では "before" と "after" が比較され、決して等しくはなりません。

もっとコンパクトな例だと、

@echo off
set A=100
set A=200 &  echo %A%
echo %A%

解決方法としては、set /?のその次に書いてある方法で、

@echo off
setlocal enabledelayedexpansion
for /f %%i in (.ip.conf) do (
	powershell ".netCheck.ps1 %%i;exit $LASTEXITCODE"	
	echo %%i : !ERRORLEVEL!
)

か、複合文を止めてサブルーチンにする。
この場合、%%iの値が空白や引用符を含んでいるとそれに対応するように書かないといけません。

@echo off
for /f %%i in (.ip.conf) do call :SUB %%i
exit /b

:SUB
powershell ".netCheck.ps1 %1;exit $LASTEXITCODE"	
echo %1 : %ERRORLEVEL%

どちらも一長一短で、ケースバイケースで使い分けます。今回はおそらくどっちでもいい。
アンドキュメンテッドな第3の方法もあります。

PowerShellスクリプトの中で表示までやるのが一番簡単ですね。

Comments

[sf213471118]

丁寧に教えていただきありがとうございます。
変数の展開タイミングについて理解が深まりました、ありがとうございます。