VBA 文字列を結合して配列に格納したい

Question

いつもお世話になっております。

以下のようなコードがあり、エクセルシートのA列とB列の値を結合したものを配列に格納したいのですが
型の不一致のエラーが出てしまいます。。。。。

VarTypeで確認したところA列とB列ともにStringで判断されているようです。

ちなみに結合せずにA列かB列のどちらかのみを格納する場合は上手くいきます。

ご教授いただければ幸いです。

Function mk_cd_arr_1() As Variant()

    '行数を定義
    Dim cd_amnt As Long
    cd_amnt = 10

    '列1と列2を結合したものを配列に格納
    Dim cd_arr() As Variant
    ReDim cd_arr(cd_amnt) As Variant

    Dim i As Integer
    For i = 1 To cd_amnt
        Set cd_arr(i - 1) = Worksheets(3).Cells(i + 1, 1) & Worksheets(3).Cells(i + 1, 2)
    Next i

    mk_cd_arr_1 = cd_arr()

End Function

Comments

[退会済みユーザー]

set が余分なだけでは。

Answer 1

以下のようなコードがあり、エクセルシートのA列とB列の値を結合したものを配列に格納したいのですが

型の不一致のエラーが出てしまいます。。。。。

&は文字列結合演算子なので、&で結合すると文字列になります。
オブジェクト型でない値にはSetは不要。

Function mk_cd_arr_1() As Variant()

    '行数を定義
    Dim cd_amnt As Long
    cd_amnt = 10

    '列1と列2を結合したものを配列に格納
    Dim cd_arr() As Variant
    ReDim cd_arr(cd_amnt) As Variant

    Dim i As Integer
    For i = 1 To cd_amnt
        cd_arr(i - 1) = Worksheets(3).Cells(i + 1, 1) & Worksheets(3).Cells(i + 1, 2)
    Next i

    mk_cd_arr_1 = cd_arr()

End Function

1列だけでうまくいくのは、セル（Rangeオブジェクト）が代入されるからです。

型を指定すると呼び出し先でエラーになってしまいます。
引用テキスト
Dim cd_arr_1() As Variant
cd_arr_1() = mk_cd_arr_1()←型が一致しません。

上記の関数ならそのコードでエラーになりません。
提示の関数は戻り値がバリアント型の配列になってますので、受ける変数もバリアント型の配列でOKです。

---

&で結合するなら文字列になるので、String型の配列を戻り値にした方がいいかもしれません。
その場合は、下記のようになります。
結果を代入する変数もString型の配列にします。

Function mk_cd_arr_1() As String()

    '行数を定義
    Dim cd_amnt As Long
    cd_amnt = 10

    '列1と列2を結合したものを配列に格納
    Dim cd_arr() As String
    ReDim cd_arr(cd_amnt)

    Dim i As Integer
    For i = 1 To cd_amnt
        cd_arr(i - 1) = Worksheets(1).Cells(i + 1, 1) & Worksheets(1).Cells(i + 1, 2)
    Next i

    mk_cd_arr_1 = cd_arr

End Function

Public Sub test()
    Dim cd_arr_1() As String
    cd_arr_1 = mk_cd_arr_1()
    
    Debug.Print cd_arr_1(1)
End Sub

Answer 2

Function mk_cd_arr_1() As Variant

    '行数を定義
    Dim cd_amnt As Long
    cd_amnt = 3
    '列1と列2を結合したものを配列に格納
    Dim cd_arr() As String
    ReDim cd_arr(cd_amnt) As String

    Dim i As Integer
    For i = 1 To cd_amnt
        cd_arr(i - 1) = Worksheets(1).Cells(i + 1, 1).Value & Worksheets(1).Cells(i + 1, 2).Value
    Next i
    mk_cd_arr_1 = cd_arr
End Function

Comments

[Chandler_Bing]

ありがとうございます。

型を指定すると呼び出し先でエラーになってしまいます。

Dim cd_arr_1() As Variant
cd_arr_1() = mk_cd_arr_1()←型が一致しません。

[Black_Velvet]

これって
Dim cd_arr_1() As Variant
cd_arr_1() = mk_cd_arr_1()

これじゃダメですか？
Dim cd_arr_1 As Variant
cd_arr_1 = mk_cd_arr_1