乱数が取得できない。全部おなじになってしまう。

Question

WEB上のサンプルを参考にしてるのですが、乱数が取得できないです。

@echo off
set cnt=10

for /l %%a in (1,1,%cnt%) do (
  echo %%a
  set /a ran1=%random%*10/32767
  set /a ran2=%random%*10/32767
  echo ran1=%ran1%
  echo ran2=%ran2%
)

pause

これをコマンドプロンプトから実行すると

>test.bat
1
ran1=6
ran2=9
2
ran1=6
ran2=9
3
ran1=6
ran2=9
4
ran1=6
ran2=9
5
ran1=6
ran2=9
6
ran1=6
ran2=9
7
ran1=6
ran2=9
8
ran1=6
ran2=9
9
ran1=6
ran2=9
10
ran1=6
ran2=9
続行するには何かキーを押してください . . .

と乱数がすべておなじになってしまいます。
timeout /nobreak 1
でウエイトを入れてみたのですが、結果変わりませんでした。

さらにダブルクリックで実行すると

1
ran1=
ran2=
2
ran1=
ran2=
3
ran1=
ran2=
4
ran1=
ran2=
5
ran1=
ran2=
6
ran1=
ran2=
7
ran1=
ran2=
8
ran1=
ran2=
9
ran1=
ran2=
10
ran1=
ran2=
続行するには何かキーを押してください . . .

となってしまいました。全く何も取得できなくなります。

これはどのようにしたら良いのでしょうか。

Answer 1

%random%の値への展開は、for 文実行前に一度だけなされます。なので、for の中では常に同じです。

%ran1%等についても同じです。これらは実行前の値なので、初回は空、同じコマンドプロンプトで再度実行すると前回実行後の値に展開されます。

案1：サブルーチンにする
案2：遅延環境変数展開を使う

for /l %%a in (1,1,%cnt%) do call :SUB %%a
exit /b

:SUB
echo %1
set /a ran1=%random%*10/32767
set /a ran2=%random%*10/32767
echo ran1=%ran1%
echo ran2=%ran2%
exit /b

setlocal enabledelayedexpansion

for /l %%a in (1,1,%cnt%) do (
  echo %%a
  set /a ran1=!random!*10/32767
  set /a ran2=!random!*10/32767
  echo ran1=!ran1!
  echo ran2=!ran2!
)

Answer 2

すいません自己解決してしまいました。
・forループを「setlocal enabledelayedexpansion」と「endlocal」で囲む
・変数の参照は「!」を使う
で解決しました。
ネット上には間違ったサンプルが溢れていますね。反省です。