Excelの選択範囲から、配列を得る方法

Question

VBAです

エクセルから配列を取得したい。
（それをUIpathに送りたい）

発生している問題・エラーメッセージ

エラーメッセージ
実行時エラー'９'
インデックスが有効範囲にありません。

該当のソースコード

Sub Selectionプロパティ01()


Dim arr As Variant
    arr = Selection

For Each Value In arr

Debug.Print Value

Next

MsgBox Selection(1)

MsgBox arr(1)

End Sub

試したこと

MsgBox　Selection(1)は、きちんと表示されます。　６　などの数字
つぎのところで、下記のエラーが出ます

エラーメッセージ
実行時エラー'９'
インデックスが有効範囲にありません。

内容的に、Selection の配列は、arrに入れられているのではないのでしょうか？

Answer 1

内容的に、Selection の配列は、arrに入れられているのではないのでしょうか？

Selectionだけ指定すると、Selection.Value2が代入されます。

試しにA1,B2,C3と選択範囲を選んでみると、For Each Value In arr でエラーになります。
Selection.Value2がA1のString型になるためです。

A1:C3と範囲で選んだ場合は、arr(3,3)になります。

範囲がExcel使用者が選んだ部分ではなく、システム側で決まっているようでしたら、Selectionを用いない方法を検討されたほうが面倒にならなくていいと思います。

Comments

[takFF]

なるほど、ありがとうございます。ご説明の内容について、レベルが高いので全体はよくわかりませんが、arrが二次元の配列になっているというのが分かりました。それでとりあえずの問題は解決しました。またさらに教えて頂いた内容、理解していきたいと思います。

Answer 2

SelectionはRangeオブジェクトです。
Selection(1)はSelection.Cells(1, 1)の省略表記になります。

arr = Selectionはarr = Selection.Value2の省略表記になります。
複数セル範囲を選択していたら、arrは 行数×列数の 二次元配列になります。
MsgBox arr(1, 1) とすればエラーなくSelection(1)と同じ値が表示されます。

単一セルしか選択していない場合は、arrは配列にはならずに値変数になります。よって、For Each の行でエラーになります。

下記のようにすれば、単一セルのみ選択したときも、複数セルを選択たときも二次元配列になり、エラーなく実行されます。

Sub Selectionプロパティ01()

    Dim arr As Variant

    arr = Selection.value

    If Not IsArray(arr) Then
        ReDim arr(1 To 1, 1 To 1)
        arr(1, 1) = Selection.value
    End If

    Dim value
    For Each value In arr

        Debug.Print value

    Next

    MsgBox Selection(1)

    MsgBox arr(1, 1)

End Sub

矩形範囲ではなく、とびとびの範囲を選択したときは、最初の選択範囲のみがarrに代入されます。

Comments

[takFF]

大変勉強になりました。ありがとうございます。