【VB.NET】【EXCEL】VB.NETでEXCELを操作した後オブジェクトを処理してもプロセスが残ってしまう

Question

お世話になっております
VB.NETでEXCEL操作を行っているのですが、処理の最後でコンポーネントを開放しているのにも関わらず、タスクマネージャー上にEXCELのプロセスが残ってしまいます
（ただしこのプロセスはアプリケーションを終了させると何故か消えます）
EXCELのバージョン等で動かない場合があるので今回オブジェクトはCreateObject("Excel.Application")にて作成しております
開放の仕方が悪いのでしょうか？
ご教示ください

当方で使用しているEXCELは2019です

該当のソースコード

        Dim objXLApp As Object
        Dim objXLBook As Object
        Dim objXLSheet As Object

        objXLApp = CreateObject("Excel.Application")

        objXLApp.ScreenUpdating = False '画面を更新しないようにします
        objXLApp.DisplayAlerts = False 'ユーザーに入力を促すメッセージや警告メッセージを表示させない
        objXLApp.EnableEvents = False 'マクロ無効化

        objXLBook = objXLApp.Workbooks.Open("C:\TEST.xlsx")
		
        objXLBook.Worksheets(1).Activate()
        objXLSheet = objXLBook.ActiveSheet
		
		'値書き込み
        objXLSheet.Range("C3") = "テスト"

        '保存
        objXLBook.SaveAs("C:\TEST2.xlsx")

        objXLApp.EnableEvents = True
        objXLApp.DisplayAlerts = True
        objXLApp.ScreenUpdating = True

        objXLBook.Saved = True

        ' Microsoft Excel およびスプレッドシートへの参照を解放します。
        System.Runtime.InteropServices.Marshal.ReleaseComObject(objXLSheet)
        objXLSheet = Nothing
        objXLBook.Close()
        System.Runtime.InteropServices.Marshal.ReleaseComObject(objXLBook)
        objXLBook = Nothing
        objXLApp.Application.Quit()
        System.Runtime.InteropServices.Marshal.ReleaseComObject(objXLApp)
        objXLApp = Nothing

試したこと

ただオブジェクトをNothingにするだけではなくSystem.Runtime.InteropServices.Marshal.ReleaseComObjectで開放した

Comments

[Zuishin]

最終行でこれを呼んでみましょう。

https://learn.microsoft.com/ja-jp/dotnet/api/system.gc.collect?view=net-7.0

[len_souko]

古い記事にはなりますがこういうのが在ります
https://qiita.com/midori44/items/acab9106e6dad9653e73
ありとあらゆるものを変数に逐一格納しないと解放漏れが起きるとのことで、Officeをインストールされていないと使えない等の面からも「Microsoft.Office.Interop.XXXX」系は使用しない方が良さそうです

Answer 1

解放漏れに気付けないことがあるため、
注意しないといけないですよね。
コードを見てみて、気づいた点を下に記載してみますね。
(気付けていないところもあるかもしれません・・)

' objXLApp.Workbooksを変数に保持して解放する必要があると思います。(要素の「book」だけではなく、コレクションの「books」)
objXLBook = objXLApp.Workbooks.Open("C:\TEST.xlsx")
' objXLBook.WorksheetsとobjXLBook.Worksheets(1)を変数に保持して解放する必要があると思います。(コレクションの「sheets」と要素の「sheet」)
objXLBook.Worksheets(1).Activate()
' objXLSheet.Range("C3")を変数に保持して解放する必要があると思います。
objXLSheet.Range("C3") = "テスト"

途中で例外が発生した場合もちゃんと解放してあげる必要があるみたいで、
すごく面倒なコードになるみたいです。
下のリンクも見てみると良いかもしれません。

VB.NET - COM オブジェクトの参照カウントを解放する

追記です。

コメントありがとうございます。

objXLSheet.Cells(6, 6) = "テスト" も使っているのですがこれも変数に保持して解放してあげる必要があるのでしょうか

ちょっと手元に環境がないため、
間違いを書いてしまうかもしれませんが・・
ここはちょっと気付くのが難しいポイントだった気がします。

引用したコードを見ますと、
Cellsの部分で一度保持して、
さらにxlCells(6, 4)の部分も保持する感じになるみたいですね。

    Dim xlCells As Excel.Range = xlSheet.Cells
    Try
        Dim xlRange As Excel.Range = DirectCast(xlCells(6, 4), Excel.Range)

