VBAの配列でExcel列の入れ替えは可能か？

Question

[やりたいこと]

ExcelでA～ED列（仮）という多くの列を扱います。
その中で、例えばA列、G列、AG列、BH列をコピーし、
他のシートに貼り付けて、そこから更に指定された並び順に変える必要があるとします。

例
コピーした列（仮）

A	G	AG	BH

指定された順に並び替え（仮）

AG	BH	G	A

現在のコード

１：列をコピーし、別シートに貼り付け
この時点でA,G,AG,BHの順番に貼り付けられている
つまり、A列は別シートのA列に、G列は別シートのB列に、AG列は別シートのC列に、BH列は別シートのD列に貼り付けられている

.Worksheets("Sheet1").Range("A:A,G:G,AG:AG,BH:BH").Copy
        .Worksheets("Sheet2").Columns("A:A").PasteSpecial _
            Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

２：並び替え

Dim strRetsu1
Dim strRetsu2
Dim strRetsu3
Dim strRetsu4

'貼り付けた列を変数にセット
strRetsu1= Columns(1) 'A列にA列が貼り付けられている
strRetsu2= Columns(2) 'B列にG列が貼り付けられている
strRetsu3= Columns(3) 'C列にAG列が貼り付けられている
strRetsu4= Columns(4) 'D列にBH列が貼り付けられている

'列の配置換え
Columns(1) = strRetsu3 'AG列
Columns(2) = strRetsu4 'BH列
Columns(3) = strRetsu2 'G列
Columns(4) = strRetsu1 'A列

こういう風に書いていますが、今後コピーしたい列が増えた時にコードが冗長になって困るのではと思っています。

聞きたいこと

上記の流れは配列ですっきりできるのでしょうか？
もし配列で可能なのであれば、その書き方を教えてほしいです。

よろしくお願いいたします。

Answer 1

今後コピーしたい列が増えた時にコードが冗長になって困るのではと思っています。

ということなので、汎用関数にしてみました。

標準モジュール

'引数
'rng: 並べ替えるセル範囲
'OrderNum: 列番号を並べ替える順に指定
'使用例: Call SortColumns(Range("A1:D10"), 3, 4, 2, 1)
Public Sub SortColumns(rng As Range, ParamArray OrderNum() As Variant)
    If UBound(OrderNum) + 1 <> rng.Columns.Count Then
        MsgBox "セル範囲の列数とOrderNum引数の数は合ってません。"
        Exit Sub
    End If
    
    Dim ary(): ary = rng.Value 'セル範囲を配列に格納
    Dim i As Long
    For i = 0 To UBound(OrderNum)
        rng.Columns(i + 1).Value = WorksheetFunction.Index(ary, 0, OrderNum(i))
    Next
End Sub

使用例

Sub test()
    Call SortColumns(Cells(1, 1).CurrentRegion, 3, 4, 2, 1)
End Sub

もし、セル範囲が増えて5列になったとしても、引数の数を増やせばいいだけです。

Sub test()
    Call SortColumns(Cells(1, 1).CurrentRegion, 3, 4, 2, 5, 1)
End Sub

Answer 2

配列といっていいかどうかわかりませんが。

Sub Sample()
    ColCopy Worksheets(1), Worksheets(2), "AG", "BH", "G", "A"
End Sub

Sub ColCopy(moto As Worksheet, saki As Worksheet, ParamArray cols())
    Dim i
    For i = 0 To UBound(cols)
        moto.Columns(cols(i)).Copy saki.Columns(i + 1)
    Next
End Sub

列指定は数字でもいけます。

Sub Sample2()
    ColCopy ActiveSheet, Worksheets.Add, 3, 2, 1
End Sub

Answer 3

 Sub test()
    '  現在の列格納用
    Dim colArray(3) As Variant
    
    Dim colNum As Integer
    colNum = 1
  
    Dim i As Integer
    For i = LBound(colArray) To UBound(colArray)
        colArray(i) = Columns(colNum)
        colNum = colNum + 1
    Next
    
    '  並び替える順番を記述
    Dim colSortNums As Variant
    colSortNums = Array("2", "3", "1", "0")
    
    '  並び替え
    For i = 1 To 4
        Columns(i) = colArray(colSortNums(i - 1))
    Next
 
 End Sub

もっと良い方法があるかもしれませんが、配列で行うならこんな感じではないかと思います。

実施前	実施後