VBAでテキストボックスの入力チェック

Question

前提

VBAで学内のスタッフ向けツールのプロトタイプを作成しています。
テキストボックスに入力された値の不正チェックの実装方法をご教示頂きたいです。

※ テキストボックスの名前はtxt1.Textとtxt2.Textとしています。

実現したいこと

・２つのテキストボックスに入力された値が半角数値であるか確認したい
・どちらか一方が半角数値でなかった場合任意のメッセージを表示させ値をクリアし処理を終了したい
・どちらも半角数値が入力された場合は何もしない

発生している問題・エラーメッセージ

テキストボックスに正しい値(半角数値)を入力してもエラー時を想定したメッセージが表示されてしまう

該当のソースコード

Private Function ChkParam()
  Input1 = txt1.Text
  Input2 = txt2.Text

  If Not IsNumeric(Input1) Or IsNumeric(Input2) Then
      MsgBox "半角数値を入力してください。"
      ChkParam = False
  End If

  ChkParam = True

End Function

Answer 1

テキストボックスに正しい値(半角数値)を入力してもエラー時を想定したメッセージが表示されてしまう

条件式が正しくありません

  If Not IsNumeric(Input1) Or IsNumeric(Input2) Then　' NG）Input1が数値でないまたはInput2が数値
  If Not (IsNumeric(Input1) And IsNumeric(Input2)) Then　' OK）[Input1が数値かつInput2が数値] ではない

２つのテキストボックスに入力された値が半角数値であるか確認したい

IsNumeric()は値が全角/半角かは関係がありません。数値とみなされる文字列であればTrueを返します。
ですので、入力値をStrConv()で自動的に半角に置き換えて処理するようにしてはどうでしょうか。

Private Function ChkParam()
  ChkParam = True
  txt1.Text= StrConv(txt1.Text, vbNarrow) '半角に置き換える
  txt2.Text= StrConv(txt2.Text, vbNarrow)
  Input1 = txt1.Text
  Input2 = txt2.Text
  If Not (IsNumeric(Input1) And IsNumeric(Input2)) Then
      MsgBox "数値を入力してください。"
      ChkParam = False
  End If
End Function

Answer 2

いろいろ突っ込みどころがありますが、
まず、条件式は下記のようにしましょう。

If Not IsNumeric(Input1) Or Not IsNumeric(Input2) Then

または、

If (Not IsNumeric(Input1)) Or (Not IsNumeric(Input2)) Then

演算子には優先順位がありますので、必要に応じて()で囲む必要があります。

次に、
ChkParam = TrueはElse節内にいれないと、結果が常にTrueになります。

    If Not (IsNumeric(Input1) And IsNumeric(Input2)) Then
        MsgBox "半角数値を入力してください。"
        ChkParam = False
    Else
        ChkParam = True
    End If

あと、IsNumeric だと、全角数字でも True になります。
さらに"123d4"とか"&H123"でもTrueになります。(指数表記と16進数表記)
他にもいろいろあります。

条件が純粋に半角数字のみということだと、IsNumericではだめです。
純粋に半角数字(０から9)のみという条件だと、
like演算子で下記のような式で ０から9 以外の文字が含まれているか判定できます。

文字列 Like "*[!0-9]*"

上記を考慮して、

Public Function ChkParam()
    Dim Input1 As String, Input2 As String
    Input1 = txt1.Text
    Input2 = txt2.Text

    If Input1 & Input2 Like "*[!0-9]*" Then
        MsgBox "半角数値を入力してください。"
        ChkParam = False
    Else
        ChkParam = True
    End If
End Function

Answer 3

OrじゃなくてAndでは？Orだとどちらか片方だけTrueでもTrue扱いです
あとVBAではNotのほうが優先順位が高いのでそれではInput1のisNumericしかNotできていません
両方使うときは括弧で囲んで優先順位を調整してください