VBA 曜日の分岐について

Question

VBA初心者で申し訳ないのですが、質問です。
日付が入っている表をエクセルで作っています。

下記のif文を作りたいです
入力された日付が土日の場合、セルの背景を青くしたい。（祝日は含まない土日のみです）
平日の場合はセルの背景を白にしたい。

土日か？平日か？を判定をするif文を作りたいと思うのですが
どのようなコードになりますでしょうか。
何もわからなくて申し訳ないのですがよろしくお願いします

Answer 1

既に適切な回答がなされていると思いますが、
質問の冒頭にVBA初心者とありましたので、
リファレンスでなく具体的なコードの例が必要であれば、
次を参考にしてみてください。

WeekDay関数の戻り値が日曜なら1、土曜なら7なので、
戻り値を6で割った余りが1なら土日、それ以外なら平日と判定しています。

'A列の日付が土日なら着色する
Sub setInteriorColorByDate()
    Const firstRow As Long = 2 '日付の開始行
    Const colorColored As String = "&HF7EBDD"
    Const colorWhite As String = "&HFFFFFF"
    Dim sheet As Worksheet
    Set sheet = ThisWorkbook.Worksheets(1)
    
    With sheet
        Dim lastRow As Long
        lastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        Dim values As Variant
        values = .Range("A" & firstRow & ":A" & lastRow).Value
        Dim i As Long
        Dim dateValue As Date
        Dim interiorColor As String
        For i = 1 To UBound(values, 1)
            'Debug.Print Hex(.Range("A" & (i - 1 + firstRow)).Interior.color)
            dateValue = values(i, 1)
            '日付が土曜、日曜なら背景色を着色
            If Weekday(dateValue) Mod 6 = 1 Then
                interiorColor = colorColored
            Else
                interiorColor = colorWhite
            End If
            .Range("A" & (i - 1 + firstRow)).Interior.color = interiorColor
        Next i
    End With
End Sub

Comments

[YellowGreen]

色の指定を変更したい場合は、
日付のセル範囲を一度ご希望の色に着色してから
Debug.Printの行のコメントを外して実行すると
16進のカラーコードxxxxxxがイミディエイト・ウインドウに表示されますので、
Const colorColored As String = "&Hxxxxxx" のように &H を付して指定してください。

Answer 2

こちらをどうぞ
https://learn.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/weekday-function