【VBA】AシートからBシートへの転記

Question

質問させていただきます。
Aシートは下記の通りです。

Bシートは下記の通りです。

Aシートで入力した情報をBシートに転記したいです。
例）Aシートで入力したAさんは5月6日欠勤です。　Bシートのセル「K7」に「欠勤」、「L7」に「5.5」と入力したいです。

下記、途中まで組んでいたマクロですが、訳が分からなくなりました。
ご教示いただけますと幸いです。宜しくお願い致します。

Sub 連絡表シートに入力した情報である種類と時間を勤怠シートに転記する()

    Dim Renrakuhyou As Worksheet
    Dim Kintaideta As Worksheet
    Dim MyList() As Variant
    Dim LastRow As Long
    Dim i As Long
    Dim j As Long
    Dim Cnt As Long

    Set Renrakuhyou = Worksheets("連絡表")
    Set Kintaideta = Worksheets("勤怠データ")

    Renrakuhyou.Select
    
    '連絡表シートの値を配列へ格納
    MyList = Renrakuhyou.Range(Cells(4, 4), Cells(Cells(Rows.Count, 4).End(xlUp).Row, 5))

    '勤怠データシート　最終行
    LastRow = Kintaideta.Cells(Rows.Count, 4).End(xlUp).Row

    '連絡表シート　最終行までループ
    For i = 2 To LastRow

    Cnt = 0

    '配列ループ
    For j = 2 To UBound(MyList)

    '日づけが一致したら
    If Renrakuhyou.Cells(i, 7) = MyList(j, 1) Then

    End If

    Next j
    Next i

End Sub

Comments

[meg_]

コード全体を「コードの挿入」で記入してください。

> 下記、途中まで組んでいたマクロですが、訳が分からなくなりました。
どこで詰まってしまったのでしょうか？

[Maeda]

失礼いたしました。コードの挿入で記入いたしました。

連絡表のデータ(Aシートの日付・届出内容・時間)が勤怠データ(Bシートの該当する日付の種類・時間)にうまく転記出来ません。

Answer 1

サンプルとしてのコードとして捉えてください
サンディプログラマ　独学で覚えた７０代のシニアですので
モニター半分をシート、画面もう半分をモジュール画面にして「F8]を押しながらプログラムをチェックしていきます

サンプルとしてコード記載します
Sub Macro1()
Dim i As Long
Dim j As Long
Dim n As Long
Dim shimei As String
Dim hiduke As Date
Dim naiyo As String
Dim jikan As Single
'
Sheets("連絡表").Select
For i = 5 To Cells(Rows.Count, 4).End(xlUp).Row
Cells(i, 3).Select
shimei = Cells(i, 3)
hiduke = Cells(i, 4)
naiyo = Cells(i, 5)
jikan = Cells(i, 8).Value
'勤怠データシートに転記
Sheets("勤怠データ").Select
n = Cells(Rows.Count, 5).End(xlUp).Row
For j = 2 To n
Cells(j, 5).Select
If Cells(j, 5) = shimei And Cells(j, 7) = hiduke Then
Cells(j, 11) = naiyo
Cells(j, 12) = jikan
End If
Next j
Sheets("連絡表").Select
Next i

End Sub

この様にしたかったのかな？

Answer 2

とりあえず、以下を直してみてはどうでしょう。

'連絡表シートの値を配列へ格納
MyList = Renrakuhyou.Range(Cells(4, 4), Cells(Cells(Rows.Count, 4).End(xlUp).Row, 5))

'日づけが一致したら
        If kintaideta.Cells(i, 7) = MyList(j, 1) Then

---

＜追記＞
こんな感じでしょうか。

    Set Renrakuhyou = Worksheets("連絡表")
    Set Kintaidata = Worksheets("勤怠データ")

    Dim shimei, hiduke, naiyo, jikan
    With Renrakuhyou
        For i = 5 To .Cells(Rows.Count, 4).End(xlUp).Row
            If .Cells(i, 4) <> "" Then
                '連絡表の値取得
                If .Cells(i, 3).Value <> "" Then shimei = .Cells(i, 3).Value
                hiduke = .Cells(i, 4).Value
                naiyo = .Cells(i, 5).Value
                jikan = .Cells(i, 8).Value
        
                '勤怠データシートに転記
                With Kintaidata
                    For j = 2 To .Cells(.Rows.Count, 4).End(xlUp).Row
                        If .Cells(j, 5).Value = shimei And .Cells(j, 7).Value = hiduke Then
                            .Cells(j, 11).Value = naiyo
                            .Cells(j, 12).Value = jikan
                        End If
                    Next
                End With
            End If
        Next
    End With

Comments

[Maeda]

修正しました。自分でも調べてみましたが上手く行きません…。