VB.NET - COM オブジェクトの参照カウントを解放する

Comments

[Ynn]

ありがとうございます

文字をセルに入れるとき、
objXLSheet.Cells(6, 6) = "テスト"
も使っているのですがこれも変数に保持して解放してあげる必要があるのでしょうか

Answer 2

過去似たような事になったときに「objXLBook = objXLApp.Workbooks.Open("C:\TEST.xlsx")」のように「.」を複数使ってしまうとプロセスが消えない状態になった覚えがあります。
こういった感じにした場合はどうですか？

        Dim objXLApp As Object = Nothing
        Dim objXLBooks As Object = Nothing
        Dim objXLBook As Object = Nothing
        Dim objXLSheets1 As Object = Nothing
        Dim objXLSheet As Object = Nothing

        objXLApp = CreateObject("Excel.Application")

        objXLApp.ScreenUpdating = False '画面を更新しないようにします
        objXLApp.DisplayAlerts = False 'ユーザーに入力を促すメッセージや警告メッセージを表示させない
        objXLApp.EnableEvents = False 'マクロ無効化

        objXLBooks = objXLApp.Workbooks
        objXLBook = objXLBooks.Open("C:\TEST.xlsx")

        objXLSheets1 = objXLBook.Worksheets(1)
        objXLSheets1.Activate()
        objXLSheet = objXLBook.ActiveSheet

        '値書き込み
        objXLSheet.Range("C3") = "テスト"

        '保存
        objXLBook.SaveAs("C:\TEST2.xlsx")

        objXLApp.EnableEvents = True
        objXLApp.DisplayAlerts = True
        objXLApp.ScreenUpdating = True

        objXLBook.Saved = True

        ' Microsoft Excel およびスプレッドシートへの参照を解放します。
        System.Runtime.InteropServices.Marshal.FinalReleaseComObject(objXLSheet)
        objXLSheet = Nothing
        System.Runtime.InteropServices.Marshal.FinalReleaseComObject(objXLSheets1)
        objXLSheets1 = Nothing
        objXLBook.Close()
        System.Runtime.InteropServices.Marshal.FinalReleaseComObject(objXLBook)
        objXLBook = Nothing
        System.Runtime.InteropServices.Marshal.FinalReleaseComObject(objXLBooks)
        objXLBooks = Nothing
        objXLApp.Application.Quit()
        System.Runtime.InteropServices.Marshal.FinalReleaseComObject(objXLApp)
        objXLApp = Nothing

Comments

[Ynn]

ありがとうございます
ご提示していただいたプログラムでは見事プロセスが消えました

ですが実際のプログラムで使っている
objXLSheet.Cells(i, j) = "テスト"
というセルに書き込んでいる記述があるのですがこれを使うとまたプロセスが残ってしまいます…

[bebebe_]

ループ内に記述していますか？
恐らく同じように宣言をして
｢For i = 1 To 10
objXLCells = objXLSheet.Cells(i, j)
objXLCells.Value = "テスト"
System.Runtime.InteropServices.Marshal.FinalReleaseComObject(objXLCells)
Next｣
のようにその都度解放する必要があった気がします。

[Ynn]

ご協力感謝します！

Answer 3

objXLApp.Application.Quit()を
objXLBook.Close()より前に実行してみてください。

いつからか仕様がちょこっと変わったような気もします
https://answers.microsoft.com/ja-jp/msoffice/forum/all/excel2010-vba/137099ad-fdb6-4480-af11-8c37d4c17fe8

Comments

[Ynn]

試してみましたがobjXLBook.Close()で
System.Runtime.InteropServices.COMException: '起動されたオブジェクトはクライアントから切断されました。
とエラーが出て止まってしまいます…
以下のように試しました

objXLApp.Application.Quit()
objXLBook.Close()

System.Runtime.InteropServices.Marshal.ReleaseComObject(objXLSheet)
objXLSheet = Nothing
System.Runtime.InteropServices.Marshal.ReleaseComObject(objXLBook)
objXLBook = Nothing
System.Runtime.InteropServices.Marshal.ReleaseComObject(objXLApp)
objXLApp = Nothing

[reimei]

見当違いならすみません。
objXLBook.Close()を除けて実行した場合、正常に動きますか？

[Ynn]

ありがとうございます
最後まで動作するようですがやはりプロセスは残ってしまいますね
今回もプログラムを終了すると消えるようですが…