for文と環境遅延変数と疑似配列の組み合わせについて

Question

実現したいこと

Amazon s3のフォルダのls結果をWindowsコマンドプロンプトで変数に代入するバッチファイルを作成したいです。

発生している問題・分からないこと

for文でトークンに分けて%%aから始まるループ変数の4つ目の要素%%dに代入された値を
file[]という疑似配列に代入したいのですが、上手く代入されません。
for文を使って数字をインクリメントしたく、バッチでやるには環境遅延変数というものを使えばいいという情報をもとにsetlocal enabledelayedexpansionを最初に使っています。
for /fだとカウンタに当たる変数が無いように見えたのでその役割を果たす配列の添え字fcountと
配列名のfileを組み合わせて書こうとして
!file[!fcount!]!
%file[!fcount!]%
%file[%fcount%]%
などを試したのですが、期待通りに動作しませんでした。
どのように書けばよいでしょうか。
シンプルな実装方法を教えてください。

該当のソースコード

@echo off
chcp 65001
setlocal enabledelayedexpansion


rem s3のlsの行数をファイルの個数とみなしてls_rowに代入
for /f "usebackq" %%a in(`aws s3 ls s3://example-bucket-address --region ap-northeast-1 ^| find /c /v "") do set ls_row=%%a
rem ここまでうまくいく

set /a fcount=1

rem 4つ目の要素%%dにs3のls結果のファイル名を格納されるので
rem それをfile[]という配列っぽく命名した変数に代入したい
for /f "tokens=1,2,3,4" %%a in('aws s3 ls s3://example-bucket-address --region ap-northeast-1') do (
rem ここでfile[]にファイル名を代入してループしたいが実際は入っていないように見える
    set file[!fcount!]=%%d
    set /a fcount=fcount+1
    echo %file[!fcount!]%
)

rem 以降、格納されたfile[]についての後続処理を予定

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

変数がうまく展開・代入されない

補足

特になし

Answer 1

@echo off
chcp 65001
setlocal enabledelayedexpansion
set /a fcount=1
for /f "tokens=1-4" %%a in ('aws s3 ls s3://example-bucket-address --region ap-northeast-1') do (
    set file[!fcount!]=%%d
    call echo %%file[!fcount!]%%
    set /a fcount=fcount+1
)

・・・どうだろう？

Comments

[pencil.lzh]

こちらもありがとうございました。試したところうまくいきました。

Answer 2

for文に文法エラーがありますが、それはさておくと、
%による環境変数展開は、文単位の構文解析に先立って行われます。
つまり、14行目から19行目までのfor文の構文解析や実行の前に、18行目の%file[!fcount!]%の展開は行われ、この段階では!による展開もまだなので、結局これはfile[!fcount!]という名前の環境変数の展開ですが、きっとそういう変な名前の変数には値はセットされてないでしょうから、空文字列になります。（未定義変数の参照はエラーにならず空文字列になるだけ）

もし仮にそこに問題が無かったとしても、fcountに+1してからの参照なので、まだ設定していない変数の参照となり、結局は空文字列だと思います。セットした変数を参照したいなら、+1する前にしましょう。

for /f "tokens=1,2,3,4" %%a in ('aws s3 ls s3://example-bucket-address --region ap-northeast-1') do (
    set file[!fcount!]=%%d
    set file[!fcount!]
    set /a fcount=fcount+1
)
set file

set file[!fcount!]で1行前でセットした変数名とその値、set fileで変数名がfileで始まる全変数名とその値が表示されます。

表示だけならこれでいいですが、括弧内で!file[%fcount%]!を参照しても、%fcount%はforの前に展開されるので無意味です。個別に値を使いたいなら、callで括弧外のサブルーチンを呼び出す必要があります。

for /f "tokens=1,2,3,4" %%a in ('aws s3 ls s3://example-bucket-address --region ap-northeast-1') do (
    set file[!fcount!]=%%d
    call :DISPLAY
    set /a fcount=fcount+1
)
exit /b
:DISPLAY
echo %fcount%: !file[%fcount%]!
exit /b

Comments

[pencil.lzh]

ほしい結果を得ることが出来ました。変数展開やサブルーチンの使用についてはまだ理解しきれていませんが、展開のタイミングによるものということまではわかりましたので、ベストアンサーとさせていただきます。

[otn]

後半のサブルーチンを呼ぶ手段は、この場合は、v838-mon さんの回答のような、CALLのアンドキュメンテッドな機能を使えば、コンパクトに書けます。

Windows2000時代に、CALLのこの機能を発見した時は、QAの回答でもよく書いてたのですが、アンドキュメンテッドなのはさておいても、正確に説明するのが面倒なので、自分では使う物の、最近は回答では自分からはあまり書いてません。使わなくてもサブルーチンにすれば出来るので。

多くの場合は「%の処理を繰り返したい回数だけCALLを前置する」で良いのですが、「CALLを書いても何を一度しかやらずに、CALLを画回数だけ何を繰り返しやるのか」をきちんと説明するためには「そもそもバッチファイルの構文解析は、、、」から入らないといけないので面倒です。

[otn]

あと、echo off しなければ、%の展開と構文解析後のコマンドラインが表示されるので、様子が分かります